Adjust graphs inside GraphicsRow to be the same scale?

Question

I want to draw a picture with GraphicsRow function in Mathematica. A simple example shows as follows

data1 = RandomInteger[5, {16, 16}];
data2 = RandomInteger[1000000000, {16, 16}];
fig1 = MatrixPlot[data1, PlotLegends -> Placed[Automatic, {0, 0.5}], 
   FrameTicks -> {{Automatic, None}, {Automatic, None}}, 
   ImageSize -> 400];
fig2 = MatrixPlot[data2, PlotLegends -> Placed[Automatic, {1, 0.5}], 
   FrameTicks -> {{None, Automatic}, {Automatic, None}}, 
   ImageSize -> 400];
GraphicsRow[{fig1, fig2}, Spacings -> -2]

The execution result is where the two graphs are not of the same size. I then add AspectRatio -> Full action inside MatrixPlot. The result becomes But now the two graphs have different widths. I think the size of the two graphs does not agree because their legends are different. Since when I remove the PlotLegend option, the result becomes

So how can I let the two pictures agree in size while keeping the legends?

My $Version result is 13.1.0 for Microsoft Windows (64-bit) (June 16, 2022).

Answer 1

It seems that the following do the job :

(* this is exactly your code : *)
data1 = RandomInteger[5, {16, 16}];
data2 = RandomInteger[1000000000, {16, 16}];
fig1 = MatrixPlot[data1, PlotLegends -> Placed[Automatic, {0, 0.5}], 
   FrameTicks -> {{Automatic, None}, {Automatic, None}}, 
   ImageSize -> 400];
fig2 = MatrixPlot[data2, PlotLegends -> Placed[Automatic, {1, 0.5}], 
   FrameTicks -> {{None, Automatic}, {Automatic, None}}, 
   ImageSize -> 400];   

(* then the new thing : *)

Legended[GraphicsRow[{fig1[[1]], fig2[[1]]}], {Placed[fig1[[2, 1]], 
   Before], Placed[fig2[[2, 1]], After]}]

Answer 2

If you want more control over how exactly your plots are laid out, you can use ResourceFunction["PlotGrid"]:

data1 = RandomInteger[5, {16, 16}];
data2 = RandomInteger[1000000000, {16, 16}];
fig1 = MatrixPlot[data1, PlotLegends -> Placed[Automatic, Left]];
fig2 = MatrixPlot[data2, PlotLegends -> Placed[Automatic, Right]];

ResourceFunction["PlotGrid"][{{fig1, fig2}}]

Note how there is no need to remove the frame/image size manually, and how the default setting for Spacings is effectively gluing the plots together, without any "magic" numbers. Please note that I had to change the legend positioning to Left/Right to achieve the optimal results, the original settings were not behaving as nicely. (settings such as {-0.05, 0.5}/{1.05, 0.5} also work, but you'll have to play around with the numbers to make it look like you want)

Answer 3

The trick seems to be to transfer the size as a variable to the internal code of execution

    data1 = RandomInteger[5, {16, 16}];
   data2 = RandomInteger[1000000000, {16, 16}];

fig1 := MatrixPlot[data1, PlotLegends -> Placed[Automatic, Scaled[{0, 0.5}]], 
   FrameTicks -> {{Automatic, None}, {Automatic, None}}, 
   ImageSize -> Medium ] ;

fig2[s_] := 
  MatrixPlot[data2, PlotLegends -> Placed[Automatic, Scaled[{1, 0.5}]], 
   FrameTicks -> {{None, Automatic}, {Automatic, None}} ,ImageSize -> {s, s}];

 GraphicsRow[{fig1, fig2[420]}]