3
$\begingroup$

I am plotting the folium of Descartes as a parametric plot, and trying to find the arclength and the area enclosed by the loop. I got both of them covered result-wise, but my professor wants us to shade the area enclosed by the loop, and bold the arclength(the whole loop). I have been trying to figure that out for quite some time now but just can't seem to get it to work.

  1. One way I found out you can do that is by using RegionPlot[] and fill the parameters. In my case nothing is shaded just my plot is being printed. Link

  2. I found this question on here Link but I didn't find it helpful, because some of the solutions include Filling which is not available for ParametricPlot[]

My code:

x[t_] := (12 t)/(1 + t^3)
y[t_] := (12 t^2)/(1 + t^3)

Vertical tangent lines

dir = {0, 1};
sol = Solve[Det[{{x'[t], y'[t]}, dir}] == 0, t, Reals];

Plot with the "shaded area" that doesn't work

Show[ParametricPlot[{x[t], y[t]}, {t, -100, 100}, 
  PlotRange -> {{-10, 10}, {-10, 10}}, AspectRatio -> Automatic, 
  PlotStyle -> Red, AxesLabel -> {"x", "y"}, 
  PlotLabel -> "Folium of Descartes", 
  BoundaryStyle -> Directive[Red, Thick]], 
 RegionPlot[
  ParametricRegion[{x[t], 
    y[t]}, {{t, 0, Infinity(*sol = 0.793701*)}}], 
  PlotStyle -> LightBlue, BoundaryStyle -> None]]

It also wouldn't accept sol as an argument. I could be wrong but I think I am supposed to integrate from t = 0 to t = Infinity and not t = sol (0.739...) right?

As for the bolding part of the graph I was thinking about just using Style and Bold for an interval of values for t where they make a loop. Would that work?

Any kind of help is appreciated Thank you!

$\endgroup$
2
  • $\begingroup$ It is impossible to find such loop since only when t->Infinity, the parametric curve go back to {0,0}. Limit[{x[t], y[t]}, t -> Infinity]` $\endgroup$
    – cvgmt
    Commented Apr 9, 2023 at 2:29
  • $\begingroup$ Yeah after playing around with this for some time I noticed that. Manipulate[ ParametricPlot[{x[t], y[t]}, {t, -100, 100}, PlotRange -> {{-10, 10}, {-10, 10}}, PerformanceGoal -> "Quality", AxesLabel -> {x, y}, Epilog -> {Red, PointSize -> .05, Point[{x[t1], y[t1]}]}], {t1, 0, 0.739}] Thank you $\endgroup$
    – Jakob
    Commented Apr 9, 2023 at 2:31

1 Answer 1

10
$\begingroup$

maybe something like:

pp = ParametricPlot[{ x[t], y[t]}, {t, -100, 100}, 
  PlotRange -> {{-10, 10}, {-10, 10}},
  PlotPoints -> 400, 
  AspectRatio -> Automatic, 
  MeshFunctions -> {# #2 &}, 
  Mesh -> {{0}}, 
  MeshShading -> { Automatic, Green}, 
  PlotStyle -> Red]

enter image description here

Normal @ pp /. {Green, l_Line} :> 
    {l, Polygon @@ l, Black, 
     Text[Style[Row[{"arc length: ", ArcLength@l}], 14], {1, 9}, Left],
     Text[Style[Row[{"area: ", Area[Polygon @@ l]}], 14], {1, 7.5}, Left]}

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.