2
$\begingroup$

If we have$$f(a)=_3F_2\left(\frac{1}{2},\frac{a+1}{2},\frac{a+2}{2}; \frac{a+3}{2},\frac{a+3}{2};1\right)$$ where $a\geq 0$ and $_3F_2$ is the Hypergeometric function with unit argument.

Evaluate using Mathematica or otherwise the value of $f'(0)$ (the first derivative of $f(a)$ at $0$).

I am requesting a code with answer if possible in Wolfram Mathematica.

Sorry, I am new to Wolfram Mathematica.

Any help would be appreciated.

$\endgroup$

4 Answers 4

9
$\begingroup$

From definition of HypergeometricPFQ as Series representations we have:

$\underset{a\to 0}{\text{lim}}\frac{\partial }{\partial a}\, _3F_2\left(\frac{1}{2},\frac{1}{2}+\frac{a}{2},1+\frac{a}{2};\frac{3}{2}+\frac{a}{2},\frac{3}{2}+\frac{a}{2};1\right)=\\\underset{a\to 0}{\text{lim}}\frac{\partial }{\partial a}\left(\sum _{k=0}^{\infty } \frac{\left(\frac{1}{2}\right)_k \left(\frac{1}{2}+\frac{a}{2}\right)_k \left(1+\frac{a}{2}\right)_k}{k! \left(\left(\frac{3}{2}+\frac{a}{2}\right)_k\right){}^2}\right)=\\\sum _{k=0}^{\infty } \left(\underset{a\to 0}{\text{lim}}\frac{\partial }{\partial a}\frac{\left(\frac{1}{2}\right)_k \left(\frac{1}{2}+\frac{a}{2}\right)_k \left(1+\frac{a}{2}\right)_k}{k! \left(\left(\frac{3}{2}+\frac{a}{2}\right)_k\right){}^2}\right)=\\\sum _{k=0}^{\infty } \left(\underset{a\to 0}{\text{lim}}\frac{\partial }{\partial a}\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right)}{(1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}\right)=\\\sum _{k=0}^{\infty } \left(\underset{a\to 0}{\text{lim}}\left(-\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right)}{(1+a+2 k)^2 \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}+\frac{\Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right)}{(1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}-\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right) \psi ^{(0)}\left(1+\frac{a}{2}\right)}{2 (1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}+\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right) \psi ^{(0)}\left(\frac{3}{2}+\frac{a}{2}\right)}{2 (1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}+\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right) \psi ^{(0)}\left(1+\frac{a}{2}+k\right)}{2 (1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}-\frac{(1+a) \Gamma \left(\frac{3}{2}+\frac{a}{2}\right) \Gamma \left(\frac{1}{2}+k\right) \Gamma \left(1+\frac{a}{2}+k\right) \psi ^{(0)}\left(\frac{3}{2}+\frac{a}{2}+k\right)}{2 (1+a+2 k) \sqrt{\pi } \Gamma \left(1+\frac{a}{2}\right) \Gamma (1+k) \Gamma \left(\frac{3}{2}+\frac{a}{2}+k\right)}\right)\right)=\\\sum _{k=0}^{\infty } \left(-\frac{\Gamma \left(\frac{1}{2}+k\right)}{2 (1+2 k)^2 \Gamma \left(\frac{3}{2}+k\right)}+\frac{\Gamma \left(\frac{1}{2}+k\right)}{2 (1+2 k) \Gamma \left(\frac{3}{2}+k\right)}+\frac{\gamma \Gamma \left(\frac{1}{2}+k\right)}{4 (1+2 k) \Gamma \left(\frac{3}{2}+k\right)}+\frac{\Gamma \left(\frac{1}{2}+k\right) \psi ^{(0)}\left(\frac{3}{2}\right)}{4 (1+2 k) \Gamma \left(\frac{3}{2}+k\right)}+\frac{\Gamma \left(\frac{1}{2}+k\right) \psi ^{(0)}(1+k)}{4 (1+2 k) \Gamma \left(\frac{3}{2}+k\right)}-\frac{\Gamma \left(\frac{1}{2}+k\right) \psi ^{(0)}\left(\frac{3}{2}+k\right)}{4 (1+2 k) \Gamma \left(\frac{3}{2}+k\right)}\right)=\\\sum _{k=0}^{\infty } -\frac{-2+(-1-2 k) H_k+(1+2 k) H_{\frac{1}{2}+k}+2 k (-4+\ln (4))+\ln (4)}{2 (1+2 k)^3}=\\\int_0^1 \left(\sum _{k=0}^{\infty } -\frac{-2+\frac{(-1-2 k) \left(1-t^k\right)}{1-t}+\frac{(1+2 k) \left(1-t^{\frac{1}{2}+k}\right)}{1-t}+2 k (-4+\ln (4))+\ln (4)}{2 (1+2 k)^3}\right) \, dt=\int_0^1 \frac{1}{16} \left(-\frac{2 \Phi \left(t,2,\frac{1}{2}\right)}{1+\sqrt{t}}-\pi ^2 (-4+\ln (4))-14 \zeta (3)\right) \, dt=\\\frac{\pi ^2}{4}-\frac{1}{16} \pi ^2 \ln (4)-\frac{7 \zeta (3)}{8}-\int_0^1 \frac{\Phi \left(t,2,\frac{1}{2}\right)}{8 \left(1+\sqrt{t}\right)} \, dt=\\\frac{\pi ^2}{4}-\frac{1}{16} \pi ^2 \ln (4)-\frac{7 \zeta (3)}{8}-\sum _{k=0}^{\infty } \int_0^1 \frac{t^k}{\left(\frac{1}{2}+k\right)^2 \left(8 \left(1+\sqrt{t}\right)\right)} \, dt=\\\frac{\pi ^2}{4}-\frac{1}{16} \pi ^2 \ln (4)-\frac{7 \zeta (3)}{8}-\sum _{k=0}^{\infty } \frac{-H_k+H_{\frac{1}{2}+k}}{2 (1+2 k)^2}=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{2} \sum _{k=0}^{\infty } \frac{H_{\frac{1}{2}+k}}{(1+2 k)^2}=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{2} \sum _{j=1}^{\infty } \left(\sum _{k=0}^{\infty } \frac{\frac{1}{2}+k}{\left(j \left(\frac{1}{2}+j+k\right)\right) (1+2 k)^2}\right)=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{2} \sum _{j=1}^{\infty } \left(\frac{\gamma }{4 j^2}+\frac{\ln (4)}{4 j^2}+\frac{\psi ^{(0)}\left(\frac{1}{2}+j\right)}{4 j^2}\right)=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{48} \pi ^2 (\gamma +\ln (4))-\sum _{j=1}^{\infty } \frac{\psi ^{(0)}\left(\frac{1}{2}+j\right)}{4 j^2}=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{48} \pi ^2 (\gamma +\ln (4))-\int_0^{\infty } \left(\sum _{j=1}^{\infty } \frac{\frac{e^{-t}}{t}-\frac{(1+t)^{-\frac{1}{2}-j}}{t}}{4 j^2}\right) \, dt=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{1}{48} \pi ^2 (\gamma +\ln (4))-\int_0^{\infty } \left(\frac{e^{-t} \pi ^2}{24 t}-\frac{\text{Li}_2\left(\frac{1}{1+t}\right)}{4 t \sqrt{1+t}}\right) \, dt=\\\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)-\frac{7 \zeta (3)}{16}$

