Find variable name from DumpSave on a scoped variable

Question

I saved an InterpolationFunction in a ".mx" files using DumpSave on a variable that was scoped by a Module. Here is a stripped-down example:

Module[{interpolation},
   interpolation=Interpolation[Range[10]];
   DumpSave["interpolation.mx", interpolation];
]

Is there a way to find out the variable name, presumably of the form interpolation$nnn, of the expression when I Get the interpolation? It is not apparent what the variable is when using

<<"interpolation.mx"

Next time I will not use a Module for scoping the save variable, but meantime I'd like to access the saved data and assign it to a new variable.

Answer 1

You can open the MX file in an ASCII editor. The variable name is there in plain text (interpolation$511 in my case). The rest is binary gibberish.

So given an MX file with a single variable with the $ suffix, the following expression can be used to access that variable directly:

getExpression[filename_] := Module[{a}, 
   ToExpression[(a = StringCases[Import[filename, "Text"], 
   WordCharacter ... ~~ "$" ~~ NumberString][[1]])];
   << (filename);
   ToExpression[a]
  ]

E.g.,

result = getExpression["interpolation.mx"]
  (* InterpolatingFunction[{{1,10}},<>] *)

Evaluating the variable name before reading it with Get (or <<) seemingly overcomes the Temporary attribute discussed in Leonid`s answer. As a (perhaps unwanted) side-effect of the above expression, the original variable remains defined.

This approach could probably be extended to work with multiple variables and expressions in one MX file.

Answer 2

You seem to be out of luck (although I will be happy to be proven wrong). This is a rather subtle point, related to the Temporary attribute and garbage-collection. I will just share a few observations. First, note that after loading of .mx file on a fresh kernel, the variable is not found anywhere, it is not among the living:

<< "interpolation.mx"
names = Flatten[Names[# <> "*"] & /@ Contexts[]];
Flatten@StringCases[names, ___ ~~ "interpolation" ~~ ___]

{"Manipulate`Dump`interpolationToAnimation", 
   "Manipulate`Dump`interpolationToManipulate"}

Here is one way to make it persist:

Module[{interpolation},
  ClearAll[interpolation];
  interpolation = Interpolation[Range[10]];
  DumpSave["interpolation.mx", interpolation];
]

Now it will be found. By using ClearAll, I removed the Temporary attribute from interpolation. Interestingly, another way to do this is to define a DownValue rather than an OwnValue for it:

Module[{interpolation}, 
  interpolation[1] = Interpolation[Range[10]];
  DumpSave["interpolation.mx", interpolation];
]

In this case, too, it can be found, since garbage-collection of Module-generated variables works differently for DownValues.

I can not fully explain why this affected the code for DumpSave, which is still inside Module. One guess I have is that it gets recorded by DumpSave all right, with all attributes, including Temporary. Then, when you load it, it probably gets garbage-collected immediately after creation, due to this attribute.

Serializing in this manner using Module is also bad (although I am myself guilty of having done this, e.g. here) for another reason: Module-generated variables are only guaranteed to be unique within a single Mathematica session. It is better to use some custom code to generate variables with names guaranteed to be unique for all sessions (which is easy to do. I recommend to read this discussion).

Answer 3

Here is another method, although I don't know how to capture the symbol name programatically...

On[General::newsym];
Get["/tmp/test.mx"];
Off[General::newsym];
 (* General::newsym: Symbol a$1772 is new. >> *)