# Inverse Laplace Transform of $\frac{\tan ^{-1}\left(\sqrt{s}\right)}{\sqrt{s}}$

How do I obtain the Inverse Laplace transform of the following expression? $$\frac{\tan ^{-1}\left(\sqrt{s}\right)}{\sqrt{s}}$$

Using Mariusz Iwaniuk recipes with Feynmann trick and "Mellin Transform trick" in earlier question I get the same result as inverse Laplace Transform of $$\frac{\tan ^{-1}\left(\frac{1}{\sqrt{s}}\right)}{\sqrt{s}}$$ which seems wrong since these two functions are distinct.

ClearAll["Global*"];
ilaplace[expr_] := InverseLaplaceTransform[expr, s, t];

(*Custom Laplace transforms from "Hypergeometric" post*)

(*Mariusz solution from \
https://mathematica.stackexchange.com/a/285338/217*)
augmentInv[expr_, var_] :=
Module[{a1, a2, a3, a4, expra},
expra = expr /. {ArcTan[a1_] -> ArcTan[a1/var],
Log[a1_] -> Log[a1/var],
Hypergeometric2F1[a1_, a2_, a3_, a4_] ->
Hypergeometric2F1[a1, a2, a3, a4/var]};
If[MemberQ[ReduceFreeVariables[expra], var], expra, expra/var]];

ilaplaceMellin0[expr_] :=
Block[{expra, mellin, ilap, imellin, s, t, a},
expra = augmentInv[expr, a];
mellin = FunctionExpand@MellinTransform[expra, a, q];
ilap = InverseLaplaceTransform[mellin, s, t];
imellin = InverseMellinTransform[ilap, q, a] /. a -> 1;
FullSimplify@imellin];

SetAttributes[ilaplaceMellin0, Listable];
ilaplaceMellin[expr_] :=
Block[{dummy},
Distribute@dummy@Expand[expr] /. dummy -> ilaplaceMellin0];

(*https://zackyzz.github.io/feynman.html*)
augment[expr_, var_] :=
Module[{a1, a2, a3, a4, expra},
expra = expr /. {ArcTan[a1_] -> ArcTan[a1 var],
Log[a1_] -> Log[a1 var],
Hypergeometric2F1[a1_, a2_, a3_, a4_] ->
Hypergeometric2F1[a1, a2, a3, a4 var]};
If[MemberQ[ReduceFreeVariables[expra], var], expra, var*expra]];

ilaplaceFeynmann0[expr_] :=
Block[{repl, ilap, a1, a2, a3, a4, a}, expra = augment[expr, a];
ilap = InverseLaplaceTransform[D[expra, a] // Factor, s, t];
Assuming[{t > 0}, Integrate[ilap, {a, 0, 1}]]];
SetAttributes[ilaplaceFeynmann0, Listable];
ilaplaceFeynmann[expr_] :=
Block[{dummy},
Distribute@dummy@Expand[expr] /. dummy -> ilaplaceFeynmann0];

expr1 = ArcTan[Sqrt[2]/Sqrt[s]]/(Sqrt[2] Sqrt[s]);
expr2 = Hypergeometric2F1[1, 1/3, 4/3, s];

expr3 = ArcTan[1/Sqrt[s]]/ Sqrt[s];
expr4 = ArcTan[Sqrt[s]]/ Sqrt[s];

exprs = {expr1, expr2, expr3, expr4};
methods = {ilaplace, ilaplaceFeynmann, ilaplaceMellin};
results = Outer[TimeConstrained[#1[#2], 10] &, methods, exprs];

TableForm[results,
TableHeadings -> {{"default", "Feynmann", "Mellin"}, exprs}]


• Are you asking why you are not getting the result you want using these methods/code you are using? Since using the direct command InverseLaplaceTransform in Mathematica works as is as shown in the answer below? Commented Jun 23, 2023 at 23:40
• @Nasser you are right, I'm getting incorrect result due to augmentation method, which was required in order to perform inverse Laplace of ArcTan[1/Sqrt[s]]/Sqrt[s]. Here it appears default method works Commented Jun 24, 2023 at 0:19
• Mathematica 13.3 expanded on LaplaceTransform and InverseLaplaceTransform capabilities significantly but cannot solve this one it seems. Commented Jun 30, 2023 at 18:50

InverseLaplaceTransform[ArcTan[Sqrt[s]]/Sqrt[s], s, t] //Simplify gives
$$\frac{e^{-t}-1}{2 t}$$.
• Actually on V 13.2.1 only Simplify not FullSimplify is needed. I wonder in this case which version of Mathematica OP used. Commented Jun 23, 2023 at 23:37
• Thanks it appears the default method works on this expression (the extra tricks in code were needed to invert ArcTan[1/Sqrt[s]]/Sqrt[s] but apparently need extra work) Commented Jun 24, 2023 at 0:27
• Going the other way LaplaceTransform[(Exp[-t] - 1)/(2 t), t, s] // Simplify produces 1/2 Log[s/(1 + s)]` in Mathematica 13.3 so is this correct? It could be, as there are Logs if we TrigToExp of the arctan expression but I can't tell. Commented Jun 30, 2023 at 18:42