# Evaluating ${}_5F_4\left(1,1,1,1,1;\frac{3}{2},2,2,2;-\frac{1}{4} \right)$

Using Mathematica, how can I find a closed-form expression (in terms of elementary functions) of $${}_5F_4\left ( 1,1,1,1,1;\frac{3}{2},2,2,2;-\frac{1}{4} \right ),$$ where $${}_5F_4$$ represents the hypergeometric function?

HypergeometricPFQ[{1, 1, 1, 1, 1}, {3/2, 2, 2, 2}, -1/4]

• "...in terms of any special functions..." -- It already is in a closed form in terms of a special function. Did you mean "elementary functions"? Jun 25, 2023 at 16:56
• @Goofy Thanks. I have edited the question. That is what I meant. Please answer.
– Max
Jun 25, 2023 at 16:58
• You can try cutting of a "1" and a "2" from the argument list of 5F4 to reduce to 4F3, Functionexpand the 4F3 with argument z and and then integrate the result (after replacing z->-t/4) from t=0 to t=1,but there appear some very hard integrals that I couldn't do... Jun 25, 2023 at 20:19
• The Wolfram functions site lists no formulas for simplifying $_5F_4$ functions. If you find something, maybe you can let them know! Jun 25, 2023 at 20:22
• @Max I don't know what you mean by "simplify". Sum[1/((-4)^k (k + 1)^3 Binomial[k + 1/2, 1/2]), {k, 0, ∞}] gives HypergeometricPFQ[{1, 1, 1, 1, 1}, {3/2, 2, 2, 2}, -1/4], as you requested. I don't know how to make this any simpler. Jun 26, 2023 at 6:54

Consider HypergeometricPFQ[{1, 1, 1, 1, 1}, {3/2, 2, 2, 2}, z] : use its integral representation

Integrate[HypergeometricPFQ[{1, 1, 1, 1}, {3/2, 2, 2}, t*z], {t, 0, 1}]
(* HypergeometricPFQ[{1, 1, 1, 1, 1}, {3/2, 2, 2, 2}, z] *)


and try to integrate the result of

FunctionExpand[HypergeometricPFQ[{1, 1, 1, 1}, {3/2, 2, 2}, -(t/4)]]


from t = 0 to t = 1.

Edit

    FunctionExpand[HypergeometricPFQ[{1, 1, 1, 1}, {3/2, 2, 2}, -(t/4)]]
(* -((8*I*(-t)^(3/2)*ArcCsch[2/Sqrt[t]]^3)/(3*t^(5/2))) + (8*
ArcCsch[2/Sqrt[t]]^2*
Log[(I*Sqrt[1 + t/4] + Sqrt[-t]/2)*Sqrt[-t]])/t -
(8*I*Sqrt[-t]*ArcCsch[2/Sqrt[t]]*
PolyLog[2, 1 - I*Sqrt[1 + t/4]*Sqrt[-t] + t/2])/
t^(3/2) - (4*PolyLog[3, 1 - I*Sqrt[1 + t/4]*Sqrt[-t] + t/2])/
t + (4*Zeta[3])/t *)


There are 5 terms and I managed to integrate them all. The last two go together because of a singularity. Using substitution variables and sometimes partial fraction decomposition I get:

-((7*Pi^4)/45) + (2/15)*
ArcCsch[2]^2*(13*Pi^2 - 20*ArcCsch[2]^2) - (4/15)*ArcCsch[2]*
ArcSinh[2]*(Pi^2 - 15*ArcCsch[2]^2) -
(8/3)*
ArcTanh[2 - Sqrt[5]]^2*(21*ArcCsch[2]^2 -
2*ArcTanh[2 - Sqrt[5]]^2) +
16*ArcCsch[2]*PolyLog[3, 2/(1 + Sqrt[5])] -
8*PolyLog[4, (1/2)*(1 - Sqrt[5])] +
8*PolyLog[4, (1/2)*(-1 + Sqrt[5])] - (8/5)*ArcCsch[2]*Zeta[3]
(* 0.980301 *)


