3
$\begingroup$

Trying to answer this question related to the calculation of $$I_k=\int_1^\infty x^ke^{-x}\ln(x+a)\,dx$$ which, at least to me, looks problematic.

What is missing for a complete answer is to indentify the following polynomials

 P[1]=1;
 P[2]=x-4;
 P[3]=x^2-5 x+17;
 P[4]=x^3-6 x^2+25 x-84;
 P[5]=x^4-7 x^3+35 x^2-141 x+485;
 P[6]=x^5-8 x^4+47 x^3-226 x^2+911 x-3236;
 P[7]=x^6-9 x^5+61 x^4-345 x^3+1647 x^2-6703 x+24609;
 P[8]=x^7-10 x^6+77 x^5-504 x^4+2825 x^3-13502 x^2+55581 x-210572;
 P[9]=x^8-11 x^7+95 x^6-709 x^5+4601 x^4-25751 x^3+123475 x^2-513929 x+2004749;
 P[10]=x^9-12 x^8+115 x^7-966 x^6+7155 x^5-46336 x^4+259467 x^3-1248450 x^2+5248891 x-21033900;

They show quite simple patterns but I am unable to see what they are.

So, my question is :

`Is there a way to find what they are or at least find the recurrence relation they obey ?`
$\endgroup$
4
  • 1
    $\begingroup$ If you put x->0 and look for the sequence in Encyclopedia of integer sequences oeis.org then for a free term you will find Table[(-1)^(n + 1)*n!*E*Sum[Gamma[k, 1]/k!, {k, 1, n}], {n, 1, 10}] . $\endgroup$
    – Acus
    May 17, 2023 at 6:16
  • 1
    $\begingroup$ @Acus: But free terms form {1, -4, 17, -84, 485, -3236, 24609, -210572, 2004749}, not that you refer to. A recurrence between polynomials implies a recurrence between their free terms, but the code of Maple with(gfun); l := [1, -4, 17, -84, 485, -3236, 24609, -210572, 2004749]; rec := listorec(l, u(n)); fails. $\endgroup$
    – user64494
    May 17, 2023 at 6:23
  • $\begingroup$ Sorry, indeed. But then if the sequence is not known in oeis.org problem probably is very complicated. $\endgroup$
    – Acus
    May 17, 2023 at 6:49
  • $\begingroup$ Here is the closest result in OEIS. $\endgroup$
    – user64494
    May 17, 2023 at 15:08

1 Answer 1

4
$\begingroup$

[ Note :

The result at the end depends on a function with a very complicated recurrence formula which I will post here in advance, after a short description, in the event that the final result might not be of much interest because of the complexity. All displayed LaTeX formulas are automatically generated by Mathematica.

In the formula below, $E_1(x)$ is an exponential integral function defined as $E_n(z)=\int_1^{\infty } \frac{e^{t (-z)}}{t^n} \, dt$ . In the following, the k defined in your integral sequence will be denoted as n. The final result depends on a sequence r1 which will be defined below. The recurrence formula itself depends on n (your k in the integral sequence). I do not know how this sequence relates to your sequence of polynomials. I have only tried finding a recurrence formula for the sequence of integrals provided in your post. Considering an auxiliary integer m , in order to define the recurrence, the recurrence formula for the fairly complicated r1 that appears in the final result is :

$$\left\{a \left((m-n+2) \text{r1}(m+2) \left(a^2 (m+2)+a (m (4 m-2 n+15)-3 (n-5))+(m (m+6)+7) (m-n+1)\right)+a (m+2) (\text{r1}(m+3) (a (-2 m+n-5)-2 (m+3) (m-n+2))+a (m+3) \text{r1}(m+4))\right)+(a+1) (m+1) (m-n) (m-n+1) (m-n+2) \text{r1}(m)=(m-n+1) (m-n+2) \text{r1}(m+1) \left(a^2 (2 m+3)+a \left(2 m^2-(m+1) n+7 m+7\right)+(m+1) (m-n)\right),\text{r1}(-1)=0,\text{r1}(0)=0,\frac{E_1(a+1)}{n!}=\text{r1}(1),\text{r1}(2)=\frac{E_1(a+1)-\frac{n \left(E_1(a+1)+e^{-a-1}\right)}{a}}{n!}\right\}$$

end of the note ]


