Asymptotic series expansions for Inverse Laplace Transform?

Question

It appears that the following function, defined in terms of Inverse Laplace Transform, has a compact approximation

$$g(t)=\mathcal{L}^{-1}\left[\frac{1}{\frac{s}{2}+\frac{5 \sqrt{s}}{\sqrt{6} \tan ^{-1}\left(\frac{\sqrt{\frac{2}{3}}}{\sqrt{s}}\right)}}\right]\approx 0.434 t^{-\frac{1}{2}}.$$

How could I have obtained this with Mathematica?

In particular, I'm wondering if there's built-in functionality to let me write $f(s)=\mathcal{L}[g(t)]$, the arctan expression above, as the following series, for $0<\lambda_0<\lambda_1<\ldots$ and $\lambda_0=\frac{1}{2}$

$$f(s)=\sum_{n=0}^\infty \frac{a_n}{s^{\lambda_n}}$$

because that gives the following power series representation of $g(t)$

$$g(t)=\sum_{n=0}^\infty \frac{a_n t^{\lambda_n-1}}{\Gamma(\lambda_n)}$$

Tried Limit[InverseLaplaceTransform[...]] and Asymptotic[InverseLaplaceTransform[...]] with no luck.

ClearAll["Global`*"];
g = 1/(s/2 + (5 Sqrt[s])/(Sqrt[6] ArcTan[Sqrt[2/3]/Sqrt[s]]));
plot1 = DiscretePlot[
   InverseLaplaceTransform[g, s, t], {t, 0., 100, 10}, 
   PlotLegends -> {"g(t)"}];
plot2 = Plot[0.434 t^(-1/2), {t, 0, 100}, 
   PlotLegends -> {" 0.434 t^(-1/2)"}];
Show[plot1, plot2]

Related mathoverflow discussion and mathematica.SE discussion

Answer 1

Looks like the trick to get that expansion was to switch order of Laplace Transform and Asymptotic, and do asymptotic around 0

g = 1/(s/2 + (5 Sqrt[s])/(Sqrt[6] ArcTan[Sqrt[2/3]/Sqrt[s]]));
InverseLaplaceTransform[Asymptotic[g, s -> 0], s, t] (* Sqrt[(3 \[Pi])/2]/(5 Sqrt[t]) *)

The reason this works is because asymptotics of $t\to \infty$ in time domain corresponds to asymptotics of $s\to 0$ in Laplace domain, so this an gives 2 ways of getting series expansion for the same regime.

ClearAll["Global`*"];
f = (Sqrt[\[Pi]/2] Erf[Sqrt[2] Sqrt[t]])/(2 Sqrt[t]);

isTimeDomain[expr_] := MemberQ[Variables@expr, t];
laplace[expr_] := If[isTimeDomain[expr],
   Distribute[LaplaceTransform[expr, t, s]],
   Distribute[InverseLaplaceTransform[expr, s, t]]];

asymp[expr_] := If[isTimeDomain[expr],
  Asymptotic[expr, {t, \[Infinity], 2}],
  Asymptotic[expr, {s, 0, 2}]
  ]

vals = Map[
   TraditionalForm, {{f, laplace@f}, {asymp@f, 
     asymp@laplace@f}, {laplace@asymp@laplace@f, 
     laplace@asymp@f}}, {2}];
TableForm[vals, 
 TableHeadings -> {{"original", "asymptotic1", 
    "asymptotic2"}, {"time domain", "laplace domain"}}]