1
$\begingroup$

Using the below sets of equations, I want to find the expression for ζ, η and eg using Mathematica.

$$\begin{aligned}\sqrt{\eta} \zeta = g \frac{1-\lambda_{\text{ch}}^2}{1-g^2 \lambda_{\text{ch}}^2} \sqrt{T} \lambda, \hspace{24 mm}\\ \frac{\eta \epsilon^g}{2+\eta \epsilon^g} =g^2 \frac{T \epsilon}{2+T \epsilon},\hspace{36 mm}\\ \frac{\eta\left[\zeta^2\left(2-\epsilon^g\right)+\epsilon^g\right]}{2-\zeta^2\left[2+\eta\left(\epsilon^g-2\right)\right]+\eta \epsilon^g}=g^2 \frac{T\left[\lambda^2(2-\epsilon)+\epsilon\right]}{2-\lambda^2[2+T(\epsilon-2)]+T \epsilon}\end{aligned}$$

$$\begin{aligned}\lambda_{\text{ch}}^2&=\frac{T\epsilon}{2+T\epsilon}\end{aligned}$$

The above system of equation should be reduced to: $$ \begin{aligned}\zeta & =\lambda \sqrt{\frac{\left(g^{2}-1\right)(\epsilon-2) T-2}{\left(g^{2}-1\right) \epsilon T-2}},\\ \eta &=\frac{g^{2} T}{\left(g^{2}-1\right) T\left[\frac{1}{4}\left(g^{2}-1\right)(\epsilon-2) \epsilon T-\epsilon+1\right]+1}, \\ \epsilon^{g}&=\epsilon+\frac{1}{2}\left(g^{2}-1\right)(2-\epsilon) \epsilon T, \hspace{43 mm} \end{aligned}$$ Could you please guide me on how to achieve this?

Code:

Solve[Sqrt[η] ζ == g λ Sqrt[T] (1 - λ^2)/(1 - g^2 λ^2) && 
   η eg/(2 + η eg) ==  g^2 T ϵ/(2 + T ϵ) && 
   η (ζ^2 (2 - eg) + eg)/(2 - ζ^2 (2 + η (eg - 2)) + η eg) == 
    g^2 T (λ^2 (2 - ϵ) + ϵ)/(2 - λ^2 (2 + T (ϵ - 2)) + T ϵ), {ζ, η, eg}]
$\endgroup$
12
  • $\begingroup$ What happens when you run your Solve expression? $\endgroup$
    – MarcoB
    Commented Aug 1, 2023 at 12:26
  • $\begingroup$ I'm not getting any response, and the process seems to be stuck in a running status $\endgroup$ Commented Aug 1, 2023 at 13:04
  • $\begingroup$ Check your code, it has typos. $\endgroup$ Commented Aug 1, 2023 at 13:41
  • 1
    $\begingroup$ Does the context which gave rise to these equations indicate any constraints on the variables and/or parameters? Are any Positive? NonNegative? Bounded? Using the constraints as assumptions might help. $\endgroup$
    – Bob Hanlon
    Commented Aug 2, 2023 at 5:49
  • 1
    $\begingroup$ Constraints on the variables: 0 ≤ T ≤ 1, ∈ = 2 * NB / T < 2, g > 1 and 𝜆^2 < 1 $\endgroup$ Commented Aug 3, 2023 at 4:49

2 Answers 2

1
$\begingroup$

Simply include the constraint condition cond and limit it to Reals. After that, everything becomes straightforward.

$\lambda_{ch}$ is replaced because it is a intermediate variable, which doesn't appear in the final solution.

P.S. Convert my code to StandardForm would be more readable.

Clear["Global`*"]

eqs = {Sqrt[\[Eta]] \[Zeta] == 
   g \[Lambda] Sqrt[T] (1 - Subscript[\[Lambda], ch]^2)/(
    1 - g^2 Subscript[\[Lambda], ch]^2) ,
     (\[Eta] eg)/(2 + \[Eta] eg) ==  
   g^2 (T \[Epsilon])/(2 + T \[Epsilon]) , 
    ( \[Eta] (\[Zeta]^2 (2 - eg) + eg))/(
   2 - \[Zeta]^2 (2 + \[Eta] (eg - 2)) + \[Eta] eg) == 
   g^2 (T (\[Lambda]^2 (2 - \[Epsilon]) + \[Epsilon]))/(
    2 - \[Lambda]^2 (2 + T (\[Epsilon] - 2)) + T \[Epsilon])};