In the following, I apply the exponential generating function to the sequence and switch the series from the generating function with the integral in the sequence. I did not check if this switch is justified. I also did not identify the polynomial P in your post but perhaps some parts of the derivation below will be of some help. Note that the final result involves a very complicated recurrence formula.

The exponential generating function of the integrand is :

ExponentialGeneratingFunction[x^k*Exp[-x]*Log[x + a], k, s]

Output in LaTeX :

$$e^{s x-x} \log (a+x)$$

Output in Mathematica :

E^(-x + s x) Log[a + x]

Integrating the generating function :

result=Integrate[E^(-x + s x) Log[a + x], {x, 1, Infinity}]

Output in LaTeX :

$$\frac{e^{a-a s} (-E_1(-((a+1) (s-1)))-\log (-((a+1) (s-1)))+\log (a+1)+\log (1-s))-e^{s-1} \log (a+1)}{s-1}\text{ if }\Re(s)<1$$

Output in Mathematica :

ConditionalExpression[
 1/(-1 + s) (-E^(-1 + s) Log[1 + a] + 
    E^(a - a s) (-ExpIntegralE[1, -((1 + a) (-1 + s))] + Log[1 + a] + 
       Log[1 - s] - Log[-((1 + a) (-1 + s))])), Re[s] < 1]

To retrieve the sequence we first formally compute the coefficients of the series. Note that, if the derivation before was justified, given the definition of the exponential generating function, the original sequence is obtained from these coefficients by multiplying them by factorial n.

First, we compute the coefficients without multiplying by factorial n :

coefficientsDividedByFactorial = 
SeriesCoefficient[Refine[result, Re[s] < 1], {s, 0, n}];

We then multiply by factorial n and define functions r0 and r1 for the recurrence formulas which are defined after. Strangely, r0[1+n] in the result turns out to be 0 after solving the recurrence formula. The recurrence formula for r1 seems to be very complicated :

definitions=<||>;
counter=0;
coefficientsDividedByFactorial2=
(n!)*Refine[coefficientsDividedByFactorial,n>1]/.m_DifferenceRoot 
:>(var=Symbol["r"<>ToString[counter]];AppendTo[definitions,var->m];
counter=counter+1; var)

Output in LaTeX :

$$ n! \left(\frac{e^a (-a)^{n-1}}{(n-1)!}+\frac{e^a n (-a)^n}{a n!}+e^a \log (a+1) \text{r0}(n+1)+e^a (-a)^n \text{r1}(n+1)+\frac{\log (a+1) \Gamma (n+1,1)}{\Gamma (n+1)}-\frac{\log (a+1) \Gamma (n+1,-a)}{\Gamma (n+1)}\right) $$

Output in Mathematica :

n! (((-a)^(-1 + n) E^a)/(-1 + n)! + ((-a)^n E^a n)/(a n!) + (
   Gamma[1 + n, 1] Log[1 + a])/Gamma[1 + n] - (
   Gamma[1 + n, -a] Log[1 + a])/Gamma[1 + n] + 
   E^a Log[1 + a] r0[1 + n] + (-a)^n E^a r1[1 + n])

r0 has the following recurrence formula :

(r0 /. definitions)[[1]][\[FormalY], \[FormalN]] /. \[FormalY] -> 
   r0 /. \[FormalN] -> m

Output in LaTeX :

$${(m - n) r0[m] + (-a - m + n) r0[1 + m] + a r0[2 + m] == 0, r0[0] == 0, r0[1] == (-a)^n/n!}$$

Output in Mathematica :

{(m - n) r0[m] + (-a - m + n) r0[1 + m] + a r0[2 + m] == 0, 
 r0[0] == 0, r0[1] == (-a)^n/n!}

It seems Mathematica can solve the recurrence formula for r0 but strangely r0[1 + n] in the formula for the coefficients seems to be 0 :