Using definitions:

$H_x=\int_0^1 \frac{1-t^x}{1-t} \, dt$

$\Phi \left(t,2,\frac{1}{2}\right)=\sum _{k=0}^{\infty } \frac{t^k}{\left(\frac{1}{2}+k\right)^2}$

$H_k=\sum _{j=1}^{\infty } \frac{k}{j (j+k)}$

$\psi ^{(0)}\left(\frac{1}{2}+j\right)=\int_0^{\infty } \left(\frac{e^{-t}}{t}-\frac{(1+t)^{-\frac{1}{2}-j}}{t}\right) \, dt$


$$\underset{a\to 0}{\text{lim}}\frac{\partial }{\partial a}\, _3F_2\left(\frac{1}{2},\frac{a+1}{2},\frac{a+2}{2};\frac{a+3}{2},\frac{a+3}{2};1\right)=\color{red}{-\frac{7 \zeta (3)}{16}+\frac{\pi ^2}{4}-\frac{1}{4} \pi ^2 \ln (2)}$$

HoldForm[Limit[D[HypergeometricPFQ[{1/2, (a + 1)/2, (a + 2)/2}, {(a + 3)/2, (a + 3)/2}, 1], a], a -> 0] ==
\[Pi]^2/4 - 1/16 \[Pi]^2 Log[4] - (7 Zeta[3])/8 - 
Integrate[LerchPhi[t, 2, 1/2]/(8 (1 + Sqrt[t])), {t, 0, 1}] == \[Pi]^2/4 - 1/4 \[Pi]^2 Log[2] - 
1/2*Sum[HarmonicNumber[1/2 + k]/(1 + 2 k)^2, {k, 0, 
  Infinity}] == \[Pi]^2/4 - 1/4 \[Pi]^2 Log[2] - (7 Zeta[3])/16]

