3
$\begingroup$

I'm going to understand power transmission system (by using LRC circuit), at least I need to solve differential equations by using MMA (analytically if it exist), and plot it.

According this paper the wireless power transmission system can be modelled by following system of differential equations:

enter image description here

enter image description here where V1 is AC voltage (Sinusoidal form), V1=V0 k*Cos[t];

R1 = 2; c1 = 1/5; L1 = 1; V0 = 220; \[Omega] = 60;
R2 = 2; c2 = 1; L2 = 1;
M = 1;
ic = {i1[0] == 0, i1'[0] == 0, i2[0] == 0, i2'[0] == 0};
sys = {L1*i1''[t] + M i2''[t] + R1 * i1[t] + 1/c1 i1[t] == V0 * \[Omega]*Cos[\[Omega] t],
       L2*i2''[t] + M i1 ''[t] + R2 * i2[t] + 1/c2 i2[t] == 0}

I tried to use DSolve and NDSolve but there is no answer

{I1, I2} = NDSolveValue[{sys, ic}, {i1, i2}, {t, 1, 2 Pi}]
$\endgroup$
3
  • 1
    $\begingroup$ It works with M=.99 (M=1 is a very special case) $\endgroup$
    – andre314
    Nov 14, 2022 at 17:28
  • 1
    $\begingroup$ Would the terms in R be i1'[t] rather than i1[t]? sys = {L1*i1''[t] + M i2''[t] + R1 * i1'[t] + 1/c1 i1[t] == V0 * [Omega]*Cos[[Omega] t], L2*i2''[t] + M i1 ''[t] + R2 * i2'[t] + 1/c2 i2[t] == 0} $\endgroup$
    – Eric Brown
    Nov 14, 2022 at 18:01
  • $\begingroup$ @EricBrown You are correct, op translated the paper equation wrong. $\endgroup$
    – Nasser
    Nov 14, 2022 at 18:11

1 Answer 1

5
$\begingroup$

Your system is not setup correctly as it leads to 0===1

Proof

R1 = 2; c1 = 1/5; L1 = 1; V0 = 220; ω = 60;
R2 = 2; c2 = 1; L2 = 1;
M = 1;
ic = {i1[0] == 0, i1'[0] == 0, i2[0] == 0, i2'[0] == 0};
sys = {L1*i1''[t] + M i2''[t] + R1*i1[t] + 1/c1 i1[t] == 
   V0*ω*Cos[ω t], L2*i2''[t] + M i1''[t] + R2*i2[t] + 1/c2 i2[t] == 0}

Mathematica graphics

Look closely at the above, You will see i1''+i2'' shows in both equations. Solving for i1''+i2'' from the second gives i1''+i2''= - 3 i2[t] Substituting this in the first gives

newsys=7 i1[t]-3 i2[t]==13200 Cos[60 t]

Mathematica graphics

So the system become an algebraic equation. Not differential equations.

The above is what you want to solve now. But it is one equation, two unknowns.

But lets try your initial conditions to see what happens. At t=0 you say that i1[0] == 0, i2[0] == 0 hence at t=0 newsys becomes

 0==13200

Which can not be correct.

No wonder NDSolve got so confused. May be some of the parameters are wrong or you translated the equations wrong.


Update

After seeing the comment above by Eric Brown and looking at the paper, yes, you seem to have made translation error. it should be R1*i1'[t] and not R*i1[t] in the first ode, also in the second ode it should be R2*i2[t]'. Fixing these gives

R1 = 2; c1 = 1/5; L1 = 1; V0 = 220; ω = 60;
R2 = 2; c2 = 1; L2 = 1;
M = 1;
ic = {i1[0] == 0, i1'[0] == 0, i2[0] == 0, i2'[0] == 0};
sys = {L1*i1''[t] + M i2''[t] + R1*i1'[t] + 1/c1 i1[t] == 
   V0*ω*Cos[ω t], L2*i2''[t] + M i1''[t] + R2*i2'[t] + 1/c2 i2[t] == 0}

{I1, I2} = NDSolveValue[{sys, ic}, {i1, i2}, {t, 1, 2 Pi}]

Mathematica graphics

Plot[{I1[t], I2[t]}, {t, 1, 2 Pi}, PlotLegends -> "Expressions"]

Mathematica graphics

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.