The numerical value corresponds to the OP's 5F4.

Edit2

The result may be simplified some more:

1/45*(-7*Pi^4+42*Pi^2*ArcCsch[2]^2-195*ArcCsch[2]^4)-
8*PolyLog[4,(1-Sqrt[5])/2]+8*PolyLog[4,(-1+Sqrt[5])/2]+
ArcCsch[2]*(16*PolyLog[3,2/(1+Sqrt[5])]-8*Zeta[3]/5)


Edit3

A working substitution is sometimes only found by trial and error, complicated by its interplay with the Jacobian factor. I demonstrate the major steps of the integration of the second term and the two last terms as examples, the complete elaboration would be too long and too boring.

Second term :

NIntegrate[(8*ArcCsch[2/Sqrt[t]]^2*
Log[(I*Sqrt[1 + t/4] + Sqrt[-t]/2)*Sqrt[-t]])/t, {t, 0, 1}]
(* -0.358773 + 6.0422 I *)


(To keep control of the correctness of the manipulations the numerical value should be calculated at every step.) The nominator of the integrand can be simplified a bit:

FullSimplify[PowerExpand[FullSimplify[
PowerExpand[
TrigToExp[
Expand[PowerExpand[
8*ArcCsch[2/Sqrt[t]]^2*
Log[(I*Sqrt[1 + t/4] + Sqrt[-t]/2)*Sqrt[-t]]]]]]]]]
(* 4*(Log[2] - Log[Sqrt[t] + Sqrt[4 + t]])^2*(2*I*Pi + Log[t/4] +
2*Log[Sqrt[t] + Sqrt[4 + t]]) *)


The following substitution is applied :

y -> (Sqrt[t]/2)*(Sqrt[t] + Sqrt[4 + t])


with the Jacobian factor D[t,y]

(y*(2 + y))/(1 + y)^2


and the new integration limits are

{(Sqrt[t]/2)*(Sqrt[t]+Sqrt[4+t])/.t->0,(Sqrt[t]/2)*(Sqrt[t]+ Sqrt[4+t])/.t->1}
(* {0, (1/2)*(1 + Sqrt[5])} *)


Then we arrive after a few Simplifications and PowerExpands at an expression that Mathematica swallows :

Integrate[((2 + y)*
Log[1+y]^2*(2*I*Pi+Log[y^2/(1+y)]+Log[1+y]))/(y*(1+y)),
{y, 0, (1/2)*(1 + Sqrt[5])}]
(* lengthy output *)


Don' t forget the numerical check!

Last terms :

The singularity of the Zeta[3]/t term at t = 0 is cancelled by

4*PolyLog[3, 1 - I*Sqrt[1 + t/4]*Sqrt[-t] + t/2] /. t -> 0
(* 4 Zeta[3] *)


The numerical integral gives

NIntegrate[-((4*PolyLog[3,1-I*Sqrt[1+t/4]*Sqrt[-t]+t/2])/t) + (4*Zeta[3])/t,
{t, 0, 1}]
(* -16.6771 + 6.0422 I *)


Substitute

z -> (1/2)*(2 + t + Sqrt[t]*Sqrt[4 + t])


with Jacobian

1 - 1/z^2


and new limits

{(1/2)*(2+t+Sqrt[t]*Sqrt[4+t])/.t->0,(1/2)*(2+t+Sqrt[t]*Sqrt[4+t])/.t->1}
(* {1, (1/2)*(3 + Sqrt[5])} *)


After Simplifications and PowerExpands Mathematica does integrate

Integrate[4*(1+z)*(-PolyLog[3,z]+Zeta[3])/((-1+z)*z),{z,1,(1/2)*(3+Sqrt[5])}]


with successful numerical check.

By the way: The first term integrates as it is, the third term is cracked with the substitution

y -> 1 + Sqrt[1 + t/4]*Sqrt[t] + t/2


In the end add all contributions to get the result, which gives a large expression that may be simplified quite a bit .

• Comments have been moved to chat; please do not continue the discussion here.
– Kuba
Jun 30, 2023 at 7:37