We can check:

 SOL1 = N[\[Pi]^2/4 - 1/4 \[Pi]^2 Log[2] - (7 Zeta[3])/16, 50]
 (* 0.23122908917573801863436751581925439504379858686425 *)
 Needs["NumericalCalculus`"];
 SOL2 = ND[f[a], a, 0, WorkingPrecision -> 50, Method -> NIntegrate]
 (* 0.23122908917573801863436751581925439504379858686430 - 2.*10^-50 I *)
 SOL1 - SOL2

 (*-5.*10^-50 + 2.*10^-50 I *)
$\endgroup$
8
  • $\begingroup$ While exact calculation is what we are expecting, it would be recommended to explain several steps above, e.g. after the 4-th equal sign how do you get rid of $\lim_{a \to 0} \frac{\partial}{\partial a}\dots$ with several functions involving $a$ as an argument and obtain harmonic functions or in the next step how does integral appear $\int_{0}^{1}\dots$. $\endgroup$
    – Artes
    Mar 16, 2023 at 16:38
  • $\begingroup$ Thanks for the beautiful effort. Please explain how did you take limit and differentiation inside the sum (which needs some condition to be allowed). Also please explain how fid you get the sums and integrals and the steps involved in between. Thank you for your effort $\endgroup$
    – Max
    Mar 16, 2023 at 16:54
  • $\begingroup$ @Max I'm not going to prove anything to you under what conditions these equations are met, because this forum is about the Mathematica program, not the math itself. Second, I'm not a mathematician, I'm an engineer, so proving isn't my strong suit. $\endgroup$ Mar 16, 2023 at 22:04
  • $\begingroup$ Thanks a lot for the edit. $\endgroup$
    – Max
    Mar 17, 2023 at 2:47
  • $\begingroup$ @Max I'll try to provide a bit more mathematical justification of the above reasoning when I find a bit of spare time, I hope until tomorow evening. $\endgroup$
    – Artes
    Mar 17, 2023 at 12:08
6
$\begingroup$

Let's define

f[a_] := HypergeometricPFQ[{1/2, (a + 1)/2, (a + 2)/2}, {(a + 3)/2, (a + 3)/2}, 1]

HypergeometricPFQ[{1/2, (a + 1)/2, (a + 2)/2}, {(a + 3)/2, (a + 3)/2}, 1]//
TraditionalForm

enter image description here

HypergeometricPFQ[{a1,..., ap},{ b1,...,bq},z] is the generalized
hypergeometric function pFq(a;b;z). 

If we evaluate simply

Derivative[1][f][0] // TraditionalForm

enter image description here

we get a symbolic representation by introducing another special functions (derivatives of $_3 F_2$ with respect to its parameters $a_i$ and $b_j$) which can't be expanded into other well (better) known functions. Moreover the system seems to choke on numerical evaluation.

Table[ f[a], {a, Range[-2, 2]}]
 {1, 1, Pi^2/8, (4 (-2 + Pi))/Pi, 9/32 (-4 + Pi^2)}

