Need help with Assumptions for an integral

Question

I want to solve this Log, Integrate[2a Log[-a+((A0 + (y-y1)²)^½, {y1, 0,b}] But Mathematica only gives me long conditional expressions or imaginary numbers. I (my thinking which can be wrong) assume I need to tell Mathematica that what's inside the root is real and positive and that it's value is greater than 'a' so the log can be solved. I did it but still it is not working . All I know is the result should be also a conditional expression but the only condition is a≠0. How should I set up my Assumtions so this problem can be solved? I've done this but is not working.Pls help :(

The info is: A0≥0 and every variable is real. You can check some of my attempts here:

https://www.reddit.com/user/EstridMyr/comments/xm3cz1/_/?utm_medium=android_app&utm_source=share

Answer 1

Clear["Global`*"]

(int1 = Assuming[{b > 0, a^2 > A0 >= 0, Element[{a, y}, Reals]},
    Integrate[2 a Log[-a + (A0 + (y - y1)^2)^(1/2)], {y1, 0, b}] //
     FullSimplify]) // InputForm

(* ConditionalExpression[
 2*a*(-b + Sqrt[a^2 - A0]*
    (ArcTanh[(b - y)/Sqrt[a^2 - A0]] + 
      ArcTanh[(a*(b - y))/Sqrt[(a^2 - A0)*
         (A0 + (b - y)^2)]] + 
     ArcTanh[y/Sqrt[a^2 - A0]] + 
     ArcTanh[(a*y)/Sqrt[(a^2 - A0)*(A0 + y^2)]]) + 
   (b - y)*Log[-a + Sqrt[A0 + (b - y)^2]] + 
   a*Log[-b + Sqrt[A0 + (b - y)^2] + y] + 
   y*Log[-a + Sqrt[A0 + y^2]] - a*Log[y + Sqrt[A0 + y^2]]), 
 Sqrt[a^2 - A0] > b && a^2 >= A0 + (b - y)^2 && 
  a^2 >= A0 + y^2 && Sqrt[A0 + (b - y)^2] >= a && 
  Sqrt[A0 + y^2] >= a && (Sqrt[A0] != 0 || b < y || 
   y < 0) && (Sqrt[a^2 - A0] + b < y || y < Sqrt[a^2 - A0])] *)

You can add the conditions to the assumptions to eliminate the conditions

int2 = Assuming[{b > 0 && a^2 > A0 >= 0 && Element[{a, y}, Reals] && 
    int1[[-1]]},
  Integrate[2 a Log[-a + (A0 + (y - y1)^2)^(1/2)], {y1, 0, b}] //
   FullSimplify]

(* 2 a (-b + 
   Sqrt[a^2 - 
     A0] (ArcTanh[(b - y)/Sqrt[a^2 - A0]] + 
      ArcTanh[(a (b - y))/Sqrt[(a^2 - A0) (A0 + (b - y)^2)]] + 
      ArcTanh[y/Sqrt[a^2 - A0]] + 
      ArcTanh[(a y)/Sqrt[(a^2 - A0) (A0 + y^2)]]) + (b - y) Log[-a + Sqrt[
      A0 + (b - y)^2]] + a Log[-b + Sqrt[A0 + (b - y)^2] + y] + 
   y Log[-a + Sqrt[A0 + y^2]] - a Log[y + Sqrt[A0 + y^2]]) *)

However, you get the same result (and quicker) just using Normal

int2 === (int1 // Normal)

(* True *)