How to gather functions which intersect at the same point?

Question

How to gather functions which intersect at the same point (real solution)?

func = {2 x, x^2 + 1, (x^3 + 3)/2};

For example, with the list of functions above I want it to be divided into 3 groups as follows:
(I'm not sure if I missed any, I just looked at the plot to group them)

out= {{2 x, x^2 + 1, (x^3 + 3)/2}, {2 x, (x^3 + 3)/2}, { x^2 + 1, (x^3 + 3)/2}}

EDIT: rhermans gave a nice answer. However, I didn't know that the number of functions would change the approach. I should have mentioned that in my case, the number of functions is quite large, probably 100 or more. So some apporach may work very nice for small number of functions but cause insufficient memory with large number of functions.

Answer 1

This goes through all $2^n -n -1$ subsets of length 2 or more. An overkill that allows very simple code, but it's not practical for large $n$. See other answer(s).

func = {2 x, x^2 + 1, (x^3 + 3)/2};
GroupBy[
    Subsets[func, {2,Infinity}]
    , N[x/.Solve[Equal@@#, Reals]]&
]

<|
    {1., 1.} -> {{2 x, 1 + x^2}},
    {1., -2.30278, 1.30278} -> {{2 x, 1/2 (3 + x^3)}},
    {1., -0.618034, 1.61803} -> {{1 + x^2, 1/2 (3 + x^3)}},
    {1.} -> {{2 x, 1 + x^2, 1/2 (3 + x^3)}}
|> 

This should be interpretes as

• Functions {2 x, 1 + x^2} all intercept only at {1., 1.}
• Functions {2 x, 1/2 (3 + x^3)} all intercept only at {1., -2.30278, 1.30278}
• Functions {1 + x^2, 1/2 (3 + x^3)} all intercept only at {1., -0.618034, 1.61803}
• Functions {2 x, 1 + x^2, 1/2 (3 + x^3)} all intercept only at {1.}

Or probably, depending what you mean

Union@@@GroupBy[
    Subsets[func, {2,Infinity}]
    , Union[N[x/.Solve[Equal@@#, Reals]]]&
]

<|
    {1.} -> {2 x, 1 + x^2, 1/2 (3 + x^3)},
    {-2.30278, 1., 1.30278} -> {2 x, 1/2 (3 + x^3)}, 
    {-0.618034, 1., 1.61803} -> {1 + x^2, 1/2 (3 + x^3)}
|> 

Answer 2

This goes only through all $(n^2-n)/2$ Subsets[func, {2}] as suggested by @Syed. For $n=100$ that is only $4950$ cases.

It calculates the intersection points of all equation pairs. Then it checks if a particular point liven in each function. Then it groups the functions based on which intersection points they share.

ClearAll[check];
check[expr_][ pnt_] := Equal[expr/.x->First[pnt], Last[pnt]]

With[
    {
        pntlist = Union@Flatten[{x, First[#]}/.Solve[Equal@@#,x,Reals]& /@Subsets[func, {2}],1]
    },
    GroupBy[Last->First]@
    Flatten[
        Table[
            {e,#}& /@ Select[pntlist, check[e]]
            , {e, func}]
        ,1
    ]
]