Finite result under "Integrate" while infinite under "NIntegrate" of a complicated integral with "NSum"

Question

I have been trying to compute the following complicated integral along with summation, details codes/function of which is given below:

A[n_, ν_, m_, l0_, M_,  h_, κ_, τ_] := (
  2 Sqrt[2])/(l0*l0)*
  Sqrt[(ν!*(2*ν + Abs[m] + 1))/(ν + Abs[m])!]*
  Sqrt[(n - (Abs[m] + m)/2)!/(n + (Abs[m] - m)/2)!]*
  Integrate[
   Exp[-I*κ*M/τ*r^2/(2*h)]*Exp[-r^2/l0^2]*((2*r^2)/l0^2)^(
    Abs[m]/2)*(r^2/l0^2)^(Abs[m]/2)*Exp[-r^2/(2*l0^2)]*
    LaguerreL[ν, Abs[m], ((2*r^2)/l0^2)]*
    LaguerreL[(n - (Abs[m] + m)/2), Abs[m], (r^2/l0^2)]*r, {r, 0, 
    Infinity}]
A[1, 2, -1, 1*10^-9, 1*10^-30,  1*10^-34, 1, 2]
P[n_, l0_, l1_, M_, ω1_, 
  h_, κ_, τ_, Ω_] := 
 NSum[A[n, ν, m, l0, M, h, κ, τ]*(2 Sqrt[2])/(l0*l1)*
   Sqrt[(ν!*(2*ν + Abs[m] + 1))/(ν + Abs[m])!]*
   Sqrt[(n - (Abs[m] + m)/2)!/(n + (Abs[m] - m)/2)!]*
   NIntegrate[
    Exp[-r^2/(2*l1^2)]*(r^2/l1^2)^(Abs[m]/2)*
     LaguerreL[(n - (Abs[m] + m)/2), Abs[m], (r^2/l1^2)]*
     Exp[I*m*Ω*τ]*
     Exp[-2*I*(2 ν + Abs[m] + 1)*ω1*τ]*
     Exp[-I*κ*M/τ*(l0/l1)*r^2/(2*h)]*
     Exp[-r^2/l1^2]*((2*r^2)/l1^2)^(Abs[m]/2)*
     LaguerreL[ν, Abs[m], ((2*r^2)/l1^2)]*r, {r, 0, 
     Infinity}], {ν, 1, 10, 1}, {m, -n, n, 1}]
P[2, 1*10^-9, 2*10^-9, 1*10^-30, 0.25*10^14, 1*10^-34, 1, 2, 
 0.5*10^14]
P1 = DiscretePlot[(Abs[
    P[n, 1*10^-9, 2*10^-9, 1*10^-30, 0.25*10^14, 1*10^-34, 1, 2, 
     0.5*10^14]])^2, {n, 1, 10}, PlotStyle -> Red, PlotRange -> Full]

Kindly peruse the 2nd input line, which produces a huge division under "Integrate" function but otherwise finite. on the other hand, the same integral under "NIntegrate" function shows "1/0", which in turn suppresses the further output. I have gone through the similar posts under heading "different results under Integrate and NIntegrate", where it has been shown that both the results after some simplification is identical.

Moreover, the 4th inputline does not produce any output, even no error message is shown. As no result comes out in the intermidiate steps, the final plot is not obtained. It appears to me that somehow I can not use the appropriate code or function for such kind of complicated integration /sum.

Would you kindly correct the codes, I have used, or suggest me any relevant posts, which may help me. Thanking you...

Answer 1

I'd recommend using the exact variants Integrate and Sum instead of NIntegrate and NSum.

First, define helper functions A and B using partial memoization: they only need to be calculated once for given integer values $\{n,\nu,m\}$ but should have the other numbers as parameters. Note that I've pulled some constants out of your definition of A:

Clear[A];
A[n_Integer, ν_Integer, m_Integer] := A[n, ν, m] =
  Function[{l0, M, h, κ, τ}, Evaluate[
    Integrate[E^(-(1/2) r^2 (3/l0^2 + (I M κ)/(h τ)))*((Sqrt[2] r^2)/l0^2)^Abs[m]*
      LaguerreL[ν, Abs[m], (2 r^2)/l0^2]*
      LaguerreL[n - (m + Abs[m])/2, Abs[m], r^2/l0^2]*r, {r, 0, ∞},
      Assumptions -> l0 > 0 && M > 0 && h > 0 && κ > 0 && τ > 0]]]

