2
$\begingroup$

I am trying to define in Mathematica the quantity $\star F^{\mu}=\frac{1}{2}\epsilon^{\mu\alpha\beta}F_{\alpha\beta}$, where $F_{\mu\nu}=\nabla_\mu A_\nu-\nabla_\nu A_\mu+\left[A_\mu,A_\nu\right]$. Here $\nabla$ is the spacetime covariant derivative of the metric $ds^2=-dt^2+R^2dr^2+L^2d\phi^2$. In the field strength $F_{\mu\nu}$ the gauge field $A_\mu$ is defined as $A=A^j_\mu t_j dx^\mu$ where $t_j=i\sigma_j$ with $\sigma_j$ the $j=1,2,3$ Pauli matrices and $$A_\mu=\lambda(x) U^{-1}\partial_\mu U\,\quad U(x)=\cos[\alpha(x)]I_{2\times 2}+\sin[\alpha(x)]n^it_i,$$ with $$n^1=\sin\left[\Theta(x)\right]\cos\left[\Phi(x)\right],\quad n^2=\sin\left[\Theta(x)\right]\sin\left[\Phi(x)\right],\quad n^3=\cos\left[\Theta(x)\right].$$ When I compute $\star F^\mu$ with the previous functions, I obtain an expression of the form Sin[1[t, r, \[Phi]]] or Sin[2 1[t, r, \[Phi]]], which seems pathological. This is my question.

Let me show my code below and explain it, step by step.

First, the spacetime is defined as

Coords = {t, r, \[Phi]};
    gdd = {{-1, 0, 0}, {0, \[Rho]^2, 0}, {0, 0, L^2}}
    gUU = Inverse[gdd]
    dimM = Dimensions[gdd][[1]]

Then I define the General Relativity tensors, i.e., Christoffel Symbols, Riemann tensors and so on (this is not important, however, I put them for completeness and perhaps this code will be helpful for somebody)

\[CapitalGamma]Udd = 
      1/2 Table[
         Sum[gUU[[\[Mu] + 1, \[Tau] + 
             1]] (D[gdd[[\[Lambda] + 1, \[Tau] + 1]], 
              Coords[[\[Nu] + 1]]] + 
             D[gdd[[\[Nu] + 1, \[Tau] + 1]], Coords[[\[Lambda] + 1]]] - 
             D[gdd[[\[Nu] + 1, \[Lambda] + 1]], 
              Coords[[\[Tau] + 1]]]), {\[Tau], 0, dimM - 1}], {\[Mu], 0, 
          dimM - 1}, {\[Nu], 0, dimM - 1}, {\[Lambda], 0, dimM - 1}] // 
       Simplify;
    RUddd = Table[
         D[\[CapitalGamma]Udd[[\[Alpha] + 1, \[Beta] + 1, \[Delta] + 1]], 
          Coords[[\[Gamma] + 1]]], {\[Alpha], 0, dimM - 1}, {\[Beta], 0, 
          dimM - 1}, {\[Gamma], 0, dimM - 1}, {\[Delta], 0, dimM - 1}] - 
        Table[D[\[CapitalGamma]Udd[[\[Alpha] + 1, \[Beta] + 1, \[Gamma] + 
            1]], Coords[[\[Delta] + 1]]], {\[Alpha], 0, 
          dimM - 1}, {\[Beta], 0, dimM - 1}, {\[Gamma], 0, 
          dimM - 1}, {\[Delta], 0, dimM - 1}] + 
        Table[Sum[\[CapitalGamma]Udd[[\[Mu] + 1, \[Beta] + 1, \[Delta] + 
             1]] \[CapitalGamma]Udd[[\[Alpha] + 1, \[Mu] + 1, \[Gamma] + 
             1]], {\[Mu], 0, dimM - 1}], {\[Alpha], 0, 
          dimM - 1}, {\[Beta], 0, dimM - 1}, {\[Gamma], 0, 
          dimM - 1}, {\[Delta], 0, dimM - 1}] - 
        Table[Sum[\[CapitalGamma]Udd[[\[Mu] + 1, \[Beta] + 1, \[Gamma] + 
             1]] \[CapitalGamma]Udd[[\[Alpha] + 1, \[Mu] + 1, \[Delta] + 
             1]], {\[Mu], 0, dimM - 1}], {\[Alpha], 0, 
          dimM - 1}, {\[Beta], 0, dimM - 1}, {\[Gamma], 0, 
          dimM - 1}, {\[Delta], 0, dimM - 1}] // Simplify;
    Rdd = Table[
        Sum[RUddd[[\[Alpha] + 1, \[Beta] + 1, \[Alpha] + 1, \[Delta] + 
           1]], {\[Alpha], 0, dimM - 1}], {\[Beta], 0, 
         dimM - 1}, {\[Delta], 0, dimM - 1}] // Simplify;
    R = Sum[gUU[[\[Beta] + 1, \[Delta] + 1]] Rdd[[\[Beta] + 1, \[Delta] + 
           1]], {\[Beta], 0, dimM - 1}, {\[Delta], 0, dimM - 1}] // 
       Simplify;
    Einsteindd = Rdd - 1/2 gdd R;

