# Appending a single point to a LineLegend

How could the LineLegend be appended with the single black dot in the following graph?

Show[Plot[{Sin[x], x}, {x, 0, π}, Epilog -> {Black, AbsolutePointSize[5],Point[{π/8, Sin[π/8]}]},Frame -> True,FrameStyle -> Directive[Black],FrameTicks -> {{{-1, -0.5, 0, -0, 0.5, 1},None},{{0.0,π/4,π/2,π, 3 π/4,2 π},None}}, Axes -> {False, False},PlotLegends ->Placed[LineLegend[{"Sin", "x"}, LegendLayout -> {"Column",1},LegendMarkerSize -> 15], {0.2, 0.2}]],PlotRange -> {{0.0, π}, {-1, 1}},AxesLabel -> {x, "E"},LabelStyle -> {GrayLevel[0]}]


i.e., I want to make something similar to the following picture, where a single point has been shown in legends.

options = {Frame -> True, FrameStyle -> Directive[Black],
FrameTicks -> {{{-1, -0.5, 0, -0, 0.5, 1}, None},
{{0.0, π/4, π/2, π, 3 π/4, 2 π},  None}},
Axes -> False, PlotRange -> {{0.0, π}, {-1, 1}},
FrameLabel -> {x, Rotate["E", -π/2]}, LabelStyle -> {GrayLevel[0]}};


Several alternative approaches:

### I.

Post-process Plot output to modify the legends:

appendToLegend[directive_, label_] :=
ReplaceAll[LineLegend[a_, b_, c___] :>
LineLegend[Append[directive] @ a, Append[label] @ b,
Joined -> {True, True, False}, c]]

appendToLegend[Directive[Black, AbsolutePointSize[5]],  "Laughlin liquid"] @
Plot[{Sin[x], x}, {x, 0, π},
Epilog -> {Black, AbsolutePointSize[5], Point[{π/8, Sin[π/8]}]},
PlotLegends -> Placed[LineLegend[{"Sin", "x"},
LegendLayout -> {"Column", 1},
LegendMarkerSize -> 15], {0.2, 0.2}],
Evaluate @ options]


### II.

Remove Epilog from Plot and use the point coordinates in ListPlot with the desired legend and combine the two plots using Show:

Show[Plot[{Sin[x], x}, {x, 0, π},
PlotLegends ->
Placed[LineLegend[{"Sin", "x"},
LegendLayout -> {"Column", 1},
LegendMarkerSize -> 15], {0.2, 0.2}]],
ListPlot[{{π/8, Sin[π/8]}},
PlotStyle -> Directive[Black, AbsolutePointSize[5]],
PlotLegends -> Placed[{"Laughlin liquid"}, {0.2, 0.2}]],
Evaluate @ options]


### III.

1. Append the automatic color list (i.e., ColorData[97]/@{1,2}) with the desired directive for the new legend item and use this list in the first argument of LineLegend[...]
2. Append the legend labels list with the desired legend label for the new legend item
3. Add the option Joined ->{True,True, False} in LineLegend[...]
Plot[{Sin[x], x}, {x, 0, π},
Epilog -> {Black, AbsolutePointSize[5], Point[{π/8, Sin[π/8]}]},
PlotLegends -> Placed[
LineLegend[Append[Directive[PointSize@Medium, Black]][
ColorData[97] /@ {1, 2}],
{"Sin", "x", "Laughlin liquid"},
Joined -> {True, True, False},
LegendLayout -> {"Column", 1},
LegendMarkerSize -> 15], {0.2, 0.2}],
Evaluate @ options]


### IV.

1. Add a non-numeric function (e.g., Null, blah) to the function list in the first argument in Plot
2. Set the plot styles for the original functions as Automatic and, for the last one as desired (say, {PointSize[Medium], Black})
3. Append the legend labels list with the desired legend label for the new legend item
4. Add the option Joined ->{True,True, False} in LineLegend[...]
Plot[{Sin[x], x, blahblah},
{x, 0, π},
PlotStyle -> {Automatic, Automatic, Directive[PointSize[Medium], Black]},
Epilog -> {Black, AbsolutePointSize[5],  Point[{π/8, Sin[π/8]}]},
PlotLegends -> Placed[LineLegend[{"Sin", "x", "Laughlin liquid"},
Joined -> {True, True, False},
LegendLayout -> {"Column", 1},
LegendMarkerSize -> 15], {0.2, 0.2}],
Evaluate @ options]


Show[Plot[{Sin[x], x}
, {x, 0, π}
, Epilog -> {
Black, AbsolutePointSize[5]
, Point[{π/8, Sin[π/8]}]
}
, Frame -> True
, FrameStyle -> Directive[Black]
, FrameTicks -> {{{-1, -0.5, 0, -0, 0.5, 1}, None}
, {{0.0, π/4, π/2, π, 3 π/4, 2 π}, None}
}
, Axes -> {False, False}
, PlotLegends -> Placed[
LineLegend[{ColorData[97][1], ColorData[97][2], White}
, {"WC", "M=2 bubble", "Laughlin liquid" }
, LegendLayout -> {"Column", 1}
, LegendMarkers -> {"", "",
Graphics[{Black, Disk[Scaled[{0, 0}], {0.75, 0.75}]}]}
]
, {0.7, 0.4}
]
, PlotRange -> {{0.0, π}, {-1, 1}}
, FrameLabel -> {x, Rotate["E", -π/2]}
, LabelStyle -> {GrayLevel[0]}
]
]