(* replace lambda_ch *)
eqsf = FullSimplify[
  eqs /. {Subscript[\[Lambda], ch]^2 -> (T \[Epsilon])/(
     2 + T \[Epsilon])}]

cond = {0 <= T <= 1, \[Epsilon] < 2, g > 1, -1 <= \[Lambda] <= 1};

sol=Solve[Join[eqsf , cond], {\[Zeta], \[Eta], eg}, Reals]

FullSimplify[sol]

eqsf /. sol // FullSimplify
$\endgroup$
3
  • $\begingroup$ Could you add some commentary to explain your approach? $\endgroup$
    – MarcoB
    Commented Aug 4, 2023 at 8:59
  • $\begingroup$ @Peace Wang: Yes, this is the final expression I was aiming for. Thank you very much for your help $\endgroup$ Commented Aug 5, 2023 at 7:02
  • $\begingroup$ If my answer is helpful, you can do me a favor to accept the answer $\endgroup$
    – Peace Wang
    Commented Aug 5, 2023 at 9:08
2
$\begingroup$
$Version

(* "13.3.0 for Mac OS X ARM (64-bit) (June 3, 2023)" *)

Clear["Global`*"]

eq1 = Sqrt[η] ζ == g λ Sqrt[T] (1 - λ^2)/(1 - g^2 λ^2);
eq2 = η eg/(2 + η eg) == g^2 T ϵ/(2 + T ϵ);
eq3 = η (ζ^2 (2 - eg) + 
       eg)/(2 - ζ^2 (2 + η (eg - 2)) + η eg) ==
   g^2 T (λ^2 (2 - ϵ) + ϵ)/(2 - λ^2 (2 + T (ϵ - 2)) + T ϵ);

Solve the equations in steps

solζ = Solve[eq1, ζ][[1]];

solη = Solve[eq2, η][[1]];

eq4 = eq3 /. solζ /. solη // Simplify;

soleg = Solve[eq4, eg][[1]] // FullSimplify;

solη = solη /. soleg // FullSimplify;

solζ = solζ /. solη;

sol = {soleg, solη, solζ} // Flatten

(* {eg -> -((ϵ ((-1 + 
            g^2)^2 T^2 ϵ (-1 + λ^2)^2 (-ϵ + (-2 + ϵ) λ^2) - 
         4 (-1 + g^2) T (-1 + λ^2)^2 (-ϵ + (-1 + ϵ) λ^2) + 
         4 λ^2 (3 - 
            2 g^2 + (-3 + g^4) λ^2 + λ^4)))/(2 (-2 + (-1 + 
            g^2) T ϵ) λ^2 (-1 + λ^2)^2)), 
 η -> (4 g^2 T λ^2 (-1 + λ^2)^2)/((-1 + 
        g^2)^2 T^2 ϵ (-1 + λ^2)^2 (-ϵ + (-2 + ϵ) λ^2) - 
     4 (-1 + g^2) T (-1 + λ^2)^2 (-ϵ + (-1 + ϵ) λ^2) + 
     4 λ^2 (3 - 2 g^2 + (-3 + g^4) λ^2 + λ^4)), 
 ζ -> (g Sqrt[T] λ (-1 + λ^2))/(2 (-1 + 
       g^2 λ^2) √((g^2 T λ^2 (-1 + λ^2)^2)/((-1 \
    + g^2)^2 T^2 ϵ (-1 + λ^2)^2 (-ϵ + (-2 + ϵ) λ^2) - 
          4 (-1 + g^2) T (-1 + λ^2)^2 (-ϵ + (-1 + ϵ) λ^2) + 
          4 λ^2 (3 - 2 g^2 + (-3 + g^4) λ^2 + λ^4))))} *)

Verifying the solution,

{eq1, eq2, eq3} /. sol // Simplify

(* {True, True, True} *)
$\endgroup$
1
  • $\begingroup$ This is not the simplified expressions that I am trying to obtain. Nevertheless, Thank you very much for your valuable contribution and efforts. $\endgroup$ Commented Aug 1, 2023 at 14:29

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.