Now we can estimate symbolically derivative of $f'(0)$ simply taking $\frac{f(1)-f(0)}{1}$ or $\frac{f(1)-f(-1)}{2}$

{(f[1] - f[0])/1, (f[1] - f[-1])/2} // Simplify
N @ %
{ 4 - 8/Pi - Pi^2/8, 3/2 - 4/Pi}
{ 0.21982, 0.22676}   

Comparing with the plot this appears to be a good approximation. Moreover evaluation at close points yields a similar, even more precise result (up to $10^{-5}$) without using external packages

(f'[0.00001] + f'[-0.00001])/2
 0.231229 
Plot[{f[a], (4 - 8/Pi - Pi^2/8) a + Pi^2/8}, {a, -5, 4}, 
  AxesOrigin -> {0, 0}, AspectRatio -> Automatic, PlotRange -> {0, 6.5}, 
  PlotStyle -> {Thick, Dashed}, PlotLegends -> Placed["Expressions", {0.8, 0.75}], 
  Epilog -> {Red, PointSize[0.02], Point[{0, Pi^2/8}]}]

enter code here

Derivation of the exact result within Mathematica

Partial sums of geometric series can be calculated simply with

ForAll[ n, n ∈ Integers && n >= 2, 
       (1 - q^n)/(1 - q) == Sum[q^k, {k, 0, n - 1}]] // Resolve
True

This also yields with $n \to \infty$ the sum of geometric series as well as the starting point to the definition of the hypergeometric series and by the analytic continuation the hypergeometric function:

Sum[ Gamma[k + a] Gamma[k + b] Gamma[c]/(
       Gamma[a] Gamma[b] Gamma[k + c] k!) q^k, { k, 0,3}]
Hypergeometric2F1[a, b, c, q]

The above formula yields for $a=b=c=1$ the sum of geometric series, more precisely this should be a conditional expression. Analogously we can define $_3 F_2$ function.

The following yields a basic definition of the Euler gamma function

Integrate[ t^(x - 1) Exp[-t], {t, 0,  ∞}, Assumptions -> Re[x] > 0]
Gamma[x]

which by the analytic continuation provides a meromorphic function in the whole complex plane

