Units, plotting and empty plots

Question

maybe I'm completely newbie but I can't understand the behavior of units and the command plot.

I'm doing some easy plotting of the state equation for gasses:

R =  Quantity[0.0831, ("Bars" "Liters")/("Kelvins" "Moles")];
a =  Quantity[3.658, ("Liters")^2]* Quantity[1, ("Bars")/("Moles")^2]  
b = Quantity[0.0429, ("Liters")/("Moles")]
PVW[V_, T_, N_] := ((N*R*T)/(V - N*b)) - (+a*(N^2/V^2));

I then test that units are ok:

test = PVW[Quantity[0.6, "Liters"], Quantity[270, "Kelvins"], Quantity[1, "Moles"]];
UnitSimplify[test]

And I get my pressure back :

Quantity[30.1135, "Bars"]

Now I want my plot so I do :

Plot[PVW[V, Quantity[330, "Kelvins"], Quantity[1, "Moles"] ], {V, 
Quantity[0.06, "Liters"] , Quantity[0.6, "Liters"]},
Frame -> True, 
GridLines -> None,
LabelStyle -> {FontFamily -> "Helvetica", FontSize -> 15},
FrameLabel -> {"Volume", "Pressure"}]

If I evaluate that I get no errors, no nothing but a empty plot:

What is going on?

Answer 1

Still working out the why, but wrapping an Evaluate[] around your function seems to solve the problem:

Plot[
 Evaluate[
  PVW[V, Quantity[330, "Kelvins"], Quantity[1, "Moles"]
 ]
],
{V,Quantity[0.06, "Liters"],Quantity[0.6, "Liters"]}, 
Frame -> True, 
GridLines -> None, 
LabelStyle -> {FontFamily -> "Helvetica", FontSize -> 15}, 
FrameLabel -> {"Volume", "Pressure"}]

Edit:

This behaviour is discussed by Nasser in this related question.

Edit 2:

As mentioned in your comment, this problem is a little bit stranger than I'd realized. If anybody has insight as to why the following three examples return different results, feel free to chime in.

1. As above, with Evaluate[] around the PVW[] call, and units passed via the plot range specification.

2. Still using Evaluate[], but with the PlotRange[] being just numbers, and V being passed through a Quantity[] function:

   Remove["Global`*"];
   R = Quantity[0.0831, ("Bars" "Liters")/("Kelvins" "Moles")];
   a = Quantity[3.658, ("Liters")^2]*Quantity[1, ("Bars")/("Moles")^2];
   b = Quantity[0.0429, ("Liters")/("Moles")];
   PVW[V_, T_, N_] := ((N*R*T)/(V - N*b)) - (a*(N^2/V^2));
   Plot[Evaluate[
     PVW[Quantity[V, "Liter"], Quantity[330, "Kelvins"], 
      Quantity[1, "Moles"]]], {V, 0.06, 0.6}, Frame -> True, 
    GridLines -> None, 
    LabelStyle -> {FontFamily -> "Helvetica", FontSize -> 15}, 
    FrameLabel -> {"Volume", "Pressure"}]
   

   

3. Using numbers without units:

   Remove["Global`*"];
   R = 0.0831;
   a = 3.658;
   b = 0.0429;
   PVW[V_, T_, N_] := ((N*R*T)/(V - N*b)) - (a*(N^2/V^2));
   Plot[PVW[V, 330, 1], {V, 0.06, 0.6}, Frame -> True, GridLines -> None,
     LabelStyle -> {FontFamily -> "Helvetica", FontSize -> 15}, 
    FrameLabel -> {"Volume", "Pressure"}]
   

   

Answer 2

You need Evaluate to release the HoldAll (as mentioned here):

Plot[Evaluate@PVW[V, Quantity[330, "Kelvins"], Quantity[1, "Moles"]],
    {V, Quantity[0.06, "Liters"], Quantity[0.6, "Liters"]}, 
    Frame -> True, GridLines -> None, 
    LabelStyle -> {FontFamily -> "Helvetica", FontSize -> 15}, 
    FrameLabel -> {"Volume", "Pressure"}]

You also had a couple of typos (in an earlier version than current): you need {V,Quantity[0.06, "Liters"], Quantity[0.6, "Liters"]} as your plot limits, and you probably also don't want the curly braces around the PVW call.