1
$\begingroup$

The following expression $$u_{nm}(r,\theta)=J_n(x_{nm}\frac{r}{a}) \begin{cases} \cos n \theta, & n=0,1,2 , m=1,2 \\ \sin n \theta, & \end{cases}$$ gives the solution for the Helmholtz problem. On the circular disc with center 0 and radius a. For a = 1, the plot in 3-dimensional graphics of the solutions on Mathematica for $(n,m)=(2,2)$ and $(n,m)=(0,2)$ and then calculate the eigenfunction

$$k_{nm}= \frac{x_{nm}}{a}$$

a = 1;
m = 2; (*Set the value of m*)
x[m_] := N[BesselJ[2, m]]
(*calculate the eigenfunction k[m]*)
k[m_] := x[m]/a
TableForm [Table[{m, k[m]}, {m, 2, 2}], TableSpacing -> {3, 5}, 
 TableAlignments -> Center, 
 TableHeadings -> {None, {"m", "\!\(\*SubscriptBox[\(k\), \(m\)]\)"}}]

My question is how could I define the function $u$ and create 3D graphics as the following picture shows

I was thinking to use this

u[r_, t_, m_] := (Cos[\[Omega][m]*t] + Sin[\[Omega][m]*t])*
  BesselJ[0, k[m]*r]

Is my consideration right? enter image description here

$\endgroup$

1 Answer 1

3
$\begingroup$

It could be better to separate functions with $\sin (n\theta)$ and $\cos (n\theta)$ as follows

a = 1;
mmax = nmax = 2; (*Set the value of m, n *)
b[m_, n_] := BesselJZero[n, m];
(*calculate the eigenfunction k[m,n]*)
k[m_, n_] := N[b[m, n]/a];
uc[r_, t_, m_, n_] := (Cos[n t]) BesselJ[n, k[m, n]*r]; 
us[r_, t_, m_, n_] := (Sin[n t]) BesselJ[n, k[m, n]*r];

Visualization

rule = {r -> Sqrt[x^2 + y^2], t -> ArcTan[x, y]}; region = 
 ImplicitRegion[x^2 + y^2 <= 1, {x, y}];
Table[Plot3D[Evaluate[uc[r, t, m, n] /. rule], 
  Element[{x, y}, region], PlotLabel -> {n, m}, 
  PlotTheme -> "Marketing", ColorFunction -> "AuroraColors"], {n, 0, 
  nmax}, {m, 1, mmax}]

Table[Plot3D[Evaluate[us[r, t, m, n] /. rule], 
  Element[{x, y}, region], PlotLabel -> {n, m}, 
  PlotTheme -> "Marketing", ColorFunction -> "AuroraColors"], {n, 1, 
  nmax}, {m, 1, mmax}]

Figure1

$\endgroup$
2
  • $\begingroup$ Thank you that was very helpful $\endgroup$ Apr 14, 2023 at 10:43
  • $\begingroup$ @AthanasiosParaskevopoulos You are welcome! $\endgroup$ Apr 14, 2023 at 11:34

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.