1
$\begingroup$

I'm a very beginner with Mathematica, and I do not get why I can't simplify this expression here:

Assuming[
  {
     a > 0, b > 0, c > 0, d > 0, e > 0, f > 0,
     b*e - f^2 > 0,
     a*e^2 - b*c*d + (f^2 - b*e)*c > 0
  }, 
  FullSimplify[
    Sqrt[a*e^2 - b*c*d + (f^2 - b*e)*c]/
    Sqrt[-a*e^2 + b*c*d + (-f^2 + b*e)*c]
  ]
]

In fact, it returns: $$\frac{\sqrt{a e^2-b c (d+e)+c f^2}}{\sqrt{-a e^2+b c (d+e)-c f^2}}$$ which is some kind of reordering of the terms, but not the full simplification. My expected result would be $-i$.

I'm assuming that everything is real, and the quantity under square root is positive.

EDIT: I've reproduced a MWE compared to original question, that was much more inricated.

$\endgroup$

2 Answers 2

4
$\begingroup$
expr = Sqrt[a*e^2 - b*c*d + (f^2 - b*e)*c]/
  Sqrt[-a*e^2 + b*c*d + (-f^2 + b*e)*c]

If we allow the indulgence:

expr /. Sqrt[a_]/Sqrt[b_] :> Sqrt[a/b] // FullSimplify

$i$

$\endgroup$
2
  • 1
    $\begingroup$ This gives the wrong result though. The expected answer is $-i$, not $i$ $\endgroup$
    – L.A.
    Commented Aug 9, 2023 at 16:25
  • $\begingroup$ Adding an If solves! $\endgroup$
    – L.A.
    Commented Aug 10, 2023 at 9:18
3
$\begingroup$
$Version

(* "13.3.0 for Mac OS X ARM (64-bit) (June 3, 2023)" *)

Clear["Global`*"]

Assuming[{
  a > 0, b > 0, c > 0, d > 0, e > 0, f > 0,
  b*e - f^2 > 0,
  a*e^2 - b*c*d + (f^2 - b*e)*c > 0}, 
 Simplify@
  ComplexExpand[
   Sqrt[a*e^2 - b*c*d + (f^2 - b*e)*c]/
    Sqrt[-a*e^2 + b*c*d + (-f^2 + b*e)*c]]]

enter image description here

EDIT: Note, however, that FindInstance cannot find any instances for which the expression is Iwith the given assumptions.

FindInstance[{Sqrt[a*e^2 - b*c*d + (f^2 - b*e)*c]/
    Sqrt[-a*e^2 + b*c*d + (-f^2 + b*e)*c] == I, a > 0, b > 0, c > 0, d > 0, 
  e > 0, f > 0, b*e - f^2 > 0, a*e^2 - b*c*d + (f^2 - b*e)*c > 0}, {a, b, c, 
  d, e, f}]

(* {} *)

As opposed to,

FindInstance[{Sqrt[a*e^2 - b*c*d + (f^2 - b*e)*c]/
    Sqrt[-a*e^2 + b*c*d + (-f^2 + b*e)*c] == -I, a > 0, b > 0, c > 0, d > 0, 
  e > 0, f > 0, b*e - f^2 > 0, a*e^2 - b*c*d + (f^2 - b*e)*c > 0}, {a, b, c, 
  d, e, f}, 3]

(* {{a -> 113, b -> 12, c -> 63, d -> 68, e -> 662/29, f -> 379/25}, {a -> 112, 
  b -> 3, c -> 34, d -> 87, e -> 3/112 (17 + Sqrt[110721]), 
  f -> 83/20}, {a -> 90, b -> 73, c -> 50, d -> 11, e -> 76, f -> 5}} *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.