Association does not work in package environment

Question

I'm trying to be sneaky with a function and try to have an expression stored as a string (unevaluated) until a desired moment when it will be converted from a string to an expression and then have it parsed.

I am doing this because some computations are quite heavy and depending on what I want from the function I can either get the "a" or "b" outputs/paths. I suspect that SetDelayed or TagSetDelayed would probably be better suited here, but I'm not certain how to use them in this context.

This works beautifully as a normal function (non-packaged) in a notebook (v.13.2) however the moment I introduce this idea in a package environment, it fails to parse it.

The packaged version:

BeginPackage["SE`Question`"];
func1; (* declared in public part of package *)
Begin["`Private`"];
func1[a_,b_,output_:"a"]:=Block[{range,data1,data2,dict,dat1,dat2},
range=Range[10];
data1 = Table[i^a,{i,10}];
data2 = Table[i^b,{i,10}];
dict=<|
"a"->"{range,data1}\[Transpose]",
"b"->"{range,data2}\[Transpose]"
|>;
ToExpression[Evaluate[dict[output]]]
]
End[];
EndPackage[];

The non-packaged version

Clear[func2]
func2[a_,b_,output_:"a"]:=Block[{range,data1,data2,dict},
range=Range[10];
data1 = Table[i^a,{i,10}];
data2=Table[i^b,{i,10}];
dict=<|
"a"->"{range,data1}\[Transpose]",
"b"->"{range,data2}\[Transpose]"
|>;
ToExpression[Evaluate[dict[output]]]
]

Output

func1[2,4,"a"] (* the packaged function *)
func2[2,4,"a"]  (* the non-packaged function *)

If someone could please explain why this happens or better yet suggest an alternative I would be very grateful.

Answer 1

Explanation

When you evaluate

BeginPackage["SE`Question`"]

it resets the $ContextPath (EndPackage resets it back). A consequence of this is that when new symbols are encountered they will be in the

SE`Question

context. So, in your Block, the symbol data1 is (fully qualified)

SE`Question`data1

Now, when you're back in the Global context and you evaluate func1[2, 4, "a"], the data1 string becomes the data1 symbol, but that symbol fully qualified is

Global`data1

So, it doesn't have the value that you expect (and apparently is undefined, which is why it just displays as itself without resolving to some other value).

The simple fix

Just don't wrap your expressions in strings:

BeginPackage["AnotherSE`Question`"];
func4; (*declared in public part of package*)
Begin["`Private`"];
func4[a_, b_, output_ : "a"] := 
Block[
  {range, data1, data2, dict, dat1, dat2}, 
  range = Range[10];
  data1 = Table[i^a, {i, 10}];
  data2 = Table[i^b, {i, 10}];
  dict = <|"a" -> Transpose[{range, data1}], "b" -> Transpose[{range, data2}]|>;
  dict[output]]
End[];
EndPackage[];

The slightly better fix

In general, one should be careful to understand how variables are localized and to avoid letting local variables "leak". In your case, you don't need all of those extraneous variables at all.

BeginPackage["NewSE`Question`"];
func3; (*declared in public part of package*)
Begin["`Private`"];
func3[a_, b_] := func3[a, b, "a"];
func3[a_, _, "a"] := theRealStuff[a];
func3[_, b_, "b"] := theRealStuff[b];
func3[___] := "func3 is undefined for these arguments";
theRealStuff[x_] := Transpose[{Range[10], Range[10]^x}];
End[];
EndPackage[];

But even this is really awkward. A function that doesn't depend on some of its arguments should be a red flag. Maybe this is just a consequence of you trying to simplify your real problem, but if this is truly representative of what you're trying to do, then a better pattern would be to make the choice of which value to pass to the function outside of the function, as opposed to using a flag to choose which argument to process inside the function. But since you haven't shown us the larger context in which you'd choose the "a" or "b" flags, I don't have a demonstration for how to do that.