How to calculate this area?

Question

For didactic purposes I want to calculate the area of the set $\{z+\frac{z^2}{2} : z\in \mathbb{C} \wedge |z| \leq 1\}$ in the complex plane. This is the image of the unit disk under the map $z\rightarrow \frac {z^2} 2 +z$. Making use of the polar coordinates and the result of

Expand[(r Cos[\[Theta]] + I*r Sin[\[Theta]])^2/2 + r Cos[\[Theta]] + I*r Sin[\[Theta]]]

r Cos[\[Theta]] + 1/2 r^2 Cos[\[Theta]]^2 + I r Sin[\[Theta]] + I r^2 Cos[\[Theta]] Sin[\[Theta]] - 1/2 r^2 Sin[\[Theta]]^2

, I write down that domain as a parametric region

reg = ParametricRegion[{r Cos[\[Theta]] + 1/2 r^2 Cos[\[Theta]]^2 - 
1/2 r^2 Sin[\[Theta]]^2, r Sin[\[Theta]] + r^2 Cos[\[Theta]] Sin[\[Theta]]},
 {{\[Theta], 0,  2 \[Pi]}, {r, 0, 1}}]

Unfortunately,

RegionMeasure[reg]

The kernel Local has quit (exited) during the course of an evaluation.

in two hours. Is there a way to calculate it with Mathematica? I am interested in the exact result.

Answer 1

Why not just use ParametricRegion directly without switching to polar coordinates?

reg = With[{z=x+I y},
    ParametricRegion[
        {
            ComplexExpand[ReIm[z+z^2/2]], 
            ComplexExpand[Abs[z]^2 <= 1]
        },
        {x, y}
    ]
]

ParametricRegion[{{x + x^2/2 - y^2/2, y + x y}, x^2 + y^2 <= 1}, {x, y}]

RegionPlot[reg]

Approximate result:

RegionMeasure[reg,WorkingPrecision->MachinePrecision]

4.71239

Exact result:

area = RegionMeasure[reg];//AbsoluteTiming
area

{0.578509, Null}

(3 Pi)/2

Check:

area //N

4.71239