2
$\begingroup$

I'd like to plot the set

s=(z - I Im[z] < 0 && -I z + I Re[z] == 
0) || (-1 + Cos[(9 Arg[z])/2] Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) + 
 2 Cos[(9 Arg[z])/2] Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) + 
 Cos[(9 Arg[z])/2] Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) < 0 && 
   Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
 2 Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
 Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] == 0)

Both

ComplexContourPlot[s, {z, -10 - 10*I, 10 + 10*I}]

and

ComplexRegionPlot[(s,{z,-10-10*I,10+10*I}]

produce empty plots. I know s is not empty as

N[s /. z -> (-1)^(4/9)]

True

shows. I think its dimension equals one. The question is inspired by that question.

Addition. Making use of the Domen's comment, I replace inequalities by Booles,

ComplexContourPlot[Boole[z - I Im[z] < 0]*(-I z + I Re[z] == 0) || 
  Boole[-1 + Cos[(9 Arg[z])/2] Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) + 
  2 Cos[(9 Arg[z])/2] Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) + 
  Cos[(9 Arg[z])/2] Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) < 
 0]*(Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
  2 Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
  Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] == 0), {z,  10}]

enter image description here

, but the result is doubtful to me.

Addition 2. The improved approach

ComplexContourPlot[Boole[z - I Im[z] < 0] == 1 && (-I z + I Re[z] == 0) || 
  Boole[-1 + Cos[(9 Arg[z])/2] Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) + 
   2 Cos[(9 Arg[z])/2] Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) +
    Cos[(9 Arg[z])/2] Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) < 0] == 
1 && (Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
  2 Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
  Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] == 0), {z,  10}]

results in empty plot. PlotPoints -> 300 does not help.

$\endgroup$
3
  • $\begingroup$ FindInstance[s && Im[z] != 0, z, Complexes] fails for me in 13.3 on Windows 10. $\endgroup$
    – user64494
    Commented Aug 30, 2023 at 18:15
  • 1
    $\begingroup$ 1. You cannot use inequations for ComplexContourPlot; it can only accept a function (or equation). 2. Please see "Possible Issues" in the documentation for ComplexRegionPlot: It cannot draw one-dimensional regions (which yours is). $\endgroup$
    – Domen
    Commented Aug 30, 2023 at 18:46
  • $\begingroup$ @Domen. Thank you for your valuable comment. $\endgroup$
    – user64494
    Commented Aug 30, 2023 at 19:01

1 Answer 1

3
$\begingroup$
  • ComplexRegionPlot in Mathematica seems can't handle 2D region and 1D lines simultaneously.

  • Here we try to use ComplexContourPlot to plot the 1D lines and use RegionFunction to limit the 2D region.

Clear[plot1, plot2];
plot1 = ComplexContourPlot[-I z + I Re[z] == 0, {z, 10}, 
  RegionFunction -> Function[{z, f}, z - I Im[z] < 0], 
  ContourStyle -> Green]; plot2 = 
 ComplexContourPlot[
  Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
    2 Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
    Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] == 0, {z, 10},
   RegionFunction -> 
   Function[{z, 
     f}, -1 + Cos[(9 Arg[z])/2] Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) + 
      2 Cos[(9 Arg[z])/2] Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) + 
      Cos[(9 Arg[z])/2] Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) < 0], 
  ContourStyle -> Blue];
Show[plot1, plot2]

enter image description here

  • The above method can also illustrate by using MeshFunctions in ComplexRegionPlot. Here we only illustrate the second part.
ComplexRegionPlot[(-1 + 
    Cos[(9 Arg[z])/2] Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) + 
    2 Cos[(9 Arg[z])/2] Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) + 
    Cos[(9 Arg[z])/2] Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) < 0), {z, 10},
  PlotPoints -> 200, MaxRecursion -> 4, 
 MeshFunctions -> 
  Function[{z}, 
   Im[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
    2 Im[z]^2 Re[z]^2 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2] + 
    Re[z]^4 (Im[z]^2 + Re[z]^2)^(1/4) Sin[(9 Arg[z])/2]], 
 Mesh -> {{0}}, MeshStyle -> Blue, PlotStyle -> Opacity[.1], 
 BoundaryStyle -> Opacity[.1]]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.