UPDATE (since version 10)
This now completely solved with built-in functionality, please read this blog for details: Visualizing Anatomy. Below is a quote and example. You can also find a few videos at Jeff Bryant on Vimeo.
"In Mathematica 10, we introduced support for anatomical structures in EntityValue, which included, among many other things, a “Graphics3D” property that returns a 3D model of the anatomical structure in question. We also styled the models and aligned them with the concepts in the Unified Medical Language System (UMLS)."

AnatomyPlot3D[
{{ClipPlanes -> {InfinitePlane[{{-50, -146, 1500}, {-20, -146 - 20, 1550},
{-50, -146 - 20, 1500}}], InfinitePlane[{{-50, -146, 1550},
{-20, -146 - 20, 1550}, {-50, -146 - 20, 1550}}]},
Entity["AnatomicalStructure", "Skull"]}, Entity["AnatomicalStructure", "Eye"],
Entity["AnatomicalStructure", "Brain"], Directive[Specularity[White, 50],
Hue[0.58, 0, 1, 0.1], Lighting -> Join[{{"Ambient", Black}},
Table[{"Directional", Hue[0.58, 0.5, 1], ImageScaled[{Sin[x], Cos[x], -0.5}]},
{x, 0, 2*Pi - 2*(Pi/8), 2*(Pi/8)}]]], Entity["AnatomicalStructure", "Nose"],
Entity["AnatomicalStructure", "Neck"], Entity["AnatomicalStructure", "SkinOfHead"],
Entity["AnatomicalStructure", "SkinOfNeck"], Entity["AnatomicalStructure", "Lip"],
Entity["AnatomicalStructure", "Ear"]},
PlotRange -> Entity["AnatomicalStructure", "Head"], PlotRangePadding -> 10,
Background -> Hue[0.58, 1, 0.3], SphericalRegion -> True, ViewAngle -> Pi/5,
ImageSize -> 600, ViewPoint -> {-1.4, -1.29, 0.07}, ViewVertical -> {0.16, -0.08, 1.}]
OLD answer
I doubt anyone would know where exactly is some full model, if there is any. But you can post-process imported model data to make them look better, apply color and opacity. For example from site you linked, I imported:
obj = Import["ZombieHunterHead_v3_87k.stl"]

Then I extract data and change rendering - add metallic color, add transparency, - now you can see his ear through his head:
Graphics3D[{GrayLevel[.25], Specularity[White, 10], EdgeForm[],
FaceForm[Opacity[.3]], Polygon[obj[[1, 2, 1]]]},
Lighting -> Automatic, Boxed -> False]
