4
$\begingroup$

Why this does not evaluate to True:

Assuming[-2 bRis bRm2 + (aRx rho + vR0)^2 > 0, Simplify[Sqrt[-2 bRis bRm2 + 
  (aRx rho + vR0)^2] > 0, reals]]
(* Sqrt[-2 bRis bRm2 + (aRx rho + vR0)^2] > 0 *)

if this does:

Assuming[-2 bRis bRm2 > 0, Simplify[Sqrt[-2 bRis bRm2] > 0]]
(* True *)

The second case would imply that Sqrt uses only the principal root.

$\endgroup$
1
  • 4
    $\begingroup$ Instead of reals, use Reals. $\endgroup$ Aug 10, 2023 at 15:32

2 Answers 2

6
$\begingroup$

I would also use Reduce. It tries harder than Simplify or FullSimplify.

For instance:

Assuming[-2 bRis bRm2 + (aRx rho + vR0)^2 > 0, 
 Simplify@
  Reduce[Implies[$Assumptions, 
    Sqrt[-2 bRis bRm2 + (aRx rho + vR0)^2] > 0]]
 ]

(*  True  *)

Or simply:

Assuming[-2 bRis bRm2 + (aRx rho + vR0)^2 > 0, 
  Reduce[Implies[$Assumptions, 
    Sqrt[-2 bRis bRm2 + (aRx rho + vR0)^2] > 0], Reals]
 ]

(*  True  *)

Or equivalently:

Reduce[
 Implies[
  -2 bRis bRm2 + (aRx rho + vR0)^2 > 0,
  Sqrt[-2 bRis bRm2 + (aRx rho + vR0)^2] > 0
  ],
 Reals]

(*  True  *)
$\endgroup$
5
$\begingroup$

If you solve inequality Reduce is better:

Reduce[Sqrt[-2 b1 b2 + (a r + v)^2] > 0 && -2 b1 b2 + (a r + v)^2 > 
   0 && a > 0 && b1 > 0 && b2 > 0 && r > 0 && v > 0]

(*  v > 0 && r > 0 && a > 0 && b2 > 0 && 
 0 < b1 < (a^2 r^2 + 2 a r v + v^2)/(2 b2)  *)

If you use Reals insted of what I did, you get an answer, but it will be considerably longer. That's why I did not do it.

Have fun!

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.