How to make frame labels like in this plot?

Question

How to make the Frame Labels like in this plot

I mean the Frame Labels are placed above the plot in different rows left and right with different colors. Also besides the plot.

Answer 1

Edit: as per the request the following encodes all the requirements

Labeled[
 ListPlot[
  RandomReal[10, 100],
  ImageSize -> Large,
  Frame -> True,
  FrameLabel -> {
    {Column[{Style["Column1", FontFamily -> "League Gothic", 
        FontSize -> 20, Red], 
       Style["Column2", FontFamily -> "Papyrus", FontSize -> 30, 
        Blue]}], None}, {Grid@{
       {
        Style["All masses are below 120 GeV", 
         FontFamily -> "League Gothic", FontSize -> 20, Magenta],
        Style["We need some new results", FontFamily -> "Button", 
         FontSize -> 20, Darker[Yellow]]
        },
       {
        Style[
         "\!\(\*SubscriptBox[\(m\), \(h\)]\) vs \
\!\(\*FractionBox[SubscriptBox[\(X\), \(t\)], SubscriptBox[\(M\), \
\(SUSY\)]]\)", FontFamily -> "League Gothic", FontSize -> 20, Green],
        Style[
         "All 120 GeV < some stuff < 150 \!\(\*SubscriptBox[\(M\), \
\(SUSY\)]\)", FontFamily -> "Academy Engraved LET", FontSize -> 20, 
         Darker[Green]]
        }
       },
     Column[
      {Style["AdS/CFT rules", FontFamily -> "Brush Script MT", 
        FontSize -> 20, Purple], 
       Style["some energy scale", FontFamily -> "SignPainter", 
        FontSize -> 20, Orange],
       Style["compute more things", FontFamily -> "Zapfino", 
        FontSize -> 20, Black]
       }
      ]
     }
    }
  ],
 Grid[
  {{Style["Title: some CERN stuff", FontSize -> Scaled[0.03], 
     FontFamily -> "League Gothic"]}}],
 {{Left, Top}}
 ]

Original

Since, for once more, people cannot come up with MWE (minimal working example) the following should be sufficient. The general idea is the use Overlay

lp1 = ListPlot[RandomReal[10, 1000], PlotStyle -> Black, 
   ImagePadding -> 65, Frame -> {True, True, True, False}, 
   FrameLabel -> {{"Some CERN stuff", 
      "still no SUSY @ high energy"}, {"does not matter", 
      "holography rules"}}, 
   PlotLabel -> 
    Style["Some CERN stuff probably", 22, "Button", Purple], 
   FrameStyle -> {{Directive[FontColor -> Blue, 
       FontFamily -> "League Gothic", FontSize -> 16], 
      Automatic}, {Directive[FontColor -> Orange, 
       FontFamily -> "Brush Script MT", FontSize -> 20], 
      Directive[FontColor -> Black, FontFamily -> "SignPainter", 
       FontSize -> 20]}}, ImageSize -> Large];
lp2 = ListLinePlot[Accumulate@RandomReal[100, 10], PlotStyle -> Red, 
   ImagePadding -> 65, Axes -> False, 
   Frame -> {False, False, False, True}, 
   FrameTicks -> {{None, All}, {None, None}}, 
   PlotLabel -> 
    Style["Some CERN stuff probably", 22, "Button", Purple], 
   FrameLabel -> {{"Some CERN stuff", 
      "still no SUSY @ high energy"}, {"does not matter", 
      "holography rules"}}, 
   FrameStyle -> {Automatic, Automatic, Automatic, 
     Directive[FontColor -> Red, FontFamily -> "Papyrus", 
      FontSize -> 13]}, ImageSize -> Large];
Overlay[{lp1, lp2}]