Can an InverseLaplaceTransform of this expression be computed?

Question

I'm looking to compute the Inverse Laplace Transform of the expression below for $0\le b\le 1$

$$\frac{\tan ^{-1}\left(\frac{\sqrt{2}}{\sqrt{s}}\right)}{\sqrt{2} \sqrt{s} \left(1-\frac{1}{4} b \left(2-\sqrt{2} \sqrt{s} \tan ^{-1}\left(\frac{\sqrt{2}}{\sqrt{s}}\right)\right)\right)}$$

I found some ways to compute this for $b=0$, is there a way to do this for any other values of $b$, such as $b=1$?

Here's the computation for $b=0$

Block[{$Assumptions = {}, b = 0},
 InverseLaplaceTransform[ArcTan[Sqrt[2]/Sqrt[s]]/(
  Sqrt[2] Sqrt[
   s] (1 - 1/4 b (2 - Sqrt[2] Sqrt[s] ArcTan[Sqrt[2]/Sqrt[s]]))), s, t]
 ]

Background: this is symbolic formula for $E_h[f]$ where f is solution of differential equation in this post for $a=-2$

Answer 1

Mathematica 13.2.0.0 gives an answer if you avoid the special case of b=0.

Block[{$Assumptions = {0<b<=1}},
InverseLaplaceTransform[ArcTan[Sqrt[2]/Sqrt[s]]/(Sqrt[2] Sqrt[s] (1 - 1/4 b (2 - Sqrt[2] Sqrt[s] ArcTan[Sqrt[2]/Sqrt[s]]))), s, t]]

(*((8 - 4*b)*Sqrt[Pi/2]*Erf[Sqrt[2]*Sqrt[t]])/
   (Sqrt[t]*(4 + b*(-2 + Log[8]) - b*Log[-2 - s])²)*)

For b=0, The Block you posted gives:

(*(-(Pi*Erf[Sqrt[2]*Sqrt[t]]) - 
   4*I*t*HypergeometricPFQ[{1, 1}, {3/2, 2}, -2*t])/
   (2*Sqrt[2*Pi]*Sqrt[t])*)

Answer 2

Here's the beginnings of a numeric approach. Will need to confirm singular points, and convergence speed along the contour.

Firse consider the inverse transform contour integral:

$$ \displaystyle \mathscr{L}^{-1}\{F(s)\}(t)=\frac{1}{2 \pi i }\lim_{\beta \to\infty}\mathop{\int}_{\gamma-i\beta}^{\gamma+i\beta} e^{st} \frac{\tan ^{-1}\left(\frac{\sqrt{2}}{\sqrt{s}}\right)}{\sqrt{2} \sqrt{s} \left(1-\frac{1}{4} b \left(2-\sqrt{2} \sqrt{s} \tan ^{-1}\left(\frac{\sqrt{2}}{\sqrt{s}}\right)\right)\right)} d\beta $$ with $s=\gamma+i\beta$ and $\gamma$ greater than the real part of all singularities of the integrand. So that as far as I can tell, the only singularity is the origin but need to investigate this more to make sure the path is correct. So let $\gamma=1$.

After testing a few terms in detail, the convergence appears to be quick along the path. So I'll just integrate it from $\beta=-100$ to $\beta=100$ but will need to more study this.

Edit: forgot the i from the differential ds in initial post. Note this cancels the i in coefficient of integral. Updated below

Edit2: Made a mistake with the integrand. Update 2 below. Updated below

Edit3: Third mistake with integrand. Corrected below

The following code is a comparison for the case of $b=0$ of the real numeric results to the analytic results given by David above as: $$ \text{bZero(t)}=\frac{\sqrt{\pi/2}\text{Erf}(\sqrt{2} \sqrt{t})}{2 \sqrt{t}} $$

    f[s_?NumericQ, b_?NumericQ] = 
  ArcTan[Sqrt[2]/
     Sqrt[s]]/(Sqrt[2] Sqrt[
      s] (1 - 1/4 b (2 - Sqrt[2] Sqrt[s] ArcTan[Sqrt[2]/Sqrt[s]])));

bZeroF[t_] := (Sqrt[Pi/2] Erf[Sqrt[2] Sqrt[t]])/(2 Sqrt[t]);

lTable2D = Table[
   {theT, 
    1/(2 Pi )
      NIntegrate[f[s, 0] Exp[s theT] /. s -> 1 + I t, {t, -200, 200}]},
   {theT, 0.1, 5, 0.1}
   ];

 realData = {#[[1]], Re@#[[2]]} & /@ lTable2D;
lp1 = ListPlot[realData, Joined -> True, PlotStyle -> Red, 
   PlotLegends -> Placed[{"Numeric"}, {0.9, 0.9}]];
lp2 = Plot[Re@bZeroF[t], {t, 0, 5}, PlotStyle -> Blue, 
   PlotLegends -> Placed[{"Analytic"}, {0.9, 0.7}]];
Show[{lp1, lp2}]