Integral involving $\cosh$

Question

How can I calculate the following integral using Mathematica? $$\int_{-\infty}^{\infty} \frac{\mathrm{d} x}{\left(1+x^2\right) \operatorname{ch} \frac{\pi x}{2}} = 2 \ln 2$$

I tried:

int1 = Assuming[Element[x, Reals], 
  Integrate[
   FullSimplify[1/((1 + x^2)*Cosh[(Pi*x)/2])], {x, -Infinity, 
    Infinity}, PrincipalValue -> True]]

int2 = Integrate[
  1/((1 + x^2)*Cosh[(Pi*x)/2]), {x, -Infinity, Infinity}, 
  Assumptions -> Element[x, Reals], GenerateConditions -> False]

int3 = Integrate`InverseIntegrate[
 1/((1 + x^2)*Cosh[(Pi*x)/2]), {x, -Infinity, Infinity}, 
 Assumptions -> Element[x, Reals]]

I can calculate it using the residue theorem, but this belongs to mathematics. Is it possible to directly solve this integral with Mathematica without using the residue theorem?

Answer 1

Use an integral representation of $\text{sech}(z)=1/\text{cosh}(z)$:

Assuming[Element[x, Reals],
  2/π Integrate[t^(I x)/(t^2 + 1), {t, 0, ∞}]]

(*    Sech[π x/2]    *)

The integral can thus be written as a double integral. With Fubini's theorem we can flip the integration order:

$$ \int_{-\infty}^{\infty}\frac{dx}{(1+x^2)\text{cosh}\frac{\pi x}{2}} =\int_{-\infty}^{\infty}dx\int_0^{\infty}dt\frac{2t^{i x}}{\pi(1+x^2)(1+t^2)}\\ =\int_0^{\infty}dt\int_{-\infty}^{\infty}dx\frac{2t^{i x}}{\pi(1+x^2)(1+t^2)}\\ =\int_0^{\infty}dt\frac{2e^{-|\ln t|}}{1+t^2} =2\ln2. $$

Using Mathematica:

Integrate[2/π t^(I x)/((1 + t^2) (1 + x^2)), {x, -∞, ∞}, {t, 0, ∞}]
(*    Integrate[Sech[π*x/2]/(1 + x^2), {x, -∞, ∞}]    *)

Integrate[2/π t^(I x)/((1 + t^2) (1 + x^2)), {t, 0, ∞}, {x, -∞, ∞}]
(*    Log[4]    *)

Answer 2

The Log[2] comes from Dirichlet eta function at 1. We have partial fraction expansion for hyperbolic secant:

Sech[(π x)/2]==4/π Sum[(((2 n-1)/((2 n-1)^2+x^2)) (-1)^(n+1)),{n,1,∞}]
1/(x^2+1) Sech[(π x)/2]==Sum[(4/π 1/(x^2+1) ((2 n-1)/((2 n-1)^2+x^2)) (-1)^(n+1)),{n,1,∞}]

(* True *)
(* True *)

$$\text{sech}\left(\frac{\pi x}{2}\right)=\frac{4}{\pi}\sum _{n=1}^{\infty } \frac{(2 n-1) (-1)^{n+1}}{(2 n-1)^2+x^2}$$

$$\frac{1}{x^2+1}\text{sech}\left(\frac{\pi x}{2}\right)=\sum _{n=1}^{\infty } \frac{4}{\pi}\frac{1}{\left(x^2+1\right)}\frac{(2 n-1) (-1)^{n+1}}{(2 n-1)^2+x^2}$$

We integrate inside of the sum which will output explicit function.

(exp=Integrate[
  4/π 1/(x^2 + 1) ((2 n - 1)/((2 n - 1)^2 + x^2)) (-1)^(n + 1), 
  x]) == ((-1)^(
  1 + n) (-1 + 2 n) ((-1 + 2 n) ArcTan[x] + ArcTan[x/(1 - 2 n)]))/(
 n (1 - 3 n + 2 n^2) π)

(* True *)

$$exp=\int \frac{4}{\pi}\frac{1}{\left(x^2+1\right)}\frac{(2 n-1) (-1)^{n+1}}{(2 n-1)^2+x^2} \, dx=\frac{(-1)^{n+1} (2 n-1) \left(\tan ^{-1}\left(\frac{x}{1-2 n}\right)+(2 n-1) \tan ^{-1}(x)\right)}{\pi n \left(2 n^2-3 n+1\right)}$$

We compute limit of exp at x=∞ and x=-∞ and subtract them.

Limit[exp, x -> ∞], 
  Assumptions -> n \[Element] PositiveIntegers] == -((-1)^n/n)
Limit[exp, x -> -∞, 
  Assumptions -> n \[Element] PositiveIntegers] == (-1)^n/n

(* True *)
(* True *)

$$lim1-lim2=-2 \frac{(-1)^n}{n}$$

$$int=-2 \sum _{n=1}^{\infty}\frac{(-1)^n}{n}=2 \sum _{n=1}^{\infty}\frac{(-1)^{n+1}}{n}=2 \eta (1)=2 \ln 2$$

Answer 3

I propose the following way: Let us represent the Cosh[(Pi*x)/2]->(Exp[(Pi*x)/2]+Exp[-(Pi*x)/2])/2 as a sum of the exponents. Then the whole integral, int, can be represented as a sum of two terms:

int=int1+int2;

Here int1 only contains the converging parts of the integrals:

int1 = 1/
  2 (Inactive[Integrate][Exp[\[Pi]*x/2]/(
     1 + x^2), {x, -\[Infinity], 0}] + 
    Inactive[Integrate][Exp[-\[Pi]*x/2]/(
     1 + x^2), {x, 0, \[Infinity]}])

int1 // Activate // FullSimplify

(*  CosIntegral[\[Pi]/2]  *)

int2 contains all the rest:

int2 =1/2 ( Inactive[Integrate][Exp[\[Pi]*x/2]/(
   1 + x^2), {x, 0, \[Infinity]}] + 
  Inactive[Integrate][Exp[-\[Pi]*x/2]/(1 + x^2), {x, -\[Infinity], 0}])

Let us change variables in the first of these two integrals:

    int2 = 1/
   2 (IntegrateChangeVariables[
      Inactive[Integrate][Exp[\[Pi]*x/2]/(
       1 + x^2), {x, 0, \[Infinity]}], t, t == -x] + 
     Inactive[Integrate][Exp[-\[Pi]*x/2]/(
      1 + x^2), {x, -\[Infinity], 0}]) /. t -> x

Now everything is clear, but it is a pleasure to go to the end with the Mma tools. Let us use the following rule to fuse the inactive integrals:

rule = Inactive[Integrate][g1__, {x, a_, b_}] + 
    Inactive[Integrate][g2__, {x, a_, b_}] :> 
   Inactive[Integrate][Simplify[g1 + g2], {x, a, b}];

and now:

int2 /. rule // Activate

(*  0  *)

The result is CosIntegral[\[Pi]/2]. Why is it not 2ln2, I do not know. However,

NIntegrate[1/((1 + x^2)*Cosh[(Pi*x)/2]), {x, -Infinity, Infinity}]

(*  1.38629 *)

while

CosIntegral[\[Pi]/2] // N

(* 0.472001  *)

Something is evidently wrong in my solution.