r0[m + 1] /. definitions // FunctionExpand // ReplaceAll[m -> n] // 
 Simplify[#, n ∈ Integers] &

output :

0

The recurrence formula for r1 seems to be very hard :

(r1 /. definitions)[[1]][\[FormalY], \[FormalN]] /. \[FormalY] -> 
    r0 /. \[FormalN] -> m // FullSimplify

Output in LaTeX :

$$\left\{a \left((m-n+2) \text{r1}(m+2) \left(a^2 (m+2)+a (m (4 m-2 n+15)-3 (n-5))+(m (m+6)+7) (m-n+1)\right)+a (m+2) (\text{r1}(m+3) (a (-2 m+n-5)-2 (m+3) (m-n+2))+a (m+3) \text{r1}(m+4))\right)+(a+1) (m+1) (m-n) (m-n+1) (m-n+2) \text{r1}(m)=(m-n+1) (m-n+2) \text{r1}(m+1) \left(a^2 (2 m+3)+a \left(2 m^2-(m+1) n+7 m+7\right)+(m+1) (m-n)\right),\text{r1}(-1)=0,\text{r1}(0)=0,\frac{E_1(a+1)}{n!}=\text{r1}(1),\text{r1}(2)=\frac{E_1(a+1)-\frac{n \left(E_1(a+1)+e^{-a-1}\right)}{a}}{n!}\right\}$$

Output in Mathematica :

    {(1 + a) (1 + m) (m - n) (1 + m - n) (2 + m - n) r1[m] + 
   a ((a^2 (2 + m) + 
         a (m (15 + 4 m - 2 n) - 3 (-5 + n)) + (7 + m (6 + m)) (1 + 
            m - n)) (2 + m - n) r1[2 + m] + 
      a (2 + m) ((-2 (3 + m) (2 + m - n) + a (-5 - 2 m + n)) r1[
           3 + m] + a (3 + m) r1[4 + m])) == (1 + m - n) (2 + m - 
     n) (a^2 (3 + 2 m) + (1 + m) (m - n) + 
     a (7 + 7 m + 2 m^2 - (1 + m) n)) r1[1 + m], r1[-1] == 0, 
 r1[0] == 0, ExpIntegralE[1, 1 + a]/n! == r1[1], 
 r1[2] == (
  ExpIntegralE[1, 1 + a] - (n (E^(-1 - a) + ExpIntegralE[1, 1 + a]))/
   a)/n!}
$\endgroup$
12
  • 1
    $\begingroup$ Integrate[E^(-x + s x) Log[a + x], {x, 1, Infinity}] produces $$\fbox{$\frac{e^{-a s-1} \left(-e^{a+1} G_{1,2}^{2,0}\left(-((a+1) (s-1))\left| \begin{array}{c} 1 \\ 0,0 \\ \end{array} \right.\right)+\left(e^{a+1}-e^{a s+s}\right) \log (a+1)+e^{a+1} (\log (1-s)-\log (-((a+1) (s-1))))\right)}{s-1}\text{ if }\Re(s)<1$} $$ in few minutes. $\endgroup$
    – user64494
    May 17, 2023 at 10:27
  • $\begingroup$ In 13.2.1 Integrate[E^(-x + s x) Log[a + x], {x, 1, Infinity}, GenerateConditions -> False] results in $$\frac{e^{-a s-1} \left(-e^{a+1} G_{1,2}^{2,0}\left(-((a+1) (s-1))\left| \begin{array}{c} 1 \\ 0,0 \\ \end{array} \right.\right)+\left(e^{a+1}-e^{a s+s}\right) \log (a+1)+e^{a+1} (\log (1-s)-\log (-((a+1) (s-1))))\right)}{s-1} .$$ What version of MMA do you use? $\endgroup$
    – user64494
    May 17, 2023 at 10:30
  • $\begingroup$ @user64494. Thanks ! I am using version 3.1.0.0 – I would refer to avoid Meijer-G function. $\endgroup$ May 17, 2023 at 14:34
  • $\begingroup$ @userrandrand. Tnaks ! May I ask you a favor ? Could you type for me the recurrence equations ? Being blind, I am just unable to do it (I always have this problem). In advance, thanks $10^{123456789}$ times & cherrs. :-) $\endgroup$ May 17, 2023 at 14:43
  • $\begingroup$ @user64494 I am using 13.2.0 on Linux maybe FunctionExpand converts that to the exponential integral function $\endgroup$ May 17, 2023 at 18:49

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.