Is there a way to get an expression for $g(t)$ defined as Laplace Transform below? $$g(t)=\mathcal{L}^{-1}\left[\frac{x^2 \tan^{-1} x}{x+\tan^{-1} x}\right](t)$$ where $$x=\sqrt{\frac{2}{s}}$$

This gives symbolic solution to NDSolve problem solved numerically by Ulich here, worked out by user here

Putting it into Mathematica gives an expression containing both $t$ and $s$

x = Sqrt[2/s];
InverseLaplaceTransform[(x^2 ArcTan[x])/(x + ArcTan[x]), s, t]
  • $\begingroup$ With version "13.2.1 for Mac OS X ARM (64-bit) (January 27, 2023)" this returns (after use of Simplify) (4 - 4 E^(-2 t) + 4 t Log[8]^2 - 4 Log[1/8 (-2 - s)] + Log[1/8 (-2 - s)]^2 - 2 t Log[4096] Log[-2 - s] + 4 t Log[-2 - s]^2)/(2 t (-2 + Log[1/8 (-2 - s)])^2) The presence of s in the result indicates that this is wrong. $\endgroup$
    – Bob Hanlon
    Commented May 7, 2023 at 14:19
  • $\begingroup$ I'm on very shaky ground here (mathematically), but it is possible to do a series expansion around s==0. Can the transform be applied term by term in some way? $\endgroup$
    – mikado
    Commented May 7, 2023 at 19:13
  • $\begingroup$ @mikado well, there this result, from Ch 2 of "Numerical Methods For Inverse Laplace" book, $\bar{f}$ refers to Laplace transform of $f$ $\endgroup$ Commented May 7, 2023 at 20:39
  • $\begingroup$ @mikado The first obstacle of using this approach is finding symbolic expression for $\lambda_n$ in Eq 2.40. $g(t)$ comes from diff-eq corresponding to the DPR1 problem described in community post $\endgroup$ Commented May 7, 2023 at 20:47
  • $\begingroup$ There exist formulas for Laplace transforms of functions of sqrt s, and the tan^.1 1/s =cot^-1 s. But the formula is an integral of the Laplace transform of f(s) with a Gaussian. Unfortunately Mathematica cannot perform the transform of the expression with arccot s nor the direct integral. So I don't expect a closed formula besides the usual series expressions. $\endgroup$
    – Roland F
    Commented May 14, 2023 at 12:54

4 Answers 4


Another way.

I use Post - Widder formula to compute InverseLaplaceTransform. $$\mathcal{L}_s^{-1}[F(s)](t)=\underset{n\to \infty }{\text{lim}}\frac{\frac{\partial ^n}{\partial t^n}\left(t^{n-1} F\left(\frac{n}{t}\right)\right)}{\Gamma (n)}$$ I only use n=20, because I can't find closed-form for n-th derivative.

 g = (2 ArcTan[Sqrt[2] Sqrt[1/s]])/(
 s (Sqrt[2] Sqrt[1/s] + ArcTan[Sqrt[2] Sqrt[1/s]]));
 U[t_] := InverseLaplaceTransform[g, s, N@t];
 F[s_] := (2 ArcTan[Sqrt[2] Sqrt[1/s]])/(
 s (Sqrt[2] Sqrt[1/s] + ArcTan[Sqrt[2] Sqrt[1/s]]));
 G[t_, n_] := 1/Gamma[n]*D[t^(n - 1)*F[n/t], {t, n}]

 {Plot[{U[t], Evaluate@G[t, 1]}, {t, 0, 10}], Plot[{U[t], Evaluate@G[t, 20]}, {t, 0, 10}]}

enter image description here


would a numerical solution help?

f = x^2 ArcTan[x]/(x + ArcTan[x]) /. x -> Sqrt[2/s] // FullSimplify;
g = Table[{t, InverseLaplaceTransform[f, s, t]}, {t, 0.01, 10.,0.1}];
model = a*Exp[-b*t] + c;
fit = NonlinearModelFit[g, model, {a, b, c}, t];
Show[ListPlot[g], Plot[fit[t], {t, 0, 10}, PlotStyle -> Red], 
 Frame -> True, GridLines -> Automatic]

enter image description here

ListPlot[fit["FitResiduals"],DataRange -> {0, 10}, Filling -> Axis]

enter image description here

  • $\begingroup$ so it's useful in a sense that the solution is clearly not exponential, I'm trying to figure out what the correct functional form is $\endgroup$ Commented May 9, 2023 at 9:09
  • $\begingroup$ The solution for closely related problem is $\sqrt{\frac{\pi}{4 t}}$ so this may also be some kind of power law $\endgroup$ Commented May 9, 2023 at 9:11
  • $\begingroup$ @Yaroslav Bulatov A huge improvement is obtained with the model = a - Exp[b/Sqrt[t]]. Good luck! $\endgroup$
    – rmw
    Commented May 9, 2023 at 15:33
  • $\begingroup$ interesting! If we extrapolate, this will underestimate the true value, while power-law fit overestimates, so the solution is neither pure exponential nor power law $\endgroup$ Commented May 9, 2023 at 16:06
  • $\begingroup$ @Yaroslav Bulatov Please consider that the solution only applies to the numerically calculated range, i.e. in this case for t in the interval [0.01,10]. For this range, the solution is only an approximation and by no means a general analytical solution. $\endgroup$
    – rmw
    Commented May 9, 2023 at 19:57


approx[n_] := approx[n] = 
  InverseLaplaceTransform[Normal[Series[expr, {s, ∞, n}]],s, t]

I find that the results are computed quite quickly.

This seems to give consistent values for small values of t

For example

Plot[Evaluate[Table[approx[i], {i, 16, 32}]], {t, 0, 5}, 
 PlotRange -> All]

Transform results

I've no idea if the results are mathematically valid or helpful to you.

  • $\begingroup$ Interesting ! I wonder if this representation is connected to the series in the theorem, writing expression as infinite partial fraction representation $\endgroup$ Commented May 8, 2023 at 7:33

Hope I didn't misunderstand the question:

If only numerical solution is asked for try

invLaplace[ t_?NumericQ] := 
InverseLaplaceTransform[1/(s/2 + Sqrt[s]/(Sqrt[2] ArcTan[Sqrt[2]/Sqrt[s]])),s, t]

Plot[invLaplace[t], {t, 0.001, 10}]

enter image description here

  • $\begingroup$ That looks like correct graph. This is another example of the integro-differential equation you provided Nested DSolve solution for earlier, the technique to get Laplace Transform of solution is documented here, I'm was looking to understand how fast the solution decays to zero $\endgroup$ Commented May 14, 2023 at 14:04
  • $\begingroup$ But the original integro-differential equation leads to a more complicated x-dependent inverse Laplace-Transformation I think $\endgroup$ Commented May 14, 2023 at 15:26
  • $\begingroup$ They are slightly different (due to different values of $a,b$) but you can see that asymptotically they both have $1/\sqrt{t}$ decay $\endgroup$ Commented May 14, 2023 at 17:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.