5
$\begingroup$

Let us consider in 13.2 on Windows 10

FourierTransform[1/Sinh[x]^2, x, k]

-((2 + k \[Pi] Coth[(k \[Pi])/2])/Sqrt[2 \[Pi]])

This is not a usual Fourier transform beacause of a non-integrable singularity at the origin

Series[1/Sinh[x]^2, {x, 0, 2}]

1/x^2-1/3+x^2/15+O[x]^3

Neither Wiki nor Kammler, David (2000), A First Course in Fourier Analysis, Prentice Hall, ISBN 978-0-13-578782-3 contain this formula (BTW, the "Fourier transform" as well as "Homosexuality" articles in English Wiki are permanently edited.).

Next, let us return to the original function by

InverseFourierTransform[-((2 + k \[Pi] Coth[(k \[Pi])/2])/Sqrt[2 \[Pi]]), k, x] // FullSimplify

Csch[x]^2 - 2 DiracDelta[x]

As we see, the fundamental property of the Fourier transform InverseFourierTransform[FourierTransform[f[t], t, \[Omega]], \[Omega], t]==f[t] does not hold in this case. Is it a bug or I don't understand something?

$\endgroup$
3
  • $\begingroup$ @bmf I can recover OP's result. For this one InverseFourierTransform[FourierTransform[f[t], t, ω], ω, t]==f[t] I think MMA just stores this property for symbolics. $\endgroup$
    – Lacia
    Jan 11, 2023 at 9:14
  • $\begingroup$ @yurie I was being blind to something in my notebook... $\endgroup$
    – bmf
    Jan 11, 2023 at 9:16
  • $\begingroup$ There shouldn't be the constant term. Since Coth's Fourier transform is Coth, and we take derivative getting 1/Sinh[x]^2, then in the momentum space we get k Coth[k]. $\endgroup$
    – Lacia
    Jan 11, 2023 at 9:18

1 Answer 1

4
$\begingroup$

I have no explanation for the problematic transform. I will show instead a way to get the correct one.

We treat this as 1/x^2 * x^2/Sinh[x]^2. We take the Fourier transform as the convolution of the separate transforms for 1/x^2 and x^2/Sinh[x]^2. We handle that latter using Integrate directly.

ftoneoverx2 = FourierTransform[1/x^2, x, k]

(* Out[648]= -k Sqrt[\[Pi]/2] Sign[k] *)

ftx2overSinhx2 = 
 1/(2*Pi)*
  Integrate[Exp[-I*k*x]*x^2/Sinh[x]^2, {x, -Infinity, Infinity}, 
   Assumptions -> {Element[k, Reals], e > 0}]

(* Out[649]= (\[Pi] (-2 + k \[Pi] Coth[(k \[Pi])/2]))/(2 (-1 + 
   Cosh[k \[Pi]])) *)

Convolve these.

ft = 
 Simplify[
  Integrate[
   ftx2overSinhx2*(ftoneoverx2 /. k -> t - k), {k, -Infinity, 
    Infinity}, Assumptions -> Element[t, Reals]]]

(* Out[650]= -(((1 + E^(\[Pi] t)) Sqrt[\[Pi]/2] t)/(-1 + E^(\[Pi] t))) *)

Check that we recover the original function on taking the inverse transform.

ift = InverseFourierTransform[ft, t, x]

(* Out[651]= Csch[x]^2 *)

--- edit ---

I was asked about verifying some of these. ftoneoverx2 is, up to constant factor dependent on parameter settings, well known. It's in an appendix in the book by Kammler for example. Here is a numerical check for the next part.

ftx2overSinhx2 /. k -> {-1.4, 3.7}
{1/(2*Pi)*
  NIntegrate[Exp[-I*(-1.4)*x]*x^2/Sinh[x]^2, {x, -Infinity, Infinity}],
 1/(2*Pi)*
  NIntegrate[Exp[-I*(3.7)*x]*x^2/Sinh[x]^2, {x, -Infinity, Infinity}]}

(* Out[98]= {0.0993251, 0.000270598}

Out[99]= {0.0993251 + 0. I, 0.000270598 + 0. I} *)

We can check ft in the same way.

ft /. t -> {-1.4, 3.7}
{NIntegrate[
  ftx2overSinhx2*(ftoneoverx2 /. k -> -1.4 - k), {k, -Infinity, 
   Infinity}], 
 NIntegrate[
  ftx2overSinhx2*(ftoneoverx2 /. k -> 3.7 - k), {k, -Infinity, 
   Infinity}]}

(* Out[101]= {-1.79834, -4.63735}

Out[102]= {-1.79834, -4.63735} *)

--- end edit ---

$\endgroup$
12
  • $\begingroup$ I am out of MMA so I ' ll respond later. $\endgroup$
    – user64494
    Jan 11, 2023 at 17:44
  • $\begingroup$ Thank you for your work. I can reproduce it in both 13.1 and 13.2. However, this generates more questions: (i) Convolve[ftoneoverx2, ftx2overSinh2, k, t] produces ``(1/(6 (-1 + E^([Pi] t)) Sqrt[ 2 [Pi]]))(12 I [Pi] - 12 I E^([Pi] t) [Pi] - 2 [Pi]^2 + 2 E^([Pi] t) [Pi]^2 - 6 [Pi] t - 6 E^([Pi] t) [Pi] t + 12 I [Pi]^2 t - 12 I E^([Pi] t) [Pi]^2 t + 6 [Pi] t Log[1/(1 - E^([Pi] t))] - 6 E^([Pi] t) [Pi] t Log[1/(1 - E^([Pi] t))] - 6 Log[1/(1 - E^([Pi] t))] Log[-1 +... 6 (-1 + E^([Pi] t)) PolyLog[2, E^([Pi] t)/(-1 + E^([Pi] t))])` , not your result. $\endgroup$
    – user64494
    Jan 11, 2023 at 20:05
  • $\begingroup$ While I agree that Convolve seems likely to do what you intend, I'm not familiar with it's design or implementation. $\endgroup$ Jan 11, 2023 at 20:14
  • $\begingroup$ (ii)FourierTransform[x^2/Sinh[x]^2, x, k] produces (-2 \[Pi]^2 Csch[(k \[Pi])/2]^2 + k \[Pi]^3 Coth[(k \[Pi])/2] Csch[(k \[Pi])/2]^2)/(2 Sqrt[2 \[Pi]]),. not ftx2overSinh2. (iii) Formula 310 in Wiki is given without any reference so it is not reliable . $\endgroup$
    – user64494
    Jan 11, 2023 at 20:22
  • $\begingroup$ I was aware FT did not correctly handle x^2/Sinh[x]^2. That's why I used Integrate. $\endgroup$ Jan 11, 2023 at 23:49

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.