How to drop `Infinity` AND 'Indeterminate' elements from an equation?

Question

This is a simple question but somehow after trying Delete, and Drop I still cannot get what I want. Given the following equation,

eq = (-0.818158 + 
0.725806 Log[0.683526 λ[1., 2.]] λ[1., 2.] + 
0.774194 Log[0.744189 λ[2., 1.]] λ[2., 1.] + 
0.774194 Log[0.744189 λ[2., 3.]] λ[2., 
 3.])/(0.951613 - 0.725806 (0.0444444 + λ[1., 2.]) - 
0.774194 (0.0208333 + λ[2., 1.] + λ[2., 3.]));

I want to drop from this equation all the terms that involve Lambda. (A term is an element between two arithmetic signs like + and -.) because the Lambda is equal to zero and taking Log[0] is infinite. So, I like to get rid of Infinity and have a real number as a solution.

Generally speaking, given a list of very large equations, I like to drop Lambda terms with zero from all the equations.

I think it is easier to drop all the terms that generate infinity.

Answer 1

I don't think that there's anything wrong with the answer by @Nasser and I have upvoted, but since there are some complains below is an alternative.

Logic:

1. Split the equation to a List
2. Evaluate all the terms of the aforementioned List for the value of $\lambda$ that causes the infinity
3. Drop infinities
4. Sum the elements

It works roughly like this:

With

eq = (-0.818158 + 
     0.725806 Log[0.683526 λ[1., 2.]] λ[1., 2.] + 
     0.774194 Log[0.744189 λ[2., 1.]] λ[2., 1.] + 
     0.774194 Log[0.744189 λ[2., 3.]] λ[2., 
       3.])/(0.951613 - 0.725806 (0.0444444 + λ[1., 2.]) - 
     0.774194 (0.0208333 + λ[2., 1.] + λ[2., 3.]));

Create the list

List @@ (eq // Rationalize // Expand)

output is:

Impose the condition that $\lambda$ is zero

List @@ (eq // Rationalize // Expand) /. λ[_, _] -> 0

with the output

Observe that Mathematica yields Indeterminate and not Infinity

Then, we proceed as

Select[List @@ (eq // Rationalize // Expand) /. λ[_, _] -> 0, 
 FreeQ[Indeterminate]]

If there were more finite numerical elements you could do a Total

Addendum: demonstrating what I mentioned at the end.

Consider the following equation, which is the original with the modification that I added a 3

eq = (-0.818158 + 
     0.725806 Log[0.683526 λ[1., 2.]] λ[1., 2.] + 
     0.774194 Log[0.744189 λ[2., 1.]] λ[2., 1.] + 
     0.774194 Log[0.744189 λ[2., 3.]] λ[2., 
       3.])/(0.951613 - 0.725806 (0.0444444 + λ[1., 2.]) - 
     0.774194 (0.0208333 + λ[2., 1.] + λ[2., 3.])) + 3;

Then

Total@(Select[
   List @@ (eq // Rationalize // Expand) /. λ[_, _] -> 0, 
   FreeQ[Indeterminate]])

gives back

Answer 2

Are you looking for this limit?

Limit[eq, {λ[1., 2.] -> 0, λ[2., 1.] -> 0, λ[2., 3.] -> 0}]
(*    -0.905818    *)

With automatic generation of the list of $\lambda$ variables:

Λ = Union[Cases[eq, λ[___], ∞]]
(*    {λ[1., 2.], λ[2., 1.], λ[2., 3.]}    *)

Limit[eq, Thread[Λ -> 0]]
(*    -0.905818    *)

Answer 3

-0.905818 is the result I obtain from the equation by manually dropping the infinity terms.

In this case you could try

eq /. Log[_ * λ[_, _]] -> 1 /. λ[_, _] -> 0

But if you want to keep the λ, and only remove the log terms, you can try

eq /. Log[_ * λ[_, _]] -> 1

I do not know if this will work for all your expressions. I only tried it on the one you gave.

Answer 4

Here's a version of my original suggestion that gives the desired result:

Replace[eq, s : Except[_?AtomQ, _Plus] :> Select[s, FreeQ[λ]], All]
(* -0.905818 *)

The original version used ReplaceAll instead of Replace[...,All], which resulted in the λ terms being deleted at the outermost level, rather than at the innermost level (see also this question).

The other trick that is required is Except[_?AtomQ,_Plus] instead of simply _Plus. This is needed because _Plus also matches atoms such as 1 due to the OneIdentity attribute of Plus, which then breaks Select