Deleting duplicated lists containing a placeholder

Question

Some time ago I asked the question about Deleting list members by rule and received a variety of responses.

I have a slightly different data set and here wish to delete list members whose third and fifth elements are "xx" but otherwise are identical to the other members of that element:

lis = {{"a", "b", "c", "d", "e", "f"}, 
       {"g", "h", "i", "j", "l", "m"}, 
       {"a", "b", "xx", "d", "xx", "f"}, 
       {"o", "p", "q", "r", "s", "t"}};

to give:

res = {{"a", "b", "c", "d", "e", "f"}, 
       {"g", "h", "i", "j", "l", "m"},    
       {"o", "p", "q", "r", "s", "t"}}

Using @eyorble's suggestion, I tried:

lis /. {a___, 
Alternatives[
PatternSequence[{b_, c_, d_, e_, f_, g_}, {b_, c_, "xx", e_, "xx",
   g_}], PatternSequence[{b_, c_, "xx", e_, "xx", g_}, {b_, c_, 
  d_, e_, f_, g_}]], w___} :> {a, {b, c, d, e, f, g}, w}

...which fails.

Answer 1

DeleteDuplicatesBy[MapAt["xx" &, {{3}, {5}}]] @ lis

{{"a", "b", "c", "d", "e", "f"},   
 {"g", "h", "i", "j", "l", "m"},   
 {"o", "p", "q", "r", "s", "t"}}

lis2 = Append[lis, {"z", "b", "xx", "d", "xx", "f"}];

DeleteDuplicatesBy[MapAt["xx" &, {{3}, {5}}]] @ lis2

{{"a", "b", "c", "d", "e", "f"},   
 {"g", "h", "i", "j", "l", "m"},   
 {"o", "p", "q", "r", "s", "t"},   
 {"z", "b", "xx", "d", "xx", "f"}}

Answer 2

lis = {{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", 
    "m"}, {"a", "b", "xx", "d", "xx", "f"}, {"o", "p", "q", "r", "s", 
    "t"}, {"z", "b", "xx", "d", "xx", "f"}};

comp = Complement[Range[6], {3, 5}]
First /@ GatherBy[lis, {#[[comp]] &}]

{{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", "m"}, {"o", "p", "q", "r", "s", "t"}, {"z", "b", "xx", "d", "xx", "f"}}

---

EDIT

To make this edit more general, the addendum will use the following list that could contain more duplicated entries matching the placeholder pattern:

lis = {{"a", "b", "c", "d", "e", "f"}, {"a", "b", "g", "d", "m", 
    "f"}, {"g", "h", "i", "j", "l", "m"}, {"a", "b", "xx", "d", "xx", 
    "f"}, {"o", "p", "q", "r", "s", "t"}, {"z", "b", "xx", "d", "xx", 
    "f"}};

GatherBy[lis, {#[[comp]] &}] /. {{k_List} :> 
   k, {g___, {_, _, "xx", _, "xx", _}, h___} -> Sequence @@ {g, h}}

{{"a", "b", "c", "d", "e", "f"}, {"a", "b", "g", "d", "m", "f"}, {"g", "h", "i", "j", "l", "m"}, {"o", "p", "q", "r", "s", "t"}, {"z",
"b", "xx", "d", "xx", "f"}}

where unduplicated entries (even those containing "xx" are retained). Only the placeholder matching any duplicated entry is filtered out.

Answer 3

Using the third argument of GroupBy:

lis = {{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", "m"}, 
      {"a", "b", "xx", "d", "xx", "f"}, {"o", "p", "q", "r", "s", "t"}, 
      {"z", "b", "xx", "d", "xx", "f"}};

Values@GroupBy[lis, #[[1]] &, First] (*Edit*)

(*{{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", "m"}, 
  {"o","p", "q", "r", "s", "t"}, {"z", "b", "xx", "d", "xx", "f"}}*)

An example suggested by Eldo:

lis = {{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", 
"m"}, {"a", "b", "xx", "d", "xx", "f"}, {"o", "p", "q", "r", "s", 
"t"}, {"z", "b", "xx", "d", "xx", "f"}, {"z", "b", "xx", "d", 
"xx", "f"}};

Values@GroupBy[lis, #[[1]] &, First]

(*{{"a", "b", "c", "d", "e", "f"}, {"g", "h", "i", "j", "l", "m"}, 
{"o","p", "q", "r", "s", "t"}, {"z", "b", "xx", "d", "xx", "f"}}*)