Integrating over Implicit region, trash output

Question

I want to compute lebesgue measure of region {$(x,y,z) \in R^3 : (x^2+y^2+z^2+3)^2 \leq 16(x^2+y^2), y>0$}. So I type:

S = ImplicitRegion[(x^2 + y^2 + z^2 + 3)^2 <= 16 (x^2 + y^2) &&  y > 0, {x, y, z}]

Integrate[1, {x, y, z} \[Element] S]

But I get:

2 Integrate[Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, -3, -1}, {y, 0, Sqrt 9 - x^2]},Assumptions -> True, GenerateConditions -> Automatic] + 2 Integrate[Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, -1, 0}, {y, Sqrt[  1 - x^2], Sqrt[9 - x^2]}, Assumptions -> True,  GenerateConditions -> Automatic] +  2 Integrate[ Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, 0, 1}, {y, Sqrt[ 1 - x^2], Sqrt[9 - x^2]}, Assumptions -> True,  GenerateConditions -> Automatic] + 2 Integrate[ Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, 1, 3}, {y, 0, Sqrt[ 9 - x^2]}, Assumptions -> True, GenerateConditions -> Automatic]

What is wrong?

Answer 1

Nothing is wrong. You presented the problem in cartesian coordinates, and Mathematica followed your lead. To analyze the region in cartesian coordinates for integration requires a decomposition into four subregions, shown here:

n = 0;
2 Integrate[
     Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, -3, -1}, {y, 0, 
      Sqrt [9 - x^2]}, Assumptions -> True, 
     GenerateConditions -> Automatic] + 
   2 Integrate[
     Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, -1, 0}, {y, 
      Sqrt[1 - x^2], Sqrt[9 - x^2]}, Assumptions -> True, 
     GenerateConditions -> Automatic] + 
   2 Integrate[
     Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, 0, 1}, {y, 
      Sqrt[1 - x^2], Sqrt[9 - x^2]}, Assumptions -> True, 
     GenerateConditions -> Automatic] + 
   2 Integrate[
     Sqrt[-3 - x^2 - y^2 + 4 Sqrt[x^2 + y^2]], {x, 1, 3}, {y, 0, 
      Sqrt[9 - x^2]}, Assumptions -> True, 
     GenerateConditions -> Automatic] // Hold;
List @@@ % /. 
   Integrate :> 
    With[{n = ++n}, 
     Plot3D[#1, #2, #3, PlotStyle -> ColorData[97][n]]/2 &] // 
  ReleaseHold // Show[#, PlotRange -> All, BoxRatios -> Automatic] &

Doing the integrals in cartesian coordinates with this decomposition is difficult, apparently too difficult for Integrate. Of course, in polar coordinates, it's much easier.

s = ImplicitRegion[(x^2 + y^2 + z^2 + 3)^2 <= 16 (x^2 + y^2) && 
   y > 0, {x, y, z}]; 
IntegrateChangeVariables[
  Inactive[Integrate][1, {x, y, z} \[Element] s], {r, \[Theta], h}, 
  "Cartesian" -> "Cylindrical"] // Activate

(*  2 \[Pi]^2  *)

Answer 2

• We using cylinder coordinate,that is x=r*Cos[θ]; y=r*Sin[θ];z=z; r>0; 0 <= θ <= π.

expr=(x^2 + y^2 + z^2 + 3)^2 <= 16 (x^2 + y^2) /. {x -> r*Cos[θ], 
   y -> r*Sin[θ]} // FullSimplify

(3 + r^2 + z^2)^2 <= 16 r^2.

preg=ParametricRegion[{{r*Cos[θ], r*Sin[θ], 
   z}, (3 + r^2 + z^2)^2 <= 16 r^2 && 0 <= θ <= π && 
   r > 0}, {r, θ, z}];
preg // Volume
Integrate[1, {r, θ, z} ∈ preg]

2 π^2

2 π^2

• Since we can rewrite the original region as the form

(Sqrt[x^2 + y^2] - 2)^2 + z^2 <= 1

If we set r=Sqrt[x^2 + y^2], the above equation become Disk[{2,0},1],it means that the original solid is half of the revolution solid of such disk.

It can also describe as a half of FilledTorus with the inner radius 2-1 and the outer radius 2+1.

FilledTorus[{0, 0, 0}, {2 + 1, 2 - 1}] // Volume;
%/2

4 π^2

2 π^2

Graphics3D[{FaceForm[Orange, Cyan], 
  FilledTorus[{0, 0, 0}, {2 - 1, 2 + 1}]}, 
 PlotRange -> {{-3, 3}, {0, 3}, {-1, 1}}, BoxRatios -> Automatic]