3
$\begingroup$

Is it possible to give Mathematica a limit about's function at infinity? For example I would like to

Limit[F[r], r -> \[Infinity], Assumptions -> F[\[Infinity]] == 0]

To evaluate to zero. What are my options? And will is there a way to impose stronger conditions, for example if $F(x)$ would behave as $1/r^2$ at infinity is it possible to assume this in Mathematica? So that for example one might calculate

$$ \lim_{r \to \infty} r F(r) = 0 \quad \text{for} \; F(r) \approx 1/r^2 \; \text{with} \; r \gg1. $$

Improve this question
$\endgroup$
2
  • $\begingroup$ What would you do with this if it were possible? What do you need this functionality for? Maybe there's a different approach to your actual underlying problem. $\endgroup$
    – MarcoB
    Mar 18 at 13:40
  • $\begingroup$ Finding a Green's function for a ODE.. I wanted to check that the Green's function that I found is really a Green's function. I.e. $L \int G(x,y) F(y) dy = F(x)$ with $L$ being some differential operator (acting on $x$). Since the expression is quite complicated I choose the upper limit as integral to be some value instead of $\infty$ to "help" Mathematica, so now I'm finding the limit of that expression. $\endgroup$
    – Nitaa a
    Mar 18 at 13:50

1 Answer 1

Reset to default
4
$\begingroup$ 
ClearAll[a, F, r, t, x]

Use TagSet to define UpValues for F

F /: Asymptotic[F[x_], x_ -> Infinity] = 1/x^2;

F /: Limit[F[x_], x_ -> Infinity] = 0;

UpValues[F]

enter image description here

Asymptotic[F[r], r -> Infinity]

(* 1/r^2 *)

Limit[F[r], r -> Infinity]

(* 0 *)

F cannot be buried any deeper in the LHS of the TagSet. Use a replacement rule when F is buried deeper.

asymFinf = F[t_] -> Asymptotic[F[t], t -> Infinity]

(* F[t_] -> 1/t^2 *)

Asymptotic[a*F[r] /. asymFinf, r -> Infinity]

(* a/r^2 *)

Limit[a*F[r] /. asymFinf, r -> Infinity]

(* 0 *)

Limit[r*F[r] /. asymFinf, r -> Infinity]

(* 0 *)

Limit[a*r^2*F[r] /. asymFinf, r -> Infinity]

(* a *)
Improve this answer
$\endgroup$
0

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.