I want to calculate this integral but Mathematica does not solve it. Why? Can it be solved by Mathematica?

Integrate[Exp[-(Sqrt[1 + x^2] - 1)/t]*x^2, {x, 0, Infinity}]

I asked Mathematica to change variables to

 "u == Sqrt[1 + x^2] - 1"

and the result is Bessel function. but I'm not sure if


works properly.

This is the result:

ConditionalExpression[Exp^(1/t) t BesselK[2, 1/t], Re[t] > 0]

  • $\begingroup$ Perhaps you have a typo... t-->x? $\endgroup$ Sep 3, 2023 at 14:46
  • $\begingroup$ @OkkesDulgerci no, it's t $\endgroup$
    – lia
    Sep 3, 2023 at 14:56
  • $\begingroup$ Haha so this is a little awkward, I did exactly what you did for the add-on edit to your post in your question, and posted it at the exact same time you made the edit. I did some numerical confirmation of the result for explicit values of $t$ at the bottom of my answer though to confirm ConditionalExpression[Exp^(1/t) t BesselK[2, 1/t], Re[t] > 0] is in fact equal to the integral $\endgroup$
    – ydd
    Sep 3, 2023 at 15:36
  • 1
    $\begingroup$ Thank you so much for your help $\endgroup$
    – lia
    Sep 3, 2023 at 15:43

1 Answer 1


You just need to change variables. Using $u=\sqrt{x^2+1}$ appears to work:

int = Exp[-(Sqrt[1 + x^2] - 1)/t]*x^2;

new = IntegrateChangeVariables[
  Inactive[Integrate][int, {x, 0, Infinity}], u, u == Sqrt[1 + x^2]]

 E^((1 - u)/t) u Sqrt[-1 + u^2], {u, 1, \[Infinity]}]*)

Yields $$\int _1^{\infty }u \sqrt{u^2-1} e^{\frac{1-u}{t}}du$$

Activating the output:

(*ConditionalExpression[E^(1/t) t BesselK[2, 1/t], Re[t] > 0]*)

So $$\int_0^{\infty } x^2 \exp \left(-\frac{\sqrt{x^2+1}-1}{t}\right) \, dx = e^{1/t} ~t~ K_2\left(\frac{1}{t}\right)$$

for $\Re(t)>0$, where $K_n(t)$ is the modified Bessel function of the second kind.

Looking experimentally with values of $t$, we see this is correct

Table[NIntegrate[int, {x, 0, Infinity}], {t, 5}]
(*{4.41677, 24.8963, 73.3853, 161.878, 302.373}*)

Table[(E^(1/t) t BesselK[2, 1/t]), {t, 5}] // N

(*{4.41677, 24.8963, 73.3853, 161.878, 302.373}*)


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.