I typed
StreamPlot[{y, x-x^3-0.3y+0.5Cos[1.25t]}, {x, -2.5, 2.5}, {y, -2.5, 2.5}]
but all I got was a blank plot. What did I do wrong and can I fix it?
$\begingroup$
$\endgroup$
2
-
$\begingroup$ But I don't want to specify any value for $t$. Is there any other function I should use? Anything in 3D? $\endgroup$– superAnnoyingUserJul 15, 2013 at 14:44
-
$\begingroup$ Related (similar system): mathematica.stackexchange.com/questions/14160/… $\endgroup$– Michael E2Dec 25, 2017 at 0:13
Add a comment
|
3 Answers
$\begingroup$
$\endgroup$
1
If you don't want to specify t there is e.g. ListAnimate (or Animate etc.)
ListAnimate[
Table[ StreamPlot[{y, x - x^3 - 0.3 y + 0.5 Cos[1.25 t]},
{x, -2.5, 2.5}, {y, -2.5, 2.5}], {t, 0.1, 2, 0.05}]
]
-
$\begingroup$ it looks like that would make an interesting bifurcation plot ... $\endgroup$– rcollyerJul 15, 2013 at 16:32
$\begingroup$
$\endgroup$
2
Or you could use the beautiful LineIntegralConvolutionPlot function - Documentation center link: Here
Manipulate[
LineIntegralConvolutionPlot[{y,
x - x^3 - 0.3 y + 0.5 Cos[1.25 t]}, {x, -2.5, 2.5}, {y, -2.5, 2.5},
ColorFunction -> ColorData["Rose"], StreamPoints -> 10,
StreamStyle -> White], {t, -2.5, 2.5}]
$\begingroup$
$\endgroup$
...Is there any other function I should use? Anything in 3D? – Student
One might stack the phase fields for a sequence of values of t, but as you can see, Artes's animation might be a better visualization.
Show[
Table[
Graphics3D[
First@(StreamPlot[{y, x - x^3 - 0.3 y + 0.5 Cos[1.25 t]},
{x, -2.5, 2.5}, {y, -2.5, 2.5},
StreamStyle -> Hue[Rescale[t, {-1.2, 1.2}]]] /.
Arrow[pts_] :>
Arrow[Transpose[Transpose@pts~Append~ConstantArray[t, Length@pts]]])],
{t, -1, 1, 0.5}],
Axes -> True, BoxRatios -> {1, 1, 1}]
See also some of the answers to this question for more on combining 2D plots into 3D graphics.
answered Jul 15, 2013 at 16:07