Evaluate using Mathematica or otherwise $\int_{0}^{\pi/2}\sin^n x \ T_n(\sin x)\ dx$

Question

Denote $T_n(x)$ as Chebyshev polynomial of the first kind (see here). Then I need to evaluate for $n$ a odd natural number $$\int_{0}^{\pi/2}\sin^n x \ T_n(\sin x)\ dx $$

I am requesting a code with answer if possible in Wolfram Mathematica or an answer otherwise. Sorry, I am a beginner of Mathematica. Any help will be appreciated.

Edit I request a related formula for $$\int_{0}^{\pi/2}\sin^n x \cos x \ U_{n-1}(\sin x)\ dx $$ where $U_{n}$ is Chebyshev polynomial of the second kind. (see here.)

Answer 1

For general n if $n\geq 0$:

list = Integrate[Table[Sin[x]^n*ChebyshevT[n, Sin[x]], {n, 0, 10}], {x, 0, Pi/2}]; 
FindSequenceFunction[list, n]/. n -> n + 1

(*2^(-1 - n) \[Pi]*)

Edited:

From here we use this formula:

$$\sum _{m=0}^{\left\lfloor \frac{n}{2}\right\rfloor } \binom{n}{2 m} \sin ^{n-2 m}(x) \left(\sin ^2(x)-1\right)^m=T_n(\sin (x))$$

int = Integrate[Sin[x]^n*Binomial[n, 2 m]*Sin[x]^(n - 2 m)*(Sin[x]^2 - 1)^m, 
{x, 0,Pi/2}][[1]];

Sum[int // FunctionExpand, {m, 0, Floor[n/2]}]

(*2^(-1 - n) \[Pi]*)

Edited:

list = Integrate[Table[Sin[x]^n*Cos[x]*ChebyshevU[n - 1, Sin[x]], {n, 0, 10}], {x, 0, Pi/2}];
F = FindSequenceFunction[list, n] /. n -> n + 1 // FullSimplify

(* -I 2^(-1 - n) \[Pi] - LerchPhi[2, 1, 1 + n] *)(*Or: -Re[LerchPhi[2, 1, 1 + n]]*)
 
Table[F, {n, 0, 10}] // Simplify
(*{0, 1/2, 1/2, 5/12, 1/3, 4/15, 13/60, 151/840, 16/105, 83/630, 73/630}*)

Answer 2

In general, one should try it with assumptions on parameters. Then it works:

Integrate[
 Sin[x]^n*ChebyshevT[n, Sin[x]] // FunctionExpand, {x, 0, Pi/2}, 
 Assumptions -> n >= 0 && n \[Element] Integers]

(*  2^(-1 - n) \[Pi]  *)

---

Not sure what form is expected for the second integral, but here are two:

Integrate[
  Sin[x]^n*Cos[x]*ChebyshevU[n, Sin[x]] // FunctionExpand, {x, 0, 
   Pi/2}, Assumptions -> n >= 0 && n \[Element] Integers] // 
 FullSimplify[#, n >= 0 && n \[Element] Integers] &
(*
Hypergeometric2F1[1, 3/2, 1/2 - n, -1]/(1 + 2 n) -
 Hypergeometric2F1[1, 3/2 + n, 1/2, -1] +
 2^(-1-n) \[Pi] HypergeometricPFQ[{-(1/2), 1/2+n/2, 1+n/2}, {1, 1+n}, 1]
*)

Table[%, {n, 0, 30}] // FunctionExpand // FindSequenceFunction
(*
-((2^(1 - #1) (I Sqrt[\[Pi]] #1! + 
     2^#1 (1/2 (-1 + 2 #1))! Hypergeometric2F1[1, 1/2 + #1, 1 + #1, 
       2]) Pochhammer[1, -1 + #1])/(
  Sqrt[\[Pi]] #1! Pochhammer[3/2, -1 + #1])) &
*)

Answer 3

A transformation of variables

{ Sin[x]:> u, Cos[x]:> Sqrt[1-u^2],  dx :> du/ Sqrt[1-u2], {x,0,1} :> {u,0,1} }

yields the integrals

Integrate[ Sin[x]^n T[n,Sin[x]],{x,0,Pi/2}] :> Integrate[ u^n/Sqrt[1-u^2] T[n,u],{u,0,1}]

Integrate[ Sin[x]^n Cos[x] U[n,Sin[x]],{x,0,Pi/2}] :> Integrate[ u^n  U[n,u],{u,0,1}]

You can map the integrals into Range[0,n] and FindSequence

    Assuming[ n > 0 && n \[Element] Integers, FindSequenceFunction[   Integrate[ChebyshevT[#, u] u^#/Sqrt[1 - u^2] , {u, 0, 1}] & /@ Range[0, 24], n]  

  

    Out:= Pi/2^n


 

Assuming[ n > 0 && n \[Element] Integers, FindSequenceFunction[  Integrate[ChebyshevU[#, u] u^# , {u, 0, 1}] & /@ Range[0, 24], n]]

  

      Out:=-((2^(1 - n) (I Sqrt[\[Pi]] n! + 2^n (1/2 (-1 + 2 n))! Hypergeometric2F1[1, 1/2 + n, 1 + n,  2]) Pochhammer[1, -1 + n])/( Sqrt[\[Pi]] n! Pochhammer[3/2, -1 + n]))