How to prove this algebraic identity?

Question

I mean $$\forall z \in \mathbb C\left(\ \left| \sqrt{z^2-1}-z\right| +\left| z+\sqrt{z^2-1}\right| =| z-1| +| z+1|\right ) .$$

The command

ComplexPlot3D[Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] - Abs[z - 1] -
Abs[z + 1] // Chop, {z, -3 - 3*I, 3 + 3*I}]

confirms it, but this is not a proof. Here are my unsuccessful attempts.

ForAll[z, Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] ==
Abs[z - 1] + Abs[z + 1]]
Resolve[%, Complexes]

is running without any response for hours. The same issue with

Reduce[Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] ==
Abs[z - 1] + Abs[z + 1], z]

The command

FindInstance[Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] != Abs[z - 1] + Abs[z + 1], z]

returns the input. A few other attempts (for example, with Solve) are omitted.

Answer 1

Since both sides are positive, the identity is valid if the square of left hand side equals the square of right hand side.

$\forall z \in \mathbb C \; \; \; \left(\ \left| \sqrt{z^2-1}-z\right| +\left| z+\sqrt{z^2-1}\right| \right )^2 = \left( | z-1| +| z+1| \right)^2 .$

To verify in Mathematica:

FullSimplify[ComplexExpand[(Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z])^2, z]]    
        
(* 2 (1 + Abs[z]^2 + Sqrt[(-1 + z^2) (-1 + Conjugate[z]^2)]) *)

FullSimplify[ComplexExpand[(Abs[z - 1] + Abs[z + 1])^2, z]]
        
(* 2 (1 + Abs[z]^2 + Sqrt[(-1 + z^2) (-1 + Conjugate[z]^2)]) *)

Answer 2

The function

f[w_]:=Abs[Sinh[w]-Cosh[w]]+Abs[Sinh[w]+Cosh[w]]-Abs[Cosh[w]-1]-Abs[Cosh[w]+1]

vanishes:

f[u+I*v]//ComplexExpand//FullSimplify[#,Element[u|v,Reals]]&
(* 0 *)

Therefore f[ArcCosh[z]] vanishes, and this is OPs identity.

Answer 3

Your ComplexPlot3D is a good test for the numerical exactness of the methods used by this Mathematica built-in for this task. Try to play around with the numerical exactness values for Your session.

Just in case You like a serious answer from Mathematica use:

 FindInstance[
 Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] == 
  Abs[z - 1] + Abs[z + 1], z, Complexes, 1]

(* {{z -> 0}} *)

I selected $n=1$, but there are infinitely many solutions because this is an identity. If $n>1$ is chosen, the given routines searches infinitely long again.

The error message FindInstance::nsmet is by the use of this additional option gone. nsmet is an abbreviation for Namespace methods. So this is a very broad and not so in-depth error message.

The noise in Your ComplexPlot3D is of the size of $$MachinePrecision (15.9546)$. So Mathematica uses the chance to show residual noise. You might choose to suppress this by using option to ComplexPlot3D PlotRange

ComplexPlot3D[
 Abs[Sqrt[z^2 - 1] + z] + Abs[Sqrt[z^2 - 1] - z] - Abs[z - 1] - 
   Abs[z + 1] // Chop, {z, -1 - I, 1 + I}, 
 PlotRange -> {0.0, 15. 10^-15}]

It is a not so rarely discussed topic, why does Mathematica produce that often the very same noise pattern for specified problems?

I used the default color theme for my plot.