4
$\begingroup$

I have two eigenvalues that are given as functions of two parameters $a$ and $b$

$$\lambda_1 = - a -\sqrt{ a ^2-b^2}, \lambda_2 =- a + \sqrt{ a^2-b^2}$$

I have a restriction that $a \gt b > 0$.

I have been trying all sorts of things to determine places where the signs are the same (both negative, both positive, different signs, etc.), but nothing has worked.

For example, I tried numerical approaches, but that is kludgy

   Table[{a,b,-a-Sqrt[a^2-b^2],-a+Sqrt[a^2-b^2]},{a,2,4},{b,0.1,2}]//N
   

I tried to compare contour plots, but I cannot seem to make use of them

   ContourPlot[-a - Sqrt[a^2 - b^2], {a, 0, 5}, {b, 0, 5}]

I also tried a simplify and reduce approach using

  FullSimplify[{a > b > 0, -a + Sqrt[a^2 - b^2] > 0}, a > 0 && b > 0]

  FullSimplify[{a > b > 0, -a - Sqrt[a^2 - b^2] > 0}, a > 0 && b > 0]

  Reduce[{a > b > 0, -a + Sqrt[a^2 - b^2] < 0}, {a, b}]

Results are not satisfying and not producing a useful result.

I tried using Manipulate with StreamPlot, which shows what I want to see, but is still kludgy

   Manipulate[StreamPlot[{y,-b^2 x - 2 a y},{x,-5,5},{y,-5,5},PlotLabel->Row[{"a = ",a," ,  b = ",b}]],{a,0,5},{b,0,5}]

Is there some elegant way to display a comparison between those two expressions that shows the sign relationship of them and particularly if there are places where they switch sign?

Maybe I am missing something basic!

$\endgroup$

2 Answers 2

5
$\begingroup$
  • RegionPlot. When a>b>0,-a + Sqrt[a^2 - b^2] and -a - Sqrt[a^2 - b^2] are both negative.
Clear[f, g];
f[a_, b_] = -a - Sqrt[a^2 - b^2];
g[a_, b_] = -a + Sqrt[a^2 - b^2];
GraphicsRow@{RegionPlot[
   f[a, b] < 0 && g[a, b] < 0, {a, 0, 4}, {b, 0, 4}, PlotPoints -> 50],
  RegionPlot[f[a, b] > 0 && g[a, b] > 0, {a, 0, 4}, {b, 0, 4}, 
   PlotPoints -> 50],
  RegionPlot[
   f[a, b] > 0 && g[a, b] < 0 || f[a, b] < 0 && g[a, b] > 0, {a, 0, 
    4}, {b, 0, 4}, PlotPoints -> 50]}

enter image description here

$\endgroup$
5
$\begingroup$

If I understand you correctly, try this:

    Plot3D[{-a - Sqrt[a^2 - b^2], -a + Sqrt[a^2 - b^2]}, {a, 0, 5}, {b, 0,
   5}, PlotStyle -> {{Blue, Opacity[0.5]}, {Orange, Opacity[0.5]}}, 
 AxesLabel -> {"a", "b", "expr"}]

yielding the following:

enter image description here

One can see that the orange surface at 0<a<5 && 0<b<5 everywhere lies over the blue one.

On the other hand, one can use Reduce as follows:

Reduce[(-a - Sqrt[a^2 - b^2] < -a + Sqrt[a^2 - b^2]) && b > 0 && a > b]

(*   b > 0 && a > b  *)

which means that provided b > 0 && a > b the inequality -a - Sqrt[a^2 - b^2] < -a + Sqrt[a^2 - b^2] always holds.

Have fun!

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.