2
$\begingroup$

Let the following inequality

$$4^xa - 2^x + 1 > 0$$

hold for any $x$. How can I find the range of parameter $a$?

The following method doesn't work:

Clear["Global`*"]
ForAll[x, x ∈ Reals, a*4^x - 2^x + 1 > 0]
Resolve[%, Reals]
Reduce[%, a, Reals]
(* Reduce::nsmet: This system cannot be solved with the methods
   available to Reduce. *)

The correct answer in the textbook is $a>1/4$.

$\endgroup$
2
  • $\begingroup$ Need to help Mathematica. ForAll[t, t ∈ PositiveReals, a*t^2 - t + 1 > 0] // Resolve $\endgroup$
    – cvgmt
    Commented Aug 15, 2023 at 7:32
  • $\begingroup$ Manual substitution can be calculated in one step, but cannot be achieved in one step $\endgroup$
    – csn899
    Commented Aug 15, 2023 at 7:37

4 Answers 4

5
$\begingroup$

Can't isolate this with Resolve, so here is a workaround.

Clear[a, x];
sol = Reduce[a*4^x - 2^x + 1 > 0, x, Reals];
Select[sol, FreeQ[x]]

a > 1/4


Visualization:

vals = {1/5, 1/4, 1/3, 1/2};
Plot[Evaluate[(1 - 2^x + # 4^x ) & /@ vals]
 , {x, -3, 3}
 , PlotLegends -> Placed[
   LineLegend[StringForm["a = ``", #] & /@ vals]
   , {0.2, 0.65}]
 ]

enter image description here

$\endgroup$
0
5
$\begingroup$
  • Extend my comment to an answer.
Clear[range];
range = FunctionRange[2^x, x, t]
ForAll[t, range, a*t^2 - t + 1 > 0] // Resolve

t > 0.

a > 1/4.

  • Test another example.(compare with the answer by @Syed)
{Select[Reduce[a (2^x + 1) (2^x + 2) + 1 > 0, x, Reals], FreeQ[x]], 
 ForAll[t, FunctionRange[2^x, x, t], a (t + 1) (t + 2) + 1 > 0] // 
  Resolve}

{a >= 0, a >= 0}.

$\endgroup$
5
$\begingroup$

From a*4^x - 2^x + 1 > 0 we have a>(2^x - 1)/4^x. Therefore, the inequality 4^x a−2x+1>0 hold for any x when and only when a > max((2^x - 1)/4^x). We have

Maximize[(2^x - 1)/4^x, x]

{1/4, {x -> 1}}

Thus a>1/4.

$\endgroup$
4
$\begingroup$

Try

Reduce[a*4^x - 2^x + 1 > 0 ] // Simplify[#, Element[a, Reals]] &

(* (4^x < 0 && 1 + 4^x a < 2^x) || (4^x > 0 && 1 + 4^x a > 2^x)*)

Visualization

RegionPlot[a*4^x - 2^x + 1 > 0, {x, -5, 5}, {a, -10, 10},FrameLabel -> {x, a}]

enter image description here

addendum

If we substitude z->2^x Mathematica's ForAll finds the solution

ForAll[z, Element[z, PositiveReals], a*z^2 - z + 1 > 0] // Resolve
(* a>1/4 *)
$\endgroup$
4
  • $\begingroup$ The final result only about a, maybe a>1/4. The original question is ForAll x instead of Exists x. $\endgroup$
    – cvgmt
    Commented Aug 15, 2023 at 7:17
  • $\begingroup$ ForAll x belongs to Reals $\endgroup$
    – csn899
    Commented Aug 15, 2023 at 7:20
  • $\begingroup$ Should be Element[z, PositiveReals] since 2^x>0 always hold. $\endgroup$
    – cvgmt
    Commented Aug 15, 2023 at 13:23
  • $\begingroup$ @cvgmt That's correct, tahnks. I'll modify my answer! $\endgroup$ Commented Aug 15, 2023 at 13:36

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.