Apply a function row- and columnwise

Question

I want to a apply a function to the 2nd row and 2nd column of an association:

dt =
  <|"Arizona" -> <|"1801" -> 60, "1802" -> 1530, "1803" -> 100, "1804" -> 665|>,
   "Kansas" -> <|"1801" -> 1160, "1802" -> 415, "1803" -> 825, "1804" -> 230|>,
   "Texas" -> <|"1801" -> 365, "1802" -> 135, "1803" -> 70, "1804" -> 1280|>,
   "Vermont" -> <|"1801" -> 60, "1802" -> 485, "1803" -> "100", "1804" -> 555|>|>;

I tried:

Query[
   <|#, "Kansas" -> f /@ #Kansas|> &,
   <|#, "1802" -> f @ #"1802"|> &] @ dt // Dataset[#, ItemSize -> 7] &

and got:

At "Kansas" / "1802" the function was applied twice, but I want it to be applied only once. Is there an easy / elegant way to achieve this?

Answer 1

If we change dt to:

dt = Dataset@<|
    "Arizona" -> <|"1801" -> 60, "1802" -> 1530, "1803" -> 100, 
      "1804" -> 665|>, 
    "Kansas" -> <|"1801" -> 1160, "1802" -> 415, "1803" -> 825, 
      "1804" -> 230|>, 
    "Texas" -> <|"1801" -> 365, "1802" -> 135, "1803" -> 70, 
      "1804" -> 1280|>, 
    "Vermont" -> <|"1801" -> 60, "1802" -> 485, "1803" -> "100", 
      "1804" -> 555|>|>;

Perhaps this:

Block[{f},
 SetAttributes[f, Flat];
 dt[MapAt[Map@f, "Kansas"], MapAt[f, "1802"]]
 ]

(If -f[..] in the 1802 column, then dt[MapAt[Map@f, "Kansas"]][All, MapAt[-f[#] &, "1802"]] for the 3rd line.)

Answer 2

Maybe not elegant, but at least bundles it up into something a relatively understandable and generalizable function:

CrossApply[a_, b_, f_] :=
  KeyValueMap[
    If[
      #1 == a,
      a -> f /@ #2,
      #1 -> ReplacePart[#2, b -> f[#2[b]]]] &]

Usage:

CrossApply["Kansas", "1802", f][dt]
(* {Arizona-><|1801->60,1802->f[1530],1803->100,1804->665|>,
    Kansas-><|1801->f[1160],1802->f[415],1803->f[825],1804->f[230]|>,
    Texas-><|1801->365,1802->f[135],1803->70,1804->1280|>,
    Vermont-><|1801->60,1802->f[485],1803->100,1804->555|>} *)

Answer 3

1.

MapIndexed[If[FreeQ["Kansas" | "1802"] @ #2, #, h @ #] &, Dataset@dt, {2}]

2.

MapAt[Replace[{a_h :> a, x_ :> h[x]}],{{"Kansas", All}, {All, "1802"}}] @ 
 Dataset @ dt

Answer 4

Dataset[dt][{"Kansas" -> 
   KeyValueMap[If[#1 != "1802", #1 -> f[#2], # -> #2] &]/*
    Association}, {"1802" -> f}]

Or

Dataset[dt][{"Kansas"->MapAt[f,{{"1801"},{"1803"},{"1804"}}]},{"1802"->f}]

Or

Dataset[dt][{"Kansas"->(<|f/@#,KeyTake[#,"1802"]|>&)},{"1802"->f}]

Answer 5

Proceeding as the OP suggests, but using MapAt rather than Map, and dropping the appropriate Key to avoid the double function call.

Query[<|#,"Kansas"->MapAt[f, #"Kansas", Keys[KeyDrop[#"Kansas","1802"], List]]|>&,
      <|#, "1802" -> f @ #"1802"|> &
     ]@dt//Dataset

Calling Normal on the above shows that 'underneath the hood" Query is using RigthtComposition.

Map[<|#, "1802" -> f[#"1802"]|> &] /* (
    <|#, "Kansas" -> MapAt[f, #Kansas, Keys[KeyDrop[#Kansas, "1802"], List]] |> &
  )@dt//Dataset

(* Same Result as above *) 

Original Answer

Generate row and column indices for the third argument of MapAt,deleting the duplicate value:

MapAt[f,Splice@Thread[#]&/@{{2,Range[4]},
    {Range[4],2}}//DeleteDuplicates]@dt//Dataset

Or:

rowIndices[rowName_]:=Thread@{PositionIndex[Keys[#]][rowName[[1]],
  Range@Last@Dimensions[#]}&

colIndices[colName_]:=Thread@{Range@First@Dimensions[#],
  PositionIndex[Keys[First[#]]][colName][[1]]}&

dt//rowIndices["Kansas"]
dt//colIndices["1802"]

(* {{2, 1}, {2, 2}, {2, 3}, {2, 4}} *)
(* {{1, 2}, {2, 2}, {3, 2}, {4, 2}} *)

MapAt[IntegerQ,#,Join[rowIndices["Kansas"][#],
  colIndices["1802"][#]]//DeleteDuplicates]&@Dataset[dt]