8
$\begingroup$

enter image description here

Manipulate[
 ParametricPlot[{Sec[t], Tan[t]}, {t, 0, u}, PlotStyle -> Dashed, 
  PerformanceGoal -> "Quality", Exclusions -> All, 
  PlotRange -> 2], {u, 0.001, 2 Pi}]

I found that for parametric curves with singularities, using ParametricPlot with the dahed line style, there will be shake in some animations, is there a simple way to eliminate shake?

$\endgroup$
3
  • $\begingroup$ it is not shaking. This is just illusion. It is due to the line being drawn each time and the dashes show at different spots on the screen each time. $\endgroup$
    – Nasser
    Dec 21, 2022 at 9:19
  • $\begingroup$ @Nasser: Isn't it obvious that OP wants to eliminate exactly this redrawn at different spots? Describing it as shaking has perfect sense to me. $\endgroup$ Dec 21, 2022 at 10:30
  • $\begingroup$ @azerbajdzan I was just saying it is not actually shaking. But an illusion of shaking due to the dashes being drawn at different places each time. That is all. I do not see what the problem with me saying this. $\endgroup$
    – Nasser
    Dec 21, 2022 at 11:06

2 Answers 2

7
$\begingroup$
Manipulate[
 ParametricPlot[{Sec[t], Tan[t]}, {t, 0, 2 Pi}, 
  PlotStyle -> Dashed, 
  PerformanceGoal -> "Quality",
  Exclusions -> All, 
  PlotRange -> 2, 
  RegionFunction -> (#3 <= u &)], 
 {u, 0.001, 2 Pi}]

enter image description here

$\endgroup$
4
  • 3
    $\begingroup$ Hi kglr! I hope you are fine. I used to follow your solutions and was a little worried as you were not around during last months. I have learned a lot from you and hope everything is fine on your side. $\endgroup$
    – user88712
    Dec 21, 2022 at 22:24
  • 2
    $\begingroup$ It's nice to know that there is a real sense of community here. I think that, like you @Marteen, I have learned a lot from kglr and other great users, and I always worry when they are absent. $\endgroup$ Dec 22, 2022 at 5:04
  • 1
    $\begingroup$ @Marteen, thank you so much for the kind words and well wishes. I've had to take some time off from stack exchange to attend to a few matters back on earth:) Hoping to visit the site more often in a few months. $\endgroup$
    – kglr
    Dec 22, 2022 at 9:57
  • 1
    $\begingroup$ @E.Chan-López, thank you so much for your concern and kind words. I really appreciate it. $\endgroup$
    – kglr
    Dec 22, 2022 at 9:58
7
$\begingroup$
pl = ParametricPlot[{Sec[t], Tan[t]}, {t, 0, 2 \[Pi]}, 
   PlotStyle -> Directive[Dashed, Thick, White], 
   PerformanceGoal -> "Quality", Exclusions -> All, PlotRange -> 2];
Manipulate[
 Show[ParametricPlot[{Sec[t], Tan[t]}, {t, 0, u}, 
   PerformanceGoal -> "Quality", Exclusions -> All, PlotRange -> 2], 
  pl], {u, 0.001, 2 Pi}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.