Antiderivative of a piecewise function evaluates wrong inside a subroutine

Question

It's very helpfull to use antiderivative of a given function in the form Derivative[-1][fun][t]!

Here my example with a simple piecewise function:

fun = Which[0 <= t <= 1, Min[1, 2 (# (1 - #))/(1/2)^2], True, 0] &
Plot[fun[t], {t, 0, 1}]

The antiderivative evaluates as expected

Plot[(Derivative[-1][Function[t, fun[t]]][t]), {t, 0, 1}, Evaluated -> True]

But if I try calculate the antiderivative inside a subroutine I get strange results:

test =.
test[fu_] :=Plot[(-Derivative[-1][Function[t, fu]][t]), {t, 0, 1},
                 Evaluated -> True] 
test[fun[t]]

My question: What might be the reason for the obviously wrong result? Is there a simple workaround?

Thanks

xzczd · Accepted Answer · 2022-11-09 11:43:06Z

4

Echo will help you see what has happened:

test[fu_] := 
 Plot[(-Derivative[-1][Function[t, fu] // Echo][t]), {t, 0, 1}, Evaluated -> True]
test[fun[t]]

This behavior is discussed in the document:

We also have a number of related posts in this site, for example:

There should be more.

A simple way to avoid the renaming is, using Apply (@@) to break the pure function:

test[fu_] := 
 Plot[(-Derivative[-1][Function @@ {t, fu}][t]), {t, 0, 1}, Evaluated -> True]

answered Nov 9, 2022 at 11:43

xzczd

63.5k9 gold badges159 silver badges459 bronze badges

1

$\begingroup$ Clever idea to use Echo, have to remember it. Thanks for your answer! Still I don't understand why Plot-function evaluates without problems. $\endgroup$
– Ulrich Neumann
Nov 9, 2022 at 12:38
$\begingroup$ @UlrichNeumann Are you asking why Plot still gives a plot in last case? If so, it's because Function[t$,…] is still a function. (Simpler example: Derivative[-1][Function[aaa, t^2]]. ) If you're asking why the renaming doesn't happen in 2nd case, it's because in that case you haven't defined the function test. The renaming is triggered by the nesting of := and Function. See the table Scoping constructs in the Wolfram Language in the linked tutorial. As mentioned therein: "When you mix these constructs in any way, the Wolfram Language does appropriate renamings to avoid conflicts." $\endgroup$
– xzczd
Nov 9, 2022 at 12:49
$\begingroup$ @xzcy Thank You very very much! $\endgroup$
– Ulrich Neumann
Nov 9, 2022 at 15:58

Add a comment |

1 Answer 1