# What method is there to retrieve which quantity to replace and complete factorization?

What method is there to retrieve which quantity to replace and complete factorization?

The following polynomial equation cannot be directly factorized, and the result obtained by directly factoring is consistent with the original equation.

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 == 0 // Factor

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 == 0


But there is another identity :y0^2==2p x0

y0^2 == 2 p x0


By using this identity, the 2px0 and y0^2 terms contained in polynomial equations can be replaced with y0^2 and 2px0, respectively, achieving the goal of factorization of polynomial equations.

y0^2 -> 2 p x0
2 p x0 -> y0^2


The problem is that before factoring, we are not sure which term or terms in the polynomial equation can be factorized by replacing them with identities. So we can only see if a polynomial equation can be factorized by constantly trying to replace a certain term in the equation

So there are the following manual calculation steps :

It should be noted that the method and steps of replacing and deforming the original polynomial equation through the isometric relationship of identities are not unique,There are multiple methods! but rather aim to factorize the original polynomial equation after identity transformation.

Provide a not very simple path that can ultimately factorize polynomial equations

STEP1 :

Replace the( -2 m p x0) term in the polynomial equation with (- my0^2),

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 == 0 /. -2 m p x0 -> -m y0^2

-2 m p s - s^2 t + 2 m^2 p t x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 - m y0^2 == 0

-2 m p s - s^2 t + 2 m^2 p t x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 - m y0^2 == 0 // Factor

-2 m p s - s^2 t + 2 m^2 p t x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 - m y0^2 == 0


This substitution cannot factorize polynomial equations

STEP2 :

Replace the(2 m^2 p t x0) term in the polynomial equation with (m^2 t y0^2)

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 == 0 /. (2 m^2 p t x0) -> m^2 t y0^2

-2 m p s - s^2 t - 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 + m^2 t y0^2 == 0

-2 m p s - s^2 t - 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 + m^2 t y0^2 == 0 // Factor

-2 m p s - s^2 t - 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 + m^2 t y0^2 == 0


This substitution cannot factorize polynomial equations too

STEP3 :

Replace these two terms in polynomial functions separately.(2 m^2 p t x0)->m^2 t y0^2,(-2m p x0)->-m y0^2

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 ==
0 /. {(2 m^2 p t x0) -> m^2 t y0^2, (-2 m p x0) -> -m y0^2}

-2 m p s - s^2 t + 2 s t x0 - t x0^2 - 2 m^2 p y0 - 2 s y0 + 2 x0 y0 -
m y0^2 + m^2 t y0^2 == 0

-2 m p s - s^2 t + 2 s t x0 - t x0^2 - 2 m^2 p y0 - 2 s y0 + 2 x0 y0 -
m y0^2 + m^2 t y0^2 == 0 // Factor

-2 m p s - s^2 t + 2 s t x0 - t x0^2 - 2 m^2 p y0 - 2 s y0 + 2 x0 y0 -
m y0^2 + m^2 t y0^2 == 0


This substitution cannot factorize polynomial equations again too

STEP4 :

First, replace an item:(2 m^2 p t x0)->m^2 t y0^2

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0 == 0 /. (2 m^2 p t x0) -> m^2 t y0^2

-2 m p s - s^2 t - 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 + m^2 t y0^2 == 0


Then perform an identical transformation and replacement of a term:

-2m p x0==-4 m p x0+2 m p x0==2 m p x0-2m y0^2


THEN

-2 m p s - s^2 t - 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 + m^2 t y0^2 == 0 /. (-2 m p x0) ->
2 m p x0 - 2 m y0^2

-2 m p s - s^2 t + 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 - 2 m y0^2 + m^2 t y0^2 == 0

-2 m p s - s^2 t + 2 m p x0 + 2 s t x0 - t x0^2 - 2 m^2 p y0 -
2 s y0 + 2 x0 y0 - 2 m y0^2 + m^2 t y0^2 == 0 // Factor

-((s - x0 + m y0) (2 m p + s t - t x0 + 2 y0 - m t y0)) == 0


After several attempts, the polynomial can finally be factorized after completing its final identity transformation

All the processes combined are:

 -2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 -
t x0^2 - 2 m^2 p y0 - 2 s y0 + 2 x0 y0 ==
0 /. {(2 m^2 p t x0) -> m^2 t y0^2, (-2 m p x0) ->
2 m p x0 - 2 m y0^2} // Factor

-((s - x0 + m y0) (2 m p + s t - t x0 + 2 y0 - m t y0)) == 0


My requirement is that after knowing a polynomial equation and an identity, the polynomial equation must be able to factorize after undergoing a series of identity transformations. So, is there a method for mathematica to find the path of identical deformation and ultimately factorize successfully?

-2 m p s-s^2 t-2 m p x0+2 m^2 p t x0+2 s t x0-t x0^2-2 m^2 p y0-2 s y0+2 x0 y0==0ANDy0^2==2p x0


try this can't achieve the goal

pl = -2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0
Assuming[y0^2 == 2 p x0, pl // Simplify]


to get

-((s - x0) (s t - t x0 + 2 y0)) + m^2 y0 (-2 p + t y0) -
m (2 p s + y0^2)


Simple as that:

-2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0
% /. Solve[y0^2 == 2 p x0, p] // Factor

(* {-(((s - x0 + m y0) (s t x0 - t x0^2 + 2 x0 y0 - m t x0 y0 + m y0^2))/
x0)} *)

• How can the numerator and denominator simultaneously approximate x0? Aug 30, 2023 at 1:14

In such situations, it is sometimes the case that resultants can help.

pol1 = -2 m p s - s^2 t - 2 m p x0 + 2 m^2 p t x0 + 2 s t x0 - t x0^2 -
2 m^2 p y0 - 2 s y0 + 2 x0 y0;
pol2 = y0^2 - 2 p x0;
-1/2 Resultant[pol1, pol2, p] //Factor
(* (s - x0 + m*y0)*(s*t*x0 - t*x0^2 + 2*x0*y0 - m*t*x0*y0 + m*y0^2) *)


In this particular case, it is also possible to use elimination as follows.

(Eliminate[ {pol1==0, pol2==0}, p] /. L_==R_ -> L-R) //Factor
(* (-s + x0 - m*y0)*(-(s*t*x0) + t*x0^2 - 2*x0*y0 + m*t*x0*y0 - m*y0^2) *)


Yet another possibility is to use polynomial remainder as follows.

PolynomialRemainder[-x0 pol1, pol2, p] //Factor
(* (s - x0 + m*y0)*(s*t*x0 - t*x0^2 + 2*x0*y0 - m*t*x0*y0 + m*y0^2) *)


There are a few other ways to do it and you may have to combine several methods.