{FunctionMeromorphic[#, x], FunctionDomain[#, x, Complexes]}&@Gamma[x]
{True, Re[x] > 0 || x \[NotElement] Integers}

We use also

FullSimplify[ Gamma[a1 + k]/Gamma[a1] == Pochhammer[a1, k]]
 True

Denoting by $d_0 = f'(0)$ we can write from the definition that wherever the series is absolutely convergent:

$$d_0=\lim_{a\to 0}\frac{d}{d a}\, _3F_2\left(\frac{1}{2},\frac{a+1}{2},\frac{a}{2}+1;\frac{a+3}{2},\frac{a+3}{2};1\right)=\sum _{k=0}^{\infty }\left(\underset{a\to 0}{\lim}\frac{d }{d a} \frac{\left(\frac{1}{2}\right)_k \left(\frac{1}{2}+\frac{a}{2}\right)_k \left(1+\frac{a}{2}\right)_k}{k! \left(\left(\frac{3}{2}+\frac{a}{2}\right)_k\right){}^2}\right)$$

which is the case here, e.g.

SumConvergence[ (Pochhammer[1/2, k] Pochhammer[(a + 1)/2, k]
                 Pochhammer[(a + 2)/2, k]/(Pochhammer[(a + 3)/2, k]^2 k!), k]
 True

The same holds also including the oprerator $\underset{a\to 0}{\lim}\frac{d}{d a}$ under the sum sign. Then differentiating with respect to $a$ we obtain

Assuming[k ∈ PositiveIntegers, 
  Limit[ D[ FunctionExpand[(
    Pochhammer[1/2, k] Pochhammer[(a + 1)/2, k] Pochhammer[(a + 2)/2, k])/(
    Pochhammer[(a + 3)/2, k]^2 k!)], a], a -> 0] // FullSimplify]
-((-2 + (-1 - 2 k) HarmonicNumber[k] + (1 + 2k) HarmonicNumber[1/2 + k]
    + 2 k (-4 + Log[4]) + Log[4])/(2 (1 + 2 k)^3))

The above limit yields $0$ for $k=0$. The only problematic term when summing from $k=1$ to $k=\infty$ is -HarmonicNumber[1/2 + k]/(2(1 + 2k)^2)

d0 = Sum[-((-2 + (-1 - 2 k) HarmonicNumber[k] + 2 k (-4 + Log[4])
         + Log[4])/(2 (1 + 2 k)^3)), {k, ∞}] 
   - Sum[ HarmonicNumber[1/2 + k]/(2 (1 + 2 k)^2), {k, ∞}]
 -1/8 ((-4 + Pi^2) (-2 + Log[4])) 
  - Sum[ HarmonicNumber[1/2 + k]/(2(1 + 2k)^2), {k, ∞}]

We denote:

 d01 = -1/8 ((-4 + Pi^2) (-2 + Log[4]));
 d02 = - Sum[ HarmonicNumber[1/2 + k]/(2(1 + 2k)^2), {k, ∞}];

Using the following identity

Sum[-((k + 1/2)/(2 m (2 k + 1)^2 (m + k + 1/2))), {m, ∞}]// FullSimplify
-HarmonicNumber[1/2 + k]/(2 (1 + 2 k)^2)

we can recast the hard term by summing it first with respect to $k$

Sum[-((k + 1/2)/(2 m (2 k + 1)^2 (m + k + 1/2))), {k, ∞}]//FunctionExpand
-((-2 + EulerGamma + Log[4] + PolyGamma[0, 3/2 + m])/(8 m^2))

Next we exploit two identities

-PolyGamma[0, 3/2 + m]/(8 m^2) == -(1/(
   8 m^2)) (PolyGamma[0, 1/2 + m] + 1/(1/2 + m)) // FullSimplify
 True

and

Integrate[ Exp[-t]/t - 1/((t + 1)^(m + 1/2) t), {t, 0, ∞},
  Assumptions -> m > 0]
PolyGamma[0, 1/2 + m]

Summing up

d02 = 1 - Log[2] - 1/48 Pi^2 (EulerGamma + Log[4]) + 
      Integrate[-Sum[ Exp[-t]/(8 m^2 t) - 1/(8 m^2 (t + 1)^(m + 1/2) t), 
                     {m, ∞}], {t, 0, ∞}] // FullSimplify
1 - Log[2] - (7 Zeta[3])/16

In mathematical notation we have $$ d_{02}= -\sum_{k=1}^{\infty}\frac{H_{k+\frac{1}{2}}}{2(2k+1)^2}=-\sum_{m=1}^{\infty}\frac{\gamma-2+\ln(4)+\psi^{(0)}(\frac{3}{2}+m)}{8m^2}$$ and $$-\sum_{m=1}^{\infty}\frac{\psi^{(0)}(\frac{3}{2}+m)}{8m^2}=-\sum_{m=1}^{\infty}\frac{1}{4m^2(2m+1)}-\sum_{m=1}^{\infty}\frac{\psi^{(0)}(\frac{1}{2}+m)}{8m^2}=\\=1-\ln(2)-\frac{\pi^2}{48}(\gamma+\ln(4))-\int_{0}^{\infty}\left( \sum_{m=1}^{\infty}\frac{\exp(-t)}{8m^2 t}-\sum_{m=1}^{\infty}\frac{1}{8m^2 (t+1)^{\frac{1}{2}+m} t}\right)=\\=1-\ln(2)-\frac{\pi^2}{48}(\gamma+\ln(4))-\int_{0}^{\infty}\left(\frac{\pi^2 \exp(-t)}{48t}-\frac{6\operatorname{Li}_{2}{\frac{1}{t+1}}}{48\sqrt{t+1}\; t} \right) $$ and finally

d0 = d01 + d02 // FullSimplify
N @ %
 1/16 ( -4 Pi^2 (-1 + Log[2]) - 7 Zeta[3])
 0.231229

$$d_0=d_{01}+d_{02}= \frac{4\pi^2\left(1-\ln(2)\right)- 7\zeta(3)}{16}$$

$\endgroup$
7
  • $\begingroup$ Thanks, But I need the value of $f'(0)$ $\endgroup$
    – Max
    Mar 15, 2023 at 18:32
  • $\begingroup$ I am sorry if I am not able to convey my question. I meant $f'(0)$ or the derivative of $f(a)$ at $0$. $\endgroup$
    – Max
    Mar 15, 2023 at 18:41
  • 1
    $\begingroup$ Thanks a lot. I need a closed form for the derivative of $f$ at $0$. Can we use "D" operator or any other idea can work? $\endgroup$
    – Max
    Mar 15, 2023 at 18:51
  • $\begingroup$ Using Derivative[1][f][0] // TraditionalForm, can't we get a closed form of the derivative? $\endgroup$
    – Max
    Mar 15, 2023 at 19:13
  • $\begingroup$ @Max This is just a closed form of the derivative $f'(0)$, however for unknown reasons it can't be numerically approximated. Perhaps there is another symbolic representation of the result which could be numerically approximated. $\endgroup$
    – Artes
    Mar 15, 2023 at 19:21
3
$\begingroup$
$Version

(* "13.2.1 for Mac OS X ARM (64-bit) (January 27, 2023)" *)

Clear["Global`*"]

f[a_] := HypergeometricPFQ[{1/2, (a + 1)/2, (a + 2)/2}, 
  {(a + 3)/2, (a + 3)/2}, 1]

This can be evaluated exactly for integers, a > -3

pts1 = {#, f[#]} & /@ Range[-2, 5] // Simplify

(* {{-2, 1}, {-1, 1}, {0, π^2/8}, {1, 4 - 8/π}, {2, 
  9/32 (-4 + π^2)}, {3, (64 (-7 + 3 π))/(27 π)}, {4, 
  75/512 (-16 + 3 π^2)}, {5, (64 (-149 + 60 π))/(375 π)}} *)

Or numerically for reals

SeedRandom[1234];

val = RandomReal[{-5, 5}, 10];

pts2 = {#, f[#]} & /@ val;

Plot[f[a], {a, -5, 5},
 Epilog -> {AbsolutePointSize[5],
   Red, Point[pts1],
   Purple, Point[pts2]}]

enter image description here

EDIT: For the derivative, f'[a]

Needs["NumericalCalculus`"]

ND[f[a], a, 0, WorkingPrecision -> 15] // N

(* 0.231229 *)

ListLinePlot[Table[{a0, ND[f[a], a, a0, WorkingPrecision -> 15]},
  {a0, 0, 5, 1/4}]]

enter image description here

$\endgroup$
3
  • $\begingroup$ +1 Thanks, but I need the value of $f'(0)$. $\endgroup$
    – Max
    Mar 15, 2023 at 18:32
  • $\begingroup$ I am sorry if I am not able to convey my question. I meant $f'(0)$ or the derivative of $f(a)$ at $0$. $\endgroup$
    – Max
    Mar 15, 2023 at 18:41
  • $\begingroup$ Thanks a lot. I need a closed form for the derivative at $0$. Please see if it can be done. $\endgroup$
    – Max
    Mar 15, 2023 at 18:49
2
$\begingroup$

Mathematica evaluates a closed form as a ConditionalExpression

Limit[(f[a] - f[0])/a, a -> 0]
  

enter image description here

which is probably not useful because it contains unevaluated expressions of HypergeometricPFQ !

$\endgroup$
4
  • $\begingroup$ +1 Can we have a closed form of the limit you have written? $\endgroup$
    – Max
    Mar 15, 2023 at 18:58
  • $\begingroup$ Yes, just evaluate the code! $\endgroup$ Mar 15, 2023 at 20:20
  • $\begingroup$ @UlrichNeumann It might be a version dependent issue, in 13.0.1 it yields a ConditionalExpression which can't be evaluated numerically. If it is not the case in a newer version you should write down the result. $\endgroup$
    – Artes
    Mar 15, 2023 at 20:46
  • $\begingroup$ Yes please write down the result. $\endgroup$
    – Max
    Mar 16, 2023 at 6:35

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.