2
$\begingroup$

I want to calculate the following limit:

b[n_] := (D[1/(1 - t), {t, n}] /. {t -> 0})/Factorial[n]
Limit[b[n], n -> ∞]
(* Indeterminate *)

where b[n] represents the $n^\rm{th}$ Taylor coefficient of function $1/(1-t)$ at $t=0$.

  1. Each $b_n$ is 1. Why does the limit return Indeterminate and not 1?

  2. Is there any simple method to calculate the limit of Taylor coefficients of a rational function? Below is an example of a rational function:

(1 + t)/(-t (1 + t + t^3) + (1 + t) (1 - t^2)^3 (1 - t^4)^3 (1 - t^6)^3)

Any help is highly appreciated. Thanks is advance.

$\endgroup$
1
  • $\begingroup$ b[n_] = Assuming[n >= 0, SeriesCoefficient[f[t], {t, 0, n}]] $\endgroup$
    – Bob Hanlon
    Mar 29, 2023 at 15:10

1 Answer 1

4
$\begingroup$

Use DiscreteLimit.

f = 1/(1 - t);
b = (D[1/(1 - t), {t, n}] /. {t -> 0})/Factorial[n]
(* ((-1)^n FactorialPower[-1, n])/n! *)

DiscreteLimit[b, n -> ∞]
(* 1 *)

Also, you don't need to calculate the coefficient via D and Factorial because there exists SeriesCoefficient.

b = SeriesCoefficient[f, {t, 0, n}]
(* Piecewise[{{1, n >= 0}}, 0] *)

DiscreteLimit[b, n -> ∞]
(* 1 *)

Now to your complicated rational function, for which it seems that the coefficients keep growing indefinitely.

f = (1 + t)/(-t (1 + t + t^3) + (1 + 
       t) (1 - t^2)^3 (1 - t^4)^3 (1 - t^6)^3);

Table[SeriesCoefficient[f, {t, 0, n}], {n, 0, 25}]
(* {1, 1, 4, 7, 20, 41, 100, 221, 515, 1164, 2679, 6096, 13980, 31889, 
    73002, 166725, 381369, 871473, 1992675, 4554587, 10412772, 23802307,
    54414141, 124388286, 284356379, 650034525} *)

You can obtain a general formula, which is an extremely long expression with 37 terms and many Root objects.

b = SeriesCoefficient[f, {t, 0, n}]

SeriesCoefficient

You may try using Limit or DiscreteLimit on this result if you are patient. However, with a bit dangerous approach by looking at the numerical representation, you may see that there are only exponential terms, and the largest base (by absolute value) is positive.

Collect[N[b], n] /. a_Complex :> Abs[a]
(* 0.225774 * (-1.4473)^n + ... + 0.685494 * 2.28601^n *)

Limit[N[b], n -> ∞]
∞
$\endgroup$
6
  • 1
    $\begingroup$ @ShrikantShekhar, please edit your question and include a concrete example of your rational function. $\endgroup$
    – Domen
    Mar 28, 2023 at 20:26
  • $\begingroup$ @ Domen Sur. Here is the rational function $\frac{(1+t)}{(-t(1+t+t^3)+(1+t)(1-t^2)^3(1-t^4)^3(1-t^6)^3)}$ for which I want to check DiscreteMaxLimit[a[n], n-> \[Infinity]] where ``` a[n] = ``` $n^th$ Taylor coefficient. $\endgroup$
    – SKS
    Mar 28, 2023 at 21:18
  • $\begingroup$ @ShrikantShekhar, please see my update. $\endgroup$
    – Domen
    Mar 28, 2023 at 22:40
  • $\begingroup$ Thanks it's helpful. But I have a question : What is numerical representation ?? I will let you know if there is any question. $\endgroup$
    – SKS
    Mar 29, 2023 at 10:50
  • $\begingroup$ @ShrikantShekhar, as you see in the image, the expression contains so called Root objects which are the exact representation of a certain number. What I meant by "numerical representation" was the conversion of this objects to "inexact" numbers (that have some finite precision) by using N. $\endgroup$
    – Domen
    Mar 29, 2023 at 10:55

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.