InverseFourierSinTransform on Mathematica did not give a result

Question

I am trying to solve the linear Schrödinger equation with the Fourier transform. I have difficulty making the corresponding graph when I solve the problem numerically. Can you explain to me what is my mistake in the following code?

\!\(\*OverscriptBox[\(u\), \(^\)]\)[\[Omega]_, t_] = -((
  2 E^(-I t v \[Omega]^2) (-T0 + 
     E^(I t v \[Omega]^2)
       T0 + \[Omega] DawsonF[\[Omega]/2]))/\[Omega])

u[x_, t_] = InverseFourierSinTransform[
\!\(\*OverscriptBox[\(u\), \(^\)]\)[\[Omega], t], \[Omega], x, 
  FourierParameters -> {1, -1}, Assumptions -> {x > 0}]

Then I tried to create the graph

T0 = 1;
Plot[Abs[u[x, t]]^2, {x, 0, 20}, PlotRange -> All]

You can download the notebook of my project from Wolfram Community

---

ps. Consider using this input as more readable (edit by Nasser)

OverHat[u][ω_, t_] = -((2*(-T0 + E^(I*t*v*ω^2)*T0 + ω*DawsonF[ω/2]))/E^(I*t*v*ω^2)/ω)
u[x_, t_] = InverseFourierSinTransform[OverHat[u][ω, t], ω, x, FourierParameters -> {1, -1}, Assumptions -> {x > 0}]

Answer 1

OverHat[u][\[Omega]_, t_] = -((2*(-T0 + 
       E^(I*t*v*\[Omega]^2)*T0 + \[Omega]*DawsonF[\[Omega]/2]))/
   E^(I*t*v*\[Omega]^2)/\[Omega]) // FunctionExpand // Expand

(*-((2 T0)/\[Omega]) + (2 E^(-I t v \[Omega]^2) T0)/\[Omega] - 
E^(-(\[Omega]^2/4) - I t v \[Omega]^2) Sqrt[\[Pi]] Erfi[\[Omega]/2]*)

InverseFourierSinTransform[#, \[Omega], x, FourierParameters -> {1, -1}, Assumptions -> {x > 0}] & /@OverHat[u][\[Omega], t]

Mathematica can't compute: $\sqrt{\pi } \text{erfi}\left(\frac{\omega }{2}\right) \left(-e^{-\frac{\omega ^2}{4}-i t v \omega ^2}\right)$ term.

We use identity:$$\text{erfi}\left(\frac{\omega }{2}\right)=\int_0^{\infty } \frac{2 e^{-z^2+\frac{\omega ^2}{4}} \sin (z \omega )}{\sqrt{\pi }} \, dz$$ then:

Integrate[InverseFourierSinTransform[
E^(-(\[Omega]^2/4) - I t v \[Omega]^2) Sqrt[\[Pi]] *(
2 E^(-z^2 + \[Omega]^2/4) Sin[z \[Omega]])/Sqrt[\[Pi]] // 
FullSimplify, \[Omega], x, FourierParameters -> {1, -1}, 
Assumptions -> {x > 0, z >= 0}], {z, 0, Infinity}, 
Assumptions -> x > 0]

(*ConditionalExpression[-(E^(x^2/(-1 - 
(4*I)*t*v))*Sqrt[I*t*v]*Sqrt[(I*t*v - 4*t^2*v^2)^(-1)]*Erf[Sqrt[((4*I)*t*v - 16*t^2*v^2)^(-1)]*x]), Im[1/(t*v)] > -4]*)

So:

$$u(x,t)=-\text{T0} \text{erf}\left(\frac{x}{2 \sqrt{i t v}}\right)-e^{\frac{x^2}{-1-4 i t v}} \sqrt{i t v} \sqrt{\frac{1}{i t v-4 t^2 v^2}} \text{erf}\left(\sqrt{\frac{1}{4 i t v-16 t^2 v^2}} x\right)+\text{T0} \text{sgn}(x)$$

 u[x_, t_] = -T0 Erf[x/(2 Sqrt[I t v])] - 
 E^(x^2/(-1 - 4 I t v)) Sqrt[I t v] Sqrt[1/(I t v - 4 t^2 v^2)]
 Erf[Sqrt[1/(4 I t v - 16 t^2 v^2)] x] + T0 Sign[x]

 T0 = 1; v = 1;(*Assumed parameters *)
 Plot[Abs[u[x, 1/5]]^2, {x, 0, 5}, PlotRange -> All](*for t=1/5*)