Here begins the important part. I define the Pauli matrices, the normal vector $n^i$, the matrix $U$, its inverse and the gauge field $A_\mu$

ColorCoords = {t, r, \[Phi]};
dimC = 3;
t1 = I PauliMatrix[1];
t2 = I PauliMatrix[2];
t3 = I PauliMatrix[3];
td = {{t1}, {t2}, {t3}};
tdd = -(1/2) Table[
    Tr[td[[a + 1, 1]].td[[b + 1, 1]]], {a, 0, dimC - 1}, {b, 0, 
     dimC - 1}];
tUU = Inverse[tdd];
tU = Sum[Table[tUU[[a + 1, b + 1]] td[[b + 1]], {b, 0, dimC - 1}], {a,
     0, dimC - 1}];
nU = {{Sin[\[CapitalTheta][t, r, \[Phi]]] Cos[\[CapitalPhi][t, 
       r, \[Phi]]]}, {Sin[\[CapitalTheta][t, 
       r, \[Phi]]] Sin[\[CapitalPhi][t, 
       r, \[Phi]]]}, {Cos[\[CapitalTheta][t, r, \[Phi]]]}};
nd = Table[
   Sum[nU[[a + 1]] tdd[[a + 1, b + 1]], {a, 0, dimC - 1}], {b, 0, 
    dimC - 1}];
U = Cos[\[Alpha][t, r, \[Phi]]] IdentityMatrix[2] + 
    Sin[\[Alpha][t, r, \[Phi]]] Sum[
      nU[[a + 1, 1]] td[[a + 1, 1]], {a, 0, dimC - 1}] // Simplify;
Uinv = Inverse[U] // Simplify;
Ad = \[Lambda][t, r, \[Phi]] Table[
     Uinv.D[U, ColorCoords[[\[Mu] + 1]]], {\[Mu], 0, dimC - 1}] // 
   FullSimplify;

Defining now the covariant derivative of the gauge field $\nabla_\mu A_\nu$

covDAd = Table[D[Ad, Coords[[\[Mu] + 1]]], {\[Mu], 0, dimM - 1}] - 
    Sum[Table[\[CapitalGamma]Udd[[\[Lambda]1 + 1, \[Mu] + 1, \[Nu] + 
          1]] Ad[[\[Lambda]1 + 1]], {\[Mu], 0, dimM - 1}, {\[Nu], 0, 
       dimM - 1}], {\[Lambda]1, 0, dimM - 1}] // Simplify;

we are now in a position to define the field strength

Fdd = covDAd - Transpose[covDAd] + 
   Table[Ad[[\[Mu] + 1]].Ad[[\[Nu] + 1]] - 
     Ad[[\[Nu] + 1]].Ad[[\[Mu] + 1]], {\[Mu], 0, dimM - 1}, {\[Nu], 0,
      dimM - 1}];

Now we are going to define the components of the dual field strength $*F^\mu$. In three-dimensions, the Levi-Civita symbol is defined as

LCd = Normal[LeviCivitaTensor[3]];
LCU = Normal[-LeviCivitaTensor[3]];
\[Epsilon]UUU = LCU;
\[Epsilon]ddd = LCd;

then, we define $\star F^\mu=\frac{1}{2}\epsilon^{\mu\alpha\beta}F_{\alpha\beta}$ as

dualFU = 1/
   2 Table[Sum[\[Epsilon]UUU[[\[Mu] + 1, \[Alpha] + 1, \[Beta] + 
         1]] Fdd[[\[Alpha] + 1, \[Beta] + 1]], {\[Alpha], 0, 
      dimM - 1}, {\[Beta], 0, dimM - 1}], {\[Mu], 0, dimM - 1}];

Observe that if we compute dualFU[[1, 1]] we quickly obtain terms of the form Cos[2 1[t, r, \[Phi]]], Sin[2 1[t, r, \[Phi]]] and so on. What am I doing wrong?

$\endgroup$
5
  • $\begingroup$ I tried to run your code, but ran into errors due to nU and tdd not being defined, causing Part to complain . These affect the evaluation of nd and U . If I push on anyway and evaluate the remaining terms, I get dualFU = {{{0,0},{0,0}},{{0,0},{0,0}},{{0,0},{0,0}}} and dualFU[[1,1]] = {0,0}. It's likely the missing terms will alter this result however, since you appear to compute derivatives of U, etc. $\endgroup$
    – user87932
    Dec 18, 2022 at 2:09
  • $\begingroup$ I edited the question and added the definition of tdd, so tell me now if you are able to compile the code. $\endgroup$ Dec 18, 2022 at 9:54
  • $\begingroup$ There are typos due to mixture of definition Ad = \[Lambda][t, r, \[Phi]] ... and index $\lambda$ in covDAd. Try covDAd = Table[D[Ad, Coords[[\[Mu] + 1]]], {\[Mu], 0, dimM - 1}] - Sum[Table[\[CapitalGamma]Udd[[\[Lambda]1 + 1, \[Mu] + 1, \[Nu] + 1]] Ad[[\[Lambda]1 + 1]], {\[Mu], 0, dimM - 1}, {\[Nu], 0, dimM - 1}], {\[Lambda]1, 0, dimM - 1}] // Simplify; $\endgroup$ Dec 18, 2022 at 12:15
  • $\begingroup$ Ok, I corrected the typos, but the error persists in dualFU. $\endgroup$ Dec 18, 2022 at 12:22
  • $\begingroup$ Maybe you need to refresh kernel? $\endgroup$ Dec 18, 2022 at 13:57

1 Answer 1

2
$\begingroup$

Using a fresh kernel, I can duplicate your results. One thing I noticed is that you appear to use \[Alpha][t,r,[Phi]] in U, but also sum over \[Alpha],\[Beta]. I tried changing the summation indices in dualFU to a,b, and the problem seems to go away. I.e. try

    dualFU = 
      1/2 Table[
           Sum[\[Epsilon]UUU[[\[Mu] + 1, a + 1, b + 1]] Fdd[[a + 1, 
              b + 1]], {a, 0, dimM - 1}, {b, 0, dimM - 1}], {\[Mu], 0, dimM-1}]    

I think Sum/Table are not only replacing the indices, but also the \[Alpha][t,r,\[Phi]] expression heads with \[Alpha] -> 0,1,2,3 in the sums. Since you use the summation indices in several places, it might be easier to just replace \[Alpha][t,r,\[Phi]] with something else which doesn't clash.

$\endgroup$
1
  • $\begingroup$ Awesome. Thank you, it solved my question. $\endgroup$ Dec 18, 2022 at 18:16

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.