# Why does V 13.2 DSolve now return no solution instead of implicit solution for some differential equations?

V 13.2 DSolve now returns {} as solution for some ode's, while V 13.1 returns solutions for same ode's but with Solve in the solution (i.e. implicit solutions).

The question is: why this change and is there a way/option to make DSolve return those implicit solutions instead of a no solution? I think implicit solution is better than no solution.

Or is it possible that those solutions returned by V 13.1 were wrong and that is why V 13.2 no longer returns them?

The following are two examples, I can find more if possible.

ode = (y'[x])^2 == Exp[4*x - 2*y[x]]*(y'[x] - 1)
DSolve[ode, y[x], x]
ode = 4*(y'[x])^2 + 2*Exp[2*x - 2*y[x]]*y'[x] - Exp[2*x - 2*y[x]] == 0
DSolve[ode, y[x], x]


The following is the output from V 13.1

Update

fyi, here is my hand solution to the first ode, verified by Mathematica

\begin{align*} \left( y^{\prime}\right) ^{2} & =e^{4x-2y}\left( y^{\prime}-1\right) \\ \ln\left( y^{\prime}\right) ^{2} & =\left( 4x-2y\right) +\ln\left( y^{\prime}-1\right) \\ 4x-2y & =\ln\left( y^{\prime}\right) ^{2}-\ln\left( y^{\prime}-1\right) \\ 4x-2y & =\ln\frac{\left( y^{\prime}\right) ^{2}}{y^{\prime}-1}\\ 2y & =4x-\ln\frac{\left( y^{\prime}\right) ^{2}}{y^{\prime}-1}\\ y & =2x-\frac{1}{2}\ln\left( \frac{\left( y^{\prime}\right) ^{2}% }{y^{\prime}-1}\right) \\ & =\phi\left( x,y^{\prime}\right) \end{align*} Let $$y^{\prime}=p$$ \begin{align} y & =2x-\frac{1}{2}\ln\left( \frac{p^{2}}{p-1}\right) \tag{1}\\ & =\phi\left( x,p\right) \nonumber \end{align} The above is d'Alembert ode. Differentiating w.r.t. $$x$$ gives \begin{align} y^{\prime} & =\frac{\partial\phi}{\partial x}+\frac{\partial\phi}{\partial p}\frac{dp}{dx}\nonumber\\ p & =2+\left( \frac{\left( \frac{2p}{p-1}-\frac{p^{2}}{\left( p-1\right) ^{2}}\right) \left( 1-p\right) }{2p^{2}}\right) \frac{dp}{dx}\nonumber\\ p-2 & =\left( \frac{2-p}{2p^{2}-2p}\right) \frac{dp}{dx}\tag{2} \end{align} The singular solution is when $$\frac{dp}{dx}=0$$ which gives $$p=2$$. From (1) this gives $$y=2x-\frac{1}{2}\ln4$$ The general solution is when $$\frac{dp}{dx}\neq0$$. Then (2) becomes \begin{align*} \frac{dp}{dx} & =\left( p-2\right) \left( \frac{2p^{2}-2p}{2-p}\right) \\ & =2p\left( 1-p\right) \end{align*} The above is separable. Solving for $$p$$ gives $$p=\frac{1}{1+ce^{-2x}}$$ Substituting the above solutions of $$p$$ in (1) gives \begin{align*} y & =2x-\frac{1}{2}\ln\left( \frac{\left( \frac{1}{1+ce^{-2x}}\right) ^{2}}{\frac{1}{1+ce^{-2x}}-1}\right) \\ & =2x-\frac{1}{2}\ln\left( \frac{-e^{4x}}{c\left( c+e^{2x}\right) }\right) \end{align*}

Verification

ClearAll[y,x];
ode = (y'[x])^2 == Exp[4*x - 2*y[x]]*(y'[x] - 1);
mysol=y->Function[{x},2*x-1/2*Log[-Exp[4*x]/(C[1]*(C[1]+Exp[2*x]))]];
ode/.mysol//Simplify
(*True*)

mysol2=y->Function[{x},2*x-1/2*Log[4]]
ode/.mysol2//Simplify
(*True*)

• +1. I don't understand the downvote without any explanation. Dec 17, 2022 at 9:53

"13.2.0 for Microsoft Windows (64-bit) (November 18, 2022)"

If we assume that x is real, DSolve 13.2 still produces solutions:

ode = (y'[x])^2 == Exp[4*x - 2*y[x]]*(y'[x] - 1);
DSolve[ode, y, x, Assumptions -> x \[Element] Reals]
Simplify[ode /. %]

(* {{y -> Function[{x}, 1/2 Log[1/4 (-E^(4 C[1]) - 2 E^(2 x + 2 C[1]))]]},
{y -> Function[{x}, Log[-Sqrt[2] Sqrt[-2 E^(4 C[1]) - E^(2 x + 2 C[1])]]]},
{y -> Function[{x}, Log[Sqrt[2] Sqrt[-2 E^(4 C[1]) - E^(2 x + 2 C[1])]]]}} *)
(* {True, True, True} *)

ode = 4*(y'[x])^2 + 2*Exp[2*x - 2*y[x]]*y'[x] - Exp[2*x - 2*y[x]] == 0;
DSolve[ode, y, x, Assumptions -> x \[Element] Reals]
Simplify[ode /. %]

(* {{y -> Function[{x}, Log[-Sqrt[2] Sqrt[2 E^(2 C[1]) - E^(x + C[1])]]]},
{y -> Function[{x}, Log[Sqrt[2] Sqrt[2 E^(2 C[1]) - E^(x + C[1])]]]},
{y -> Function[{x}, 1/2 Log[1/4 (E^(2 C[1]) + 2 E^(x + C[1]))]]}} *)
(* {True, True, True} *)


although with the Solve warning message, "Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information."

"12.3.1 for Microsoft Windows (64-bit) (June 19, 2021)"

Solutions given in the question for Version 13.1 can be simplified greatly for real x. I no longer have 13.1.0, but I do have 12.3.1, which gives the same solutions. For the first ODE in the question,

ode = (y'[x])^2 == Exp[4*x - 2*y[x]]*(y'[x] - 1);
s = DSolve[ode, y, x, Assumptions -> x \[Element] Reals]

(* {Solve[-(1/2) ArcTanh[E^(2 x)/Sqrt[E^(4 x) - 4 E^(2 y[x])]]
+ y[x]/2 == C[1], y[x]],
Solve[1/2 ArcTanh[E^(2 x)/Sqrt[E^(4 x) - 4 E^(2 y[x])]]
+ y[x]/2 == C[1], y[x]]} *)


which can be solved for y[x] without much difficulty. For instance,

SubtractSides[MultiplySides[s[[1, 1]], 2] // Simplify, 2 C[1]];
Together[Subtract @@ TrigToExp@ApplySides[Tanh[#]^2 &, %]]
Numerator[%] // Last

(* E^(8 C[1]) + E^(4 x + 4 C[1]) + E^(4 y[x]) - 2 E^(4 C[1] + 2 y[x]) *)


Visibly, this is a polynomial in Exp[y[x]], which yields

Solve[Simplify[% /. C[1] -> Log[c] + 3 I Pi/4] == 0, y[x], Reals] // Flatten

(* {y[x] -> ConditionalExpression[1/2 Log[-c^4 + Sqrt[c^4 E^(4 x)]],
E^(4 x) > c^4]} *)


which is equivalent to the verified solution in the Update section of the question. It also is equivalent to the solutions obtained in the earlier section of this answer, provided that C[1] is appropriately chosen. A similar analysis can be performed for the second ODE in the question.

In summary, both versions of Mathermatica give correct solutions to the two ODEs, if x is specified as real. Nonetheless, I agree with Nasser that the DSolve treatment of these two odes in 13.2 is a step backward.

Too long for a comment. The output of

ode = (y'[x])^2 == Exp[4*x - 2*y[x]]*(y'[x] - 1);DSolve[ode, y[x], x]


substantially differs from the Maple 2018's one

$$x-1/2\,{\frac {\sqrt {- \left( 4\,{{\rm e}^{-4\,x+2\,y \left( x \right) }}-1 \right) {{\rm e}^{8\,x-4\,y \left( x \right) }}}{{\rm e} ^{-4\,x+2\,y \left( x \right) }}{\rm arctanh} \left({\frac {1}{\sqrt { -4\,{{\rm e}^{-4\,x+2\,y \left( x \right) }}+1}}}\right)}{\sqrt {-4\,{ {\rm e}^{-4\,x+2\,y \left( x \right) }}+1}}}-1/4\,\ln \left( 2\,{ {\rm e}^{-2\,x+y \left( x \right) }}-1 \right) -1/4\,\ln \left( 2\,{ {\rm e}^{-2\,x+y \left( x \right) }}+1 \right) +1/2\,\ln \left( { {\rm e}^{-2\,x+y \left( x \right) }} \right) +1/4\,\ln \left( 4\,{ {\rm e}^{-4\,x+2\,y \left( x \right) }}-1 \right) -{\it \_C1}=0 ,...$$

• I am confident that the Mathematica result is correct, although this does not mean that the Maple result is incorrect. The expressions are sufficiently complicated that they may reduce to the same results while appearing different. Dec 18, 2022 at 19:50

Thanks for pointing out this issue. In version 13.1 DSolve returns implicit solutions for these ODEs. After recent form changes in Integrate in version 13.2 the internal outcomes of some integrals inside DSolve have been changed, due to which DSolve fails to solve these ODEs in 13.2. Currently we are working on this issue.

This has been fixed in V 13.3.