# How to merge the lines in the following way?

Consider the following curves:

Bound1temp =
RegionPlot[
10^13*10^(2 y)*(10^x/90)^4*Sqrt[1 - 10^(2 x)/90^2.] >= 1, {x,
Log10[0.01], Log10[90]}, {y, -11, 0}];
Bound1 = {10^#[[1]], 10^#[[2]]} & /@
Partition[
Flatten[Cases[Normal@Bound1temp, Line[x_] :> x, Infinity]], 2];
Bound2temp =
RegionPlot[
10^20*10^(2 y)*Sqrt[
1 - 10^(4 x)/6^4.] (Exp[-10^7.*10^(6*x)*10^(2*y)] -
Exp[-(10^7 + 10)*10^(6*x)*10^(2*y)]) >= 1, {x, Log10[0.01],
Log10[6.]}, {y, -11, 0}];
Bound2 = {10^#[[1]], 10^#[[2]]} & /@
Partition[
Flatten[Cases[Normal@Bound2temp, Line[x_] :> x, Infinity]], 2];
ListLogLogPlot[{Bound1, Bound2}]


Could you please tell me whether it is possible to merge them such that their intersection would be removed, i.e. to get the following red line?

Let us assume that we have only Bound1 and Bound2, but not the underlying functions/conditions used to obtain them.

pred1 = 10^13*10^(2 y)*(10^x/90)^4*Sqrt[1 - 10^(2 x)/90^2.] >= 1;

pred2 = 10^20*10^(2 y)*
Sqrt[1 - 10^(4 x)/6^4.] (Exp[-10^7.*10^(6*x)*10^(2*y)] -
Exp[-(10^7 + 10)*10^(6*x)*10^(2*y)]) >= 1;

rp12 = RegionPlot[Or[pred1, pred2], {x, Log10[0.01], Log10[90]}, {y, -11, 0}];

bound12 = Cases[Normal @ rp12, Line[x_] :> 10^x, All];

ListLogLogPlot @ bound12


Update: "what to do if Bound1 and Bound2 are pre-generated, i.e., I do not have access to the initial functions used to extract the contours?"

lllp = ListLogLogPlot[{Bound1, Bound2}];

boundaryline =  RegionBoundary[
RegionUnion @@ Cases[lllp, Point[x_] :> Polygon[x], All]];

Show[lllp, Prolog ->
{AbsoluteThickness[10],JoinForm["Round"], Green, boundaryline}]


• Thanks! But what to do if Bound1 and Bound2 are pre-generated, i.e., I do not have access to the initial functions used to extract the contours? May 31 at 9:51