Clear[B];
B[n_Integer, ν_Integer, m_Integer] := B[n, ν, m] =
  Function[{l0, l1, ω1, Ω, M, h, κ, τ}, Evaluate[
    E^(I τ (m Ω - 2 ω1 (1 + 2 ν + Abs[m])))
    Integrate[E^(-((r^2 (I l0 l1 M κ + 3 h τ))/(2 h l1^2 τ))) ((Sqrt[2] r^2)/l1^2)^Abs[m]*
      LaguerreL[n - (m + Abs[m])/2, Abs[m], r^2/l1^2]*
      LaguerreL[ν, Abs[m], (2 r^2)/l1^2]*r, {r, 0, ∞}, 
      Assumptions -> l0 > 0 && l1 > 0 && M > 0 && h > 0 && κ > 0 && τ > 0]]]

Example:

A[1, 2, -1]
(*    Function[{l0$, M$, h$, κ$, τ$},
        -((12 Sqrt[2] h$^2 l0$^2 τ$^2 (-I l0$^2 M$ κ$ + 
        h$ τ$) (-l0$^4 M$^2 κ$^2 +
        7 h$^2 τ$^2))/(I l0$^2 M$ κ$ + 3 h$ τ$)^5)]    *)

Now we can add them up:

P[n_Integer?NonNegative, l0_, l1_, M_, ω1_, h_, κ_, τ_, Ω_] :=
  Sum[8/(l0^3 l1)*((1 + 2 ν + Abs[m]) ν!)/(ν + Abs[m])!*(n - (m + Abs[m])/2)!/(n - (m - Abs[m])/2)! *
    A[n, ν, m][l0, M, h, κ, τ] *
    B[n, ν, m][l0, l1, ω1, Ω, M, h, κ, τ],
    {ν, 1, 10}, {m, -n, n}]

The evaluation is very slow though. I think you can speed it up dramatically by looking up some analytic formulas for the integrals in A and B.

DiscretePlot[
  Abs[P[n, 1*^-9, 2*^-9, 1*^-30, 0.25*^14, 1*^-34, 1, 2, 0.5*^14]]^2,
  {n, 0, 3}]

update: simplification

The functions A and B can be expressed in terms of the function R:

Clear[R];
R[n_Integer, ν_Integer, m_Integer] := R[n, ν, m] = 
  Function[ɑ, Evaluate[
    Integrate[E^(-ɑ r^2) (Sqrt[2] r^2)^Abs[m]*
      LaguerreL[ν, Abs[m], 2 r^2]*
      LaguerreL[n - (m + Abs[m])/2, Abs[m], r^2]*r,
      {r, 0, Infinity}, 
      Assumptions -> Re[ɑ] > 0]]]

Now we have the simpler (faster) expressions

Clear[A, B];
A[n_Integer, ν_Integer, m_Integer, l0_, M_, h_, κ_, τ_] :=
  l0^2 * R[n, ν, m][3/2 + (I l0^2 M κ)/(2 h τ)]
B[n_Integer, ν_Integer, m_Integer, l0_, l1_, ω1_, Ω_, M_, h_, κ_, τ_] :=
  l1^2 E^(I τ (m Ω - 2 ω1 (1 + 2 ν + Abs[m]))) *
  R[n, ν, m][3/2 + (I l0 l1 M κ)/(2 h τ)]

P[n_Integer?NonNegative, l0_, l1_, M_, ω1_, h_, κ_, τ_, Ω_] :=
  Sum[8/(l0^3 l1)*((1 + 2 ν + Abs[m]) ν!)/(ν + Abs[m])!*(n - (m + Abs[m])/2)!/(n - (m - Abs[m])/2)! *
    A[n, ν, m, l0, M, h, κ, τ] *
    B[n, ν, m, l0, l1, ω1, Ω, M, h, κ, τ],
    {ν, 1, 10}, {m, -n, n}]

If you can find an analytic expression for the function R, you can speed up this code infinitely.