1
$\begingroup$

MMA does not calculate the limit, however the limit exists as seen in the approximative plot.

Limit[HypergeometricPFQ[{-1/2}, {1/2, m/2}, x]/Gamma[m], m -> 0]

How to achieve the limit?

MMA 13.0

$\endgroup$
1
  • $\begingroup$ Do you know of a transformation that would show the limit exists? Otherwise this looks like a math question, rather than a MMA one. $\endgroup$
    – MarcoB
    Sep 16 at 14:14

2 Answers 2

2
$\begingroup$

Use this identity from the Wolfram functions website. This reads:

equation = HypergeometricPFQ[{a1}, {b, b2}, z] == 
((2 + 2 b - b2) HypergeometricPFQ[{a1}, {1 + b, b2}, z])/ b + ((-2 - b + b2)/b
 + z/( b (1 + b))) HypergeometricPFQ[{a1}, {2 + b, b2}, z] 
 + ((-2 + a1 - b) z HypergeometricPFQ[{a1}, {3 + b, b2}, z])/( b (1 + b) (2 + b));

To match your case, use the substitution rule (note that the function is symmetric in the two lower parameters):

substitute = {a1 -> -1/2, b -> m/2, b2 -> 1/2};

This means you want the limit of the following expression:

expression = (equation[[2]] /. substitute)/Gamma[m]

enter image description here

Expand the expression around m==0 to leading order, and truncate the result to the leading term:

limit = Series[expression, {m, 0, 0}] // Normal

enter image description here

You can check that the plot is correct:

Plot[limit, {z, -2, 2}]

enter image description here

$\endgroup$
1
  • $\begingroup$ @granularbastard Note that the whole purpose of using the identity is to unfold the b parameter into b+1, b+2, b+3 to resolve the degenerate point b->0. This means you should be using the symmetry of the function under interchange of the two b parameters and do the substitution as: a1->m-1/2; b2->1/2+m/2; b->m/2. Then it should go through as you expect. $\endgroup$
    – Kagaratsch
    Sep 16 at 14:46
3
$\begingroup$

Here is a solution with a bit of manual work. Note that HypergeometricPFQRegularized is close to what OP wants. So define

f=HypergeometricPFQ[{-1/2},{1/2,m/2},x];
g=HypergeometricPFQRegularized[{-1/2},{1/2,m/2},x];

Using FunctionExpand[g] it is easy to see that

FullSimplify[f/Gamma[m]==g*Sqrt[Pi]*(Gamma[m/2]/Gamma[m])]
(* True *)

Therefore the limit OP is looking for can be obtained as follows:

Limit[g*Sqrt[Pi],m->0]*Limit[Gamma[m/2]/Gamma[m],m->0]
(* -2*x*HypergeometricPFQ[{1/2},{3/2,2},x] *)
$\endgroup$
1
  • 1
    $\begingroup$ The conversion can be obtained by Solve[ HypergeometricPFQRegularized[{a}, {b, c}, x] == (HypergeometricPFQRegularized[{a}, {b, c}, x] // FunctionExpand), HypergeometricPFQ[{a}, {b, c}, x]] $\endgroup$
    – Bob Hanlon
    Sep 16 at 14:28

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.