# Evaluating $\int_{1/\phi^2}^{1}\frac{\log^2x}{1-x}\ \log^2\left(\frac{1}{x}\left(\frac{1-x}{1+x}\right)^2\right)\ \mathrm{d}x$

I want to calculate the following integral: $$I=\int_{1/\phi^2}^{1}\frac{\log^2x}{1-x}\ \log^2\left(\frac{1}{x}\left(\frac{1-x}{1+x}\right)^2\right)\ \mathrm{d}x$$ where $$\phi=(\sqrt{5}+1)/2$$ is the golden ratio, so $$1/\phi^2 = (3-\sqrt 5)/2$$.

Can Mathematica give a closed form answer for $$I$$ (even if it is in terms of some special functions like the Riemann zeta function)?

The following code returns unevaluated:

Integrate[
Log[x]^2/(1 - x) Log[1/x ((1 - x)/(1 + x))^2]^2, {x, 1/GoldenRatio^2, 1}]


This is as close as I've been able to get:

First, I rewrite your integrand a little:

$$\frac {\mathrm {log}[x]^2} {(1 - x)} \mathrm {log}[\frac {1} {x} (\frac {1 - x} {1 + x})^2]^2$$ = $$\frac {\mathrm {log}[x]^2} {(1 - x)} (-\mathrm {log}[x] + 2 (\mathrm {log}[1 - x] - \mathrm {log}[1 + x]))^2$$

I input this as:

part1=Log[x]^2/(1 - x);
part2 = (-Log[x] + 2 (Log[1 - x] - Log[1 + x]))^2;
integrand= part1*part2;


Then define this alternating function (it will come in handy in a second):

altFun[n_] = 1/2 (1 - (-1)^n (-1 + Log[x]) + Log[x]);


observe the coefficients of the expansion of part2 at $$x=0$$ follow a kind of regular pattern when divided by altFun:

expansionPart2 = (Table[{n,
SeriesCoefficient[(-Log[x] + 2 (Log[1 - x] - Log[1 + x]))^2, {x,
0, n}]/altFun[n]}, {n, 0, 30}])

(*{{0, Log[x]^2}, {1, 8}, {2, 16}, {3, 8/3}, {4, 32/3}, {5, 8/5}, {6,
368/45}, {7, 8/7}, {8, 704/105}, ... *)


The odd n terms are just $$\frac{8}{n}$$. We can find the even terms by using FindSequenceFunction:

odds[n_] = 8/n;

evens[n_] = FindSequenceFunction[no[[3 ;; All ;; 2]], n]

(*-((16 (-2 + PolyGamma[0, 3/2] - PolyGamma[0, 1/2 + n/2]))/n)*)


and the $$n=0$$ term is $$\mathrm{log[x]^2}$$.

we can now create a function that generates the $$n$$th expansion term at $$x=0$$ for $$part2$$:

seqFun[n_] =
FullSimplify[
PiecewiseExpand[
x^n*altFun[n]*
Piecewise[{{odds[n], Mod[n, 2] == 1}, {evens[n],
Mod[n, 2] == 0 && n > 0}, {Log[x]^2, n == 0}}]]]



This results in

$$$$\mathrm{seqFun[n]} = \left\{ \begin{array}{lr} 8 x^n \frac{\mathrm{log[x]}}{n}, & \text{odd n } \\ (16 x^n (\mathrm{HarmonicNumber}[1/2 (-1 + n)] + \mathrm{Log[4]}))/n, & \text{even n, n>0 } \\ (\mathrm{Log[x]}^2 & \text{n = 0 } \end{array} \right\}$$$$

we now can multiply seqFun by part1 and get integral for each term:

seqInt[n_] =
PiecewiseExpand[part1*seqFun[n]];
indef = Integrate[serInt[n], x];
x0=1/GoldenRatio^2;
defInt =
FullSimplify[PiecewiseExpand[(indef /. x -> 1) - (indef /. x -> x0)],
n >= 1]


This yields a very complicated expression that doesn't format well here: $$\begin{array}{cc} \{ & \begin{array}{cc} \frac{32 \left(\sqrt{5}+1\right)^{-2 (n+1)} \left(H_{\frac{n-1}{2}}+\log (4)\right) \left(-4^{n+1} \left(\Phi \left(\frac{1}{\phi ^2},3,n+1\right)+2 \text{csch}^{-1}(2) \Phi \left(\frac{1}{\phi ^2},2,n+1\right)\right)-\left(\left(\sqrt{5}+3\right) \left(\sqrt{5}+1\right)^{2 n} \left(4 \text{csch}^{-1}(2)^2 B_{\frac{1}{\phi ^2}}(n+1,0)+\psi ^{(2)}(n+1)\right)\right)\right)}{n} & (n \bmod 2)=0 \\ \frac{8 \left(3\ 2^{2 n+3} \left(\sqrt{5}+1\right)^{-2 (n+1)} \left(\Phi \left(\frac{2}{\sqrt{5}+3},4,n+1\right)+2 \text{csch}^{-1}(2) \left(\Phi \left(\frac{2}{\sqrt{5}+3},3,n+1\right)+\text{csch}^{-1}(2) \Phi \left(\frac{2}{\sqrt{5}+3},2,n+1\right)\right)\right)+8 \text{csch}^{-1}(2)^3 B_{\frac{1}{\phi ^2}}(n+1,0)-\psi ^{(3)}(n+1)\right)}{n} & (n \bmod 2)=1 \\ \end{array} \\ \end{array}$$

This is a screenshot of the output which looks a little easier to read: You may notice that I ran FullSimplify on defInt with the assumption $$n\geq1$$. This is because indef/.{x->1,n->0} results in Indeterminate, but we can evaluate the $$n=0$$ case separately and take the limit as $$x->1$$:

int0 = Integrate[seqInt[0], x];

p0 = Limit[int0, x -> 1] - (int0 /. x -> x0)
(* 16 Log[1 - 1/GoldenRatio^2] Log[GoldenRatio]^4 -
32 Log[GoldenRatio]^3 PolyLog[2, 1/GoldenRatio^2] -
48 Log[GoldenRatio]^2 PolyLog[3, 1/GoldenRatio^2] -
48 Log[GoldenRatio] PolyLog[4, 1/GoldenRatio^2] -
24 PolyLog[5, 1/GoldenRatio^2] + 24 Zeta[5] *)


So now we have calculated the definite integral defInt for each term, and we just need to sum from $n=1,...,\infty$ to get the result:

result = p0 + Sum[defInt, {n, 1, Infinity}]


The infinite sum unfortunately does not evaluate for me. But we can plot the partial sum and see it approaches the value of NIntegrate:

partSum := p0 + Sum[defInt, {n, 1, nMax}];
nResult = NIntegrate[integrand, {x, x0, 1}];
DiscretePlot[{nResult, partSum}, {nMax, 1, 300, 10}, Joined -> True,
Filling -> None]


I am not sure how feasible it is to find a closed form to DiscreteLimit[partSum, nMax -> Infinity], but this is at least much closer to a closed form.

– Max
Commented Jun 27, 2023 at 2:19
• I will update answer if I make anymore progress. I am also looking at if I can use the series coefficients from AsymptoticIntegrate and plug them into FindGeneratingFunction to get a closed form for the indefinite integral, but I have not had luck with this yet.
– ydd
Commented Jun 27, 2023 at 2:21