Interrupted plot lines when multiple branches of an ODE solution are plotted

Question

I am plotting the following:

Plot[Evaluate[
  Table[Piecewise[{{Abs[x]*Sqrt[Log[x^2] + 2 i], 
      x < -Exp[-i]}, {Abs[x]*Sqrt[Log[x^2] + 2 i], x > Exp[-i]}}, 
    None], {i, -2, 3, 1}]], {x, -3, 3}, 
 PlotRange -> {Automatic, {0, 1}}]

What I am getting is this:

The two lines closest to the y axis are interrupted. Why? And why the plot line starts further and further away from zero as one increases the i? The one sided limits are clear and the function tends to zero... Now, if I only print a single branch there are no interruptions.

Plot[Evaluate[
  Table[Piecewise[{{Abs[x]*Sqrt[Log[x^2] + 2 i], 
      x < -Exp[-i]}, {Abs[x]*Sqrt[Log[x^2] + 2 i], x > Exp[-i]}}, 
    None], {i, 1, 1, 1}]], {x, -3, 3}, 
 PlotRange -> {Automatic, {0, 1}}]

Note, my piecewise definition might be wrong, I was trying to tell mathematica that for $|x|<e^{-i}$ the function is not defined, if I don't include the None portion, Mathematica keeps connecting the points $-e^{-i}$ and $e^{-i}$ with a line at $y=0$ which is wrong and this was the only way that I was able to find to prevent this behaviour.

Answer 1

This shows that the gaps come from discontinuities in one function being applied to other functions in the Plot. You can use Exclusions -> None to remove them, or plot each function individually.

gl = Table[
     Piecewise[{{Abs[x]*Sqrt[Log[x^2] + 2 i], 
        x < -Exp[-i]}, {Abs[x]*Sqrt[Log[x^2] + 2 i], x > Exp[-i]}}, 
      None], {i, -2, 3, 1}] // 
    Map[SolveValues[FunctionDiscontinuities[#, x], x] &] // N // 
  Apply@Union
(*
{-7.38906, -2.71828, -1., -0.367879, -0.135335, -0.0497871, \
0.0497871, 0.135335, 0.367879, 1., 2.71828, 7.38906}
*)

Plot[Evaluate[
  Table[Piecewise[{{Abs[x]*Sqrt[Log[x^2] + 2 i], 
      x < -Exp[-i]}, {Abs[x]*Sqrt[Log[x^2] + 2 i], x > Exp[-i]}}, 
    None], {i, -2, 3, 1}]], {x, -3, 3}, 
 PlotRange -> {Automatic, {0, 1}}, 
 GridLines -> {gl, None}(*,Exclusions->None*)]