# Calculation of Approximate Equation with Mathematica

I am trying to find an approximate equation for a complicated expression (L1, L2) using Mathematica. The equation involves several parameters and expressions, and I want to simplify it by considering the following approximations: k << 1, Ns << 1, and Nb >> 1

S = 2 Ns + 1
B = 2 Nb + 1
A = 2*k*Ns + B
Cq = 2*Sqrt[Ns*(Ns + 1)]
vH1[i_] = ((-1)^i*(S - A) + Sqrt[(A + S)^2 - 4*k*(Cq)^2])/2
L[s_, x_] = ((x + 1)^s + (x - 1)^s)/((x + 1)^s - (x - 1)^s)
L1 = L[1/2, vH1[1]] // Simplify
L2 = L[1/2, vH1[2]] // Simplify


$$L1=-\frac{\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}+k \text{Ns}+\text{Nb}-\text{Ns}-1}+\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}+k \text{Ns}+\text{Nb}-\text{Ns}+1}}{\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}+k \text{Ns}+\text{Nb}-\text{Ns}-1}-\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}+k \text{Ns}+\text{Nb}-\text{Ns}+1}}$$

$$L2=-\frac{\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}-k \text{Ns}-\text{Nb}+\text{Ns}-1}+\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}-k \text{Ns}-\text{Nb}+\text{Ns}+1}}{\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}-k \text{Ns}-\text{Nb}+\text{Ns}-1}-\sqrt{\sqrt{(k \text{Ns}+\text{Nb}+\text{Ns}+1)^2-4 k \text{Ns} (\text{Ns}+1)}-k \text{Ns}-\text{Nb}+\text{Ns}+1}}$$

I would like the approximate equations for L1 and L2 to give the values 81.9882 and 1.22094, respectively, when k=0.01, Ns=0.01, Nb=20.

Any guidance or suggestions would be greatly appreciated. Thank you in advance for your help!

• You could try an expansion with Series. Commented Jul 21, 2023 at 14:03
• Your definitions of L1,L2 depend on A,S,k,Cq! Please correct your question Commented Jul 21, 2023 at 14:03
• @Ulrich Neuman: Apologies, I forgot to include the definitions of A, S, B, and Cq in the question. Now, I have updated question. Commented Jul 21, 2023 at 14:11
• @SumitSugar Thanks for the update. What is known about the limiting behavior of the three parameters? Perhaps Nb~1/eps,k~eps, Ns~eps as eps->0? Commented Jul 21, 2023 at 14:34
• @UlrichNeumann: the limiting behaviour of the three parameters (Nb, k, and Ns) as epsilon (eps) approaches 0. It's worth considering these limits to see if they provide valuable insights into the approximate equation. The values of the three parameters (Nb, k, and Ns) can be in the range of: Ns=0.01-0.1, k=0.01-0.5, and Nb=10-100. Commented Jul 21, 2023 at 14:58

You may expand L1 and L2 in a series around k==0, Ns==0 and Nb around infinity like:

ser1= Series[L1, {k, 0, 1}, {Ns, 0, 1}, {Nb, Infinity, 1}] // Normal

2 - 1/(4 Nb) + 4 Nb + k (4 - 4/Nb) Ns

ser2=Series[L2, {k, 0, 1}, {Ns, 0, 1}, {Nb, Infinity, 1}] // Normal

1 + 2 Sqrt[Ns] + 2 Ns + k (-(Sqrt[Ns]/Nb) - (2 Ns)/Nb)


Now to test:

{ser1, ser2} /. { k -> 0.01, Ns -> 0.01, Nb -> 20}

{81.9879, 1.21994}

• @Deniel Huber: Thank you very much for helping me with the problem!🙏🏼😊 Commented Jul 21, 2023 at 16:47

If the asymptotic behavior of the parameters is Nb~1/eps,k~eps, Ns~eps as eps->0 try

Asymptotic[L1 /. {Nb -> Nb/eps, k -> eps k, Ns -> eps Ns}, {eps, 0, 2}] /.eps -> 1 // Simplify[#, Nb > 0] &
(*2 + 1/(8 Nb^2) - 1/(4 Nb) + 4 Nb + 4 k Ns*)


Unfortuantely the same procedure applied to L2 gives a message "Power::infy: Infinite expression 1/0^2 encountered."

• Thank you for your valuable contributions and efforts. Commented Jul 21, 